[gentoo-commits] gentoo-x86 commit in app-misc/freemind: ChangeLog freemind-0.9.0_rc6.ebuild freemind-0.9.0_rc7.ebuild freemind-0.9.0_rc4-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/freemind: ChangeLog freemind-0.9.0_rc6.ebuild freemind-0.9.0_rc7.ebuild freemind-0.9.0_rc4-r1.ebuild

[Vlastimil Babka (caster)]

caster      10/02/28 11:40:45

  Modified:             ChangeLog freemind-0.9.0_rc6.ebuild
  Added:                freemind-0.9.0_rc7.ebuild
  Removed:              freemind-0.9.0_rc4-r1.ebuild
  Log:
  Version bump. Fix building with Ant 1.8.0 (broken by basedir handling change) with a sed call, compatible with Ant 1.7.1 too. Bug #305929.
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.51                 app-misc/freemind/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/ChangeLog?r1=1.50&r2=1.51

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/freemind/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog	25 Oct 2009 10:22:48 -0000	1.50
+++ ChangeLog	28 Feb 2010 11:40:44 -0000	1.51
@@ -1,6 +1,14 @@
 # ChangeLog for app-misc/freemind
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/ChangeLog,v 1.50 2009/10/25 10:22:48 caster Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/ChangeLog,v 1.51 2010/02/28 11:40:44 caster Exp $
+
+*freemind-0.9.0_rc7 (28 Feb 2010)
+
+  28 Feb 2010; Vlastimil Babka <caster@gentoo.org>
+  -freemind-0.9.0_rc4-r1.ebuild, freemind-0.9.0_rc6.ebuild,
+  +freemind-0.9.0_rc7.ebuild:
+  Version bump. Fix building with Ant 1.8.0 (broken by basedir handling
+  change) with a sed call, compatible with Ant 1.7.1 too. Bug #305929.
 
 *freemind-0.9.0_rc6 (25 Oct 2009)
 



1.2                  app-misc/freemind/freemind-0.9.0_rc6.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc6.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc6.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc6.ebuild?r1=1.1&r2=1.2

Index: freemind-0.9.0_rc6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc6.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- freemind-0.9.0_rc6.ebuild	25 Oct 2009 10:22:48 -0000	1.1
+++ freemind-0.9.0_rc6.ebuild	28 Feb 2010 11:40:44 -0000	1.2
@@ -1,6 +1,6 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc6.ebuild,v 1.1 2009/10/25 10:22:48 caster Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc6.ebuild,v 1.2 2010/02/28 11:40:44 caster Exp $
 
 EAPI="2"
 
@@ -70,7 +70,7 @@
 	fi
 	local gcp="$(java-pkg_getjars --with-dependencies ${gcp}):lib/bindings.jar"
 	ANT_TASKS="${WANT_ANT_TASKS} jibx xsd2jibx" eant -Djibxlibs="${jibxlibs}" \
-		-Dgentoo.classpath="${gcp}" dist browser $(use_doc doc)
+		-Dgentoo.classpath="${gcp}" -Dbasedir="${PWD}" dist browser $(use_doc doc)
 }
 
 src_install() {



1.1                  app-misc/freemind/freemind-0.9.0_rc7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc7.ebuild?rev=1.1&content-type=text/plain

Index: freemind-0.9.0_rc7.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/freemind/freemind-0.9.0_rc7.ebuild,v 1.1 2010/02/28 11:40:44 caster Exp $

EAPI="2"

# will handle rewriting myself
JAVA_PKG_BSFIX="off"
WANT_ANT_TASKS="ant-nodeps ant-trax"
inherit java-pkg-2 java-ant-2 eutils

MY_PV=${PV//beta/Beta_}
MY_PV=${MY_PV//rc/RC_}

DESCRIPTION="Mind-mapping software written in Java"
HOMEPAGE="http://freemind.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${PN}-src-${MY_PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc groovy latex pdf svg"
COMMON_DEP="dev-java/jgoodies-forms:0
	dev-java/jibx:0
	>=dev-java/simplyhtml-0.13.1:0
	dev-java/commons-lang:2.1
	dev-java/javahelp:0
	groovy? ( dev-java/groovy )
	latex? ( dev-java/hoteqn:0 )
	pdf? ( dev-java/batik:1.7
		>=dev-java/fop-0.95:0 )
	svg? ( dev-java/batik:1.7
		>=dev-java/fop-0.95:0 )"
DEPEND=">=virtual/jdk-1.4
	dev-java/xsd2jibx:0
	app-arch/unzip
	${COMMON_DEP}"
RDEPEND=">=virtual/jre-1.4
	${COMMON_DEP}"

S="${WORKDIR}/${PN}"

java_prepare() {
	# kill the jarbundler taskdef
	epatch "${FILESDIR}/${PN}-0.9.0_rc1-build.xml.patch"

	# Ant 1.8.0 changed basedir handling in some subtle ways and probably
	# correcly. This change does not break ant 1.7.1 builds. Bug #305929
	sed -i 's/basedir="\."/basedir="\.\."/' plugins/build_*.xml || die

	use groovy || rm plugins/build_scripting.xml || die
	use latex || rm plugins/build_latex.xml || die
	if ! use pdf && ! use svg ; then
		rm plugins/build_svg.xml || die
	fi

	local xml
	for xml in $(find . -name 'build*.xml'); do
		java-ant_rewrite-classpath ${xml}
		java-ant_bsfix_one ${xml}
	done

	rm -v lib/*.jar lib/*.zip lib/*/*.jar \
		plugins/*/*.jar plugins/*/*/*.jar || die
}

src_compile() {
	local jibxlibs="$(java-pkg_getjars --build-only --with-dependencies xsd2jibx)"
	local gcp="jgoodies-forms,jibx,commons-lang-2.1,javahelp,simplyhtml"
	use groovy && gcp="${gcp},groovy"
	use latex && gcp="${gcp},hoteqn"
	if use pdf || use svg ; then
		# there is both direct batik usage and through fop
		gcp="${gcp},batik-1.7,fop"
	fi
	local gcp="$(java-pkg_getjars --with-dependencies ${gcp}):lib/bindings.jar"
	ANT_TASKS="${WANT_ANT_TASKS} jibx xsd2jibx" eant -Djibxlibs="${jibxlibs}" \
		-Dgentoo.classpath="${gcp}" -Dbasedir="${PWD}" dist browser $(use_doc doc)
}

src_install() {
	cd "${WORKDIR}/bin/dist"
	local dest="/usr/share/${PN}/"

	java-pkg_dojar lib/*.jar

	insinto "${dest}"
	doins -r accessories browser/ doc/ plugins/ patterns.xml || die

	use doc && java-pkg_dojavadoc doc/javadoc

	java-pkg_dolauncher ${PN} --java_args "-Dfreemind.base.dir=${dest}" \
		--pwd "${dest}" --main freemind.main.FreeMindStarter

	newicon "${S}/images/FreeMindWindowIcon.png" freemind.png

	make_desktop_entry freemind Freemind freemind Utility
}