[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-epgsearch: ChangeLog vdr-epgsearch-0.9.25_beta16.ebuild

["Joerg Bornkessel (hd_brummy)" <hd_brummy@gentoo.org>]

hd_brummy    10/02/07 13:48:23

  Modified:             ChangeLog
  Added:                vdr-epgsearch-0.9.25_beta16.ebuild
  Log:
  new beta
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.45                 media-plugins/vdr-epgsearch/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	17 Jul 2009 06:51:05 -0000	1.44
+++ ChangeLog	7 Feb 2010 13:48:22 -0000	1.45
@@ -1,6 +1,13 @@
 # ChangeLog for media-plugins/vdr-epgsearch
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog,v 1.44 2009/07/17 06:51:05 zzam Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/ChangeLog,v 1.45 2010/02/07 13:48:22 hd_brummy Exp $
+
+*vdr-epgsearch-0.9.25_beta16 (07 Feb 2010)
+
+  07 Feb 2010; Joerg Bornkessel <hd_brummy@gentoo.org>
+  +vdr-epgsearch-0.9.25_beta16.ebuild,
+  +files/vdr-epgsearch-0.9.25_beta16_missing-include.diff:
+  new beta
 
 *vdr-epgsearch-0.9.25_beta14 (17 Jul 2009)
 



1.1                  media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta16.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta16.ebuild?rev=1.1&content-type=text/plain

Index: vdr-epgsearch-0.9.25_beta16.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-epgsearch/vdr-epgsearch-0.9.25_beta16.ebuild,v 1.1 2010/02/07 13:48:22 hd_brummy Exp $

EAPI="2"

inherit vdr-plugin

DESCRIPTION="Video Disk Recorder epgsearch plugin"
HOMEPAGE="http://winni.vdr-developer.org/epgsearch"

case ${P#*_} in
	rc*|beta*)
		MY_P="${P/_/.}"
		SRC_URI="http://winni.vdr-developer.org/epgsearch/downloads/beta/${MY_P}.tgz"
		S="${WORKDIR}/${MY_P#vdr-}"
		;;
	*)
		SRC_URI="http://winni.vdr-developer.org/epgsearch/downloads/${P}.tgz"
		;;
esac

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="pcre tre"

DEPEND=">=media-video/vdr-1.3.45
	pcre? ( dev-libs/libpcre )
	tre? ( dev-libs/tre )"
RDEPEND="${DEPEND}"

src_prepare() {
	vdr-plugin_src_prepare

	cd "${S}"
	fix_vdr_libsi_include conflictcheck.c

	# disable automagic deps
	sed -i Makefile -e '/^AUTOCONFIG=/s/^/#/'

	if use pcre; then
		einfo "Using pcre for regexp searches"
		sed -i Makefile -e 's/^#HAVE_PCREPOSIX/HAVE_PCREPOSIX/'
	fi

	if use tre; then
		einfo "Using tre for unlimited fuzzy searches"
		sed -i Makefile -e 's/^#HAVE_LIBTRE/HAVE_LIBTRE/'
	fi

	# install conf-file disabled
	sed -e '/^Menu/s:^:#:' -i conf/epgsearchmenu.conf

	epatch "${FILESDIR}/${P}_missing-include.diff"
}

src_install() {
	vdr-plugin_src_install
	cd "${S}"
	diropts "-m755 -o vdr -g vdr"
	keepdir /etc/vdr/plugins/epgsearch
	insinto /etc/vdr/plugins/epgsearch

	doins conf/epgsearchmenu.conf
	doins conf/epgsearchconflmail.templ conf/epgsearchupdmail.templ

	dodoc conf/*.templ

	emake install-doc MANDIR="${D}/usr/share/man"
	dodoc MANUAL
}

pkg_preinst() {
	has_version "<${CATEGORY}/${PN}-0.9.18"
	previous_less_than_0_9_18=$?
}

pkg_postinst() {
	vdr-plugin_pkg_postinst
	if [[ $previous_less_than_0_9_18 = 0 ]] ; then
		elog "Moving config-files to new location /etc/vdr/plugins/epgsearch"
		cd "${ROOT}"/etc/vdr/plugins
		local f
		local moved=""
		for f in epgsearch*.* .epgsearch*; do
			[[ -e ${f} ]] || continue
			mv "${f}" "${ROOT}/etc/vdr/plugins/epgsearch"
			moved="${moved} ${f}"
		done
		elog "These files were moved:${moved}"
	fi
}