[gentoo-commits] gentoo-x86 commit in x11-libs/pango: ChangeLog pango-1.26.2.ebuild

["Gilles Dartiguelongue (eva)" <eva@gentoo.org>]

eva         09/12/21 23:28:30

  Modified:             ChangeLog
  Added:                pango-1.26.2.ebuild
  Log:
  Version bump. Bug fixes.
  (Portage version: 2.2_rc60/cvs/Linux x86_64)

Revision  Changes    Path
1.280                x11-libs/pango/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/pango/ChangeLog?rev=1.280&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/pango/ChangeLog?rev=1.280&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/pango/ChangeLog?r1=1.279&r2=1.280

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/pango/ChangeLog,v
retrieving revision 1.279
retrieving revision 1.280
diff -u -r1.279 -r1.280
--- ChangeLog	28 Nov 2009 17:39:38 -0000	1.279
+++ ChangeLog	21 Dec 2009 23:28:30 -0000	1.280
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/pango
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/pango/ChangeLog,v 1.279 2009/11/28 17:39:38 remi Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/pango/ChangeLog,v 1.280 2009/12/21 23:28:30 eva Exp $
+
+*pango-1.26.2 (21 Dec 2009)
+
+  21 Dec 2009; Gilles Dartiguelongue <eva@gentoo.org> +pango-1.26.2.ebuild:
+  Version bump. Bug fixes.
 
   28 Nov 2009; Rémi Cardona <remi@gentoo.org> pango-1.24.5-r1.ebuild,
   pango-1.26.0.ebuild:



1.1                  x11-libs/pango/pango-1.26.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/pango/pango-1.26.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/pango/pango-1.26.2.ebuild?rev=1.1&content-type=text/plain

Index: pango-1.26.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/pango/pango-1.26.2.ebuild,v 1.1 2009/12/21 23:28:30 eva Exp $

EAPI="2"
GCONF_DEBUG="yes"

inherit autotools eutils gnome2 multilib

DESCRIPTION="Internationalized text layout and rendering library"
HOMEPAGE="http://www.pango.org/"

LICENSE="LGPL-2 FTL"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="X doc test"

RDEPEND=">=dev-libs/glib-2.17.3
	>=media-libs/fontconfig-2.5.0
	media-libs/freetype:2
	>=x11-libs/cairo-1.7.6[X?]
	X? (
		x11-libs/libXrender
		x11-libs/libX11
		x11-libs/libXft )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9
	dev-util/gtk-doc-am
	doc? (
		>=dev-util/gtk-doc-1
		~app-text/docbook-xml-dtd-4.1.2
		x11-libs/libXft )
	test? (
		>=dev-util/gtk-doc-1
		~app-text/docbook-xml-dtd-4.1.2
		x11-libs/libXft )
	X? ( x11-proto/xproto )"

DOCS="AUTHORS ChangeLog* NEWS README THANKS"

function multilib_enabled() {
	has_multilib_profile || ( use x86 && [ "$(get_libdir)" = "lib32" ] )
}

pkg_setup() {
	# XXX: DO NOT add introspection support, collides with gir-repository[pango]
	G2CONF="${G2CONF}
		--disable-introspection
		$(use_with X x)"
}

src_prepare() {
	gnome2_src_prepare

	# make config file location host specific so that a 32bit and 64bit pango
	# wont fight with each other on a multilib system.  Fix building for
	# emul-linux-x86-gtklibs
	if multilib_enabled ; then
		epatch "${FILESDIR}/${PN}-1.26.0-lib64.patch"
	fi

	# gtk-doc checks do not pass, upstream bug #578944
	sed -e 's:TESTS = check.docs: TESTS = :g' \
		-i docs/Makefile.am || die "sed failed"

	# Fix introspection automagic.
	# https://bugzilla.gnome.org/show_bug.cgi?id=596506
	epatch "${FILESDIR}/${PN}-1.26.0-introspection-automagic.patch"

	eautoreconf
}

pkg_postinst() {
	if [ "${ROOT}" = "/" ] ; then
		einfo "Generating modules listing..."

		local PANGO_CONFDIR=

		if multilib_enabled ; then
			PANGO_CONFDIR="/etc/pango/${CHOST}"
		else
			PANGO_CONFDIR="/etc/pango"
		fi

		mkdir -p ${PANGO_CONFDIR}

		pango-querymodules > ${PANGO_CONFDIR}/pango.modules
	fi
}