* [gentoo-commits] gentoo-x86 commit in app-admin/puppet: ChangeLog puppet-0.25.4.ebuild
@ 2010-02-28 3:04 Matsuu Takuto (matsuu)
0 siblings, 0 replies; only message in thread
From: Matsuu Takuto (matsuu) @ 2010-02-28 3:04 UTC (permalink / raw
To: gentoo-commits
matsuu 10/02/28 03:04:55
Modified: ChangeLog
Added: puppet-0.25.4.ebuild
Log:
Version bumped. Fixed rrd issue, bug #294304.
(Portage version: 2.1.7.17/cvs/Linux x86_64)
Revision Changes Path
1.52 app-admin/puppet/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/ChangeLog?r1=1.51&r2=1.52
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/puppet/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog 26 Jan 2010 15:58:13 -0000 1.51
+++ ChangeLog 28 Feb 2010 03:04:54 -0000 1.52
@@ -1,6 +1,12 @@
# ChangeLog for app-admin/puppet
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/puppet/ChangeLog,v 1.51 2010/01/26 15:58:13 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/puppet/ChangeLog,v 1.52 2010/02/28 03:04:54 matsuu Exp $
+
+*puppet-0.25.4 (28 Feb 2010)
+
+ 28 Feb 2010; MATSUU Takuto <matsuu@gentoo.org> +puppet-0.25.4.ebuild,
+ +files/puppet-0.25.4-rrd.patch:
+ Version bumped. Fixed rrd issue, bug #294304.
*puppet-0.25.3 (26 Jan 2010)
1.1 app-admin/puppet/puppet-0.25.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/puppet-0.25.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/puppet-0.25.4.ebuild?rev=1.1&content-type=text/plain
Index: puppet-0.25.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/puppet/puppet-0.25.4.ebuild,v 1.1 2010/02/28 03:04:54 matsuu Exp $
EAPI="2"
inherit elisp-common eutils ruby
DESCRIPTION="A system automation and configuration management software"
HOMEPAGE="http://reductivelabs.com/projects/puppet"
SRC_URI="http://reductivelabs.com/downloads/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
IUSE="augeas emacs ldap rrdtool shadow vim-syntax"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
DEPEND="dev-lang/ruby[ssl]
emacs? ( virtual/emacs )
>=dev-ruby/facter-1.5.0"
RDEPEND="${DEPEND}
>=app-portage/eix-0.18.0
augeas? ( dev-ruby/ruby-augeas )
ldap? ( dev-ruby/ruby-ldap )
rrdtool? ( >=net-analyzer/rrdtool-1.2.23[ruby] )
shadow? ( dev-ruby/ruby-shadow )"
USE_RUBY="ruby18"
SITEFILE="50${PN}-mode-gentoo.el"
pkg_setup() {
enewgroup puppet
enewuser puppet -1 -1 /var/lib/puppet puppet
}
src_prepare() {
# Bug #294304
epatch "${FILESDIR}/${P}-rrd.patch"
}
src_compile() {
if use emacs ; then
elisp-compile ext/emacs/puppet-mode.el || die "elisp-compile failed"
fi
}
src_install() {
DESTDIR="${D}" ruby_einstall "$@" || die
DESTDIR="${D}" erubydoc || die
newinitd "${FILESDIR}"/puppetmaster-0.25.init puppetmaster || die
doconfd conf/gentoo/conf.d/puppetmaster || die
newinitd "${FILESDIR}"/puppet-0.25.init puppet || die
doconfd conf/gentoo/conf.d/puppet || die
# Initial configuration files
keepdir /etc/puppet/manifests || die
insinto /etc/puppet
doins conf/gentoo/puppet/* || die
doins conf/auth.conf || die
# Location of log and data files
keepdir /var/run/puppet || die
keepdir /var/log/puppet || die
keepdir /var/lib/puppet/ssl || die
keepdir /var/lib/puppet/files || die
fowners -R puppet:puppet /var/{run,log,lib}/puppet || die
if use emacs ; then
elisp-install ${PN} ext/emacs/puppet-mode.el* || die "elisp-install failed"
elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
fi
if use ldap ; then
insinto /etc/openldap/schema; doins ext/ldap/puppet.schema || die
fi
if use vim-syntax ; then
insinto /usr/share/vim/vimfiles/syntax; doins ext/vim/syntax/puppet.vim || die
insinto /usr/share/vim/vimfiles/ftdetect; doins ext/vim/ftdetect/puppet.vim || die
fi
# ext and examples files
for f in $(find ext examples -type f) ; do
docinto "$(dirname ${f})"; dodoc "${f}" || die
done
docinto conf; dodoc conf/namespaceauth.conf || die
}
pkg_postinst() {
elog
elog "Please, *don't* include the --ask option in EMERGE_EXTRA_OPTS as this could"
elog "cause puppet to hang while installing packages."
elog
elog "Puppet uses eix to get information about currently installed packages,"
elog "so please keep the eix metadata cache updated so puppet is able to properly"
elog "handle package installations."
elog
elog "Currently puppet only supports adding and removing services to the default"
elog "runlevel, if you want to add/remove a service from another runlevel you may"
elog "do so using symlinking."
elog
if [ \
-f "${ROOT}/etc/puppet/puppetd.conf" -o \
-f "${ROOT}/etc/puppet/puppetmaster.conf" -o \
-f "${ROOT}/etc/puppet/puppetca.conf" \
] ; then
elog
elog "Please remove deprecated config files."
elog " /etc/puppet/puppetca.conf"
elog " /etc/puppet/puppetd.conf"
elog " /etc/puppet/puppetmasterd.conf"
elog
fi
use emacs && elisp-site-regen
}
pkg_postrm() {
use emacs && elisp-site-regen
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2010-02-28 3:04 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2010-02-28 3:04 [gentoo-commits] gentoo-x86 commit in app-admin/puppet: ChangeLog puppet-0.25.4.ebuild Matsuu Takuto (matsuu)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox