* [gentoo-commits] gentoo-x86 commit in dev-util/schroot: ChangeLog schroot-1.4.1-r1.ebuild
@ 2010-03-26 18:14 Jonathan Callen (abcd)
0 siblings, 0 replies; only message in thread
From: Jonathan Callen (abcd) @ 2010-03-26 18:14 UTC (permalink / raw
To: gentoo-commits
abcd 10/03/26 18:14:15
Modified: ChangeLog
Added: schroot-1.4.1-r1.ebuild
Log:
Add patch for boost 1.42.0, thanks to Andrew Savchenko (bug 307975)
(Portage version: -svn/cvs/Linux i686)
Revision Changes Path
1.16 dev-util/schroot/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/ChangeLog?r1=1.15&r2=1.16
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog 27 Feb 2010 02:06:47 -0000 1.15
+++ ChangeLog 26 Mar 2010 18:14:15 -0000 1.16
@@ -1,6 +1,12 @@
# ChangeLog for dev-util/schroot
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v 1.15 2010/02/27 02:06:47 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v 1.16 2010/03/26 18:14:15 abcd Exp $
+
+*schroot-1.4.1-r1 (26 Mar 2010)
+
+ 26 Mar 2010; Jonathan Callen <abcd@gentoo.org> +schroot-1.4.1-r1.ebuild,
+ +files/schroot-1.4.1-boost-validation_error.patch:
+ Add patch for boost 1.42.0, thanks to Andrew Savchenko (bug 307975)
*schroot-1.4.1 (27 Feb 2010)
1.1 dev-util/schroot/schroot-1.4.1-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/schroot-1.4.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/schroot/schroot-1.4.1-r1.ebuild?rev=1.1&content-type=text/plain
Index: schroot-1.4.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/schroot-1.4.1-r1.ebuild,v 1.1 2010/03/26 18:14:15 abcd Exp $
EAPI="2"
WANT_AUTOMAKE="1.11"
inherit autotools base pam
DESCRIPTION="Utility to execute commands in a chroot environment"
HOMEPAGE="http://packages.debian.org/source/sid/schroot"
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.orig.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+dchroot debug doc lvm nls pam test"
COMMON_DEPEND="
>=dev-libs/boost-1.42.0
dev-libs/lockdev
>=sys-apps/util-linux-2.16
lvm? ( sys-fs/lvm2 )
pam? ( sys-libs/pam )
"
DEPEND="${COMMON_DEPEND}
doc? (
app-doc/doxygen
media-gfx/graphviz
)
nls? ( sys-devel/gettext )
test? ( >=dev-util/cppunit-1.10.0 )
"
RDEPEND="${COMMON_DEPEND}
sys-apps/debianutils
dchroot? ( !sys-apps/dchroot )
nls? ( virtual/libintl )
"
PATCHES=(
"${FILESDIR}/${PN}-1.4.0-tests.patch"
# This patch requires boost >= 1.42.0
"${FILESDIR}/${PN}-1.4.1-boost-validation_error.patch"
)
src_prepare() {
base_src_prepare
# Don't depend on cppunit unless we are testing
use test || sed -i '/AM_PATH_CPPUNIT/d' configure.ac
echo -e "Package: ${PN}\nVersion: ${PV}" > VERSION
eautoreconf
}
src_configure() {
root_tests=no
use test && (( EUID == 0 )) && root_tests=yes
econf \
$(use_enable doc doxygen) \
$(use_enable dchroot) \
$(use_enable dchroot dchroot-dsa) \
$(use_enable debug) \
$(use_enable lvm lvm-snapshot) \
$(use_enable nls) \
$(use_enable pam) \
--enable-block-device \
--enable-loopback \
--enable-uuid \
--enable-root-tests=$root_tests \
--enable-shared \
--disable-static \
--localstatedir=/var \
--with-bash-completion-dir=/usr/share/bash-completion
}
src_test() {
if [[ $root_tests == yes && $EUID -ne 0 ]]; then
ewarn "Disabling tests because you are no longer root"
return 0
fi
default
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
newinitd "${FILESDIR}"/schroot.initd schroot || die "installation of init.d script failed"
newconfd "${FILESDIR}"/schroot.confd schroot || die "installation of conf.d file failed"
dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die "installation of docs failed"
if use doc; then
docinto html/sbuild
dohtml doc/sbuild/html/* || die "installation of html docs failed"
docinto html/schroot
dohtml doc/schroot/html/* || die "installation of html docs failed"
fi
if use pam; then
rm -f "${D}"/etc/pam.d/schroot
pamd_mimic_system schroot auth account session
fi
# Remove *.la files
find "${D}" -name "*.la" -exec rm {} + || die "removal of *.la files failed"
}
pkg_preinst() {
export had_older_1_4_1=false
has_version "<dev-util/schroot-1.4.1" && had_older_1_4_1=true
if ${had_older_1_4_1}; then
einfo "Moving config files to new location..."
mkdir "${ROOT}etc/schroot/default"
mv_conffile etc/schroot/script-defaults etc/schroot/default/config
mv_conffile etc/schroot/mount-defaults etc/schroot/default/fstab
mv_conffile etc/schroot/copyfiles-defaults etc/schroot/default/copyfiles
mv_conffile etc/schroot/nssdatabases-defaults etc/schroot/default/nssdatabases
fi
}
mv_conffile() {
local OLDFILE=${ROOT}$1
local NEWFILE=${ROOT}$2
# if the old file doesn't exist, or is a symlink, stop
[[ -f ${OLDFILE} ]] || return 0
[[ -L ${OLDFILE} ]] && return 0
# if the new file already exists, then we have a problem...
if [[ -e ${NEWFILE} ]]; then
# but if they are the same, then don't worry about it
if cmp -s "${OLDFILE}" "${NEWFILE}"; then
rm -f "${OLDFILE}"
else
ewarn "${NEWFILE} already exists, not moving ${OLDFILE}"
fi
else
mv "${OLDFILE}" "${NEWFILE}"
fi
local x y
# now move all the unmerged config files as well
for x in "${OLDFILE%/*}"/._cfg????_"${OLDFILE##*/}"; do
[[ -f ${x} ]] || continue
# /etc/schroot/._cfg0000_script-defaults -> /etc/schroot/default/._cfg0000_config
y=${x##*/}
y=${NEWFILE%*/}${y%${OLDFILE##*/}}${NEWFILE##*/}
mv "${x}" "${y}"
done
}
pkg_postinst() {
local x
if ${had_older_1_4_1}; then
for x in script:config mount:fstab copyfiles nssdatabases; do
if [[ ! -e ${ROOT}etc/schroot/${x%:*}-defaults && -f ${ROOT}etc/schroot/default/${x#*:} ]]; then
einfo "Creating compatibility symlink for ${x%:*}-defaults"
ln -sf "default/${x#*:}" "${ROOT}etc/schroot/${x%:*}-defaults"
fi
done
ewarn "Your config files have been moved to the new location in"
ewarn "/etc/schroot/default. Compatibility symlinks have been installed in"
ewarn "/etc/schroot, and may be removed if no running chroot refers to them."
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-03-26 18:14 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-03-26 18:14 [gentoo-commits] gentoo-x86 commit in dev-util/schroot: ChangeLog schroot-1.4.1-r1.ebuild Jonathan Callen (abcd)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox