* [gentoo-commits] gentoo-x86 commit in kde-base/kdelibs: ChangeLog kdelibs-4.3.3-r1.ebuild kdelibs-4.3.3.ebuild
@ 2009-11-28 20:38 Tomas Chvatal (scarabeus)
0 siblings, 0 replies; only message in thread
From: Tomas Chvatal (scarabeus) @ 2009-11-28 20:38 UTC (permalink / raw
To: gentoo-commits
scarabeus 09/11/28 20:38:55
Modified: ChangeLog
Added: kdelibs-4.3.3-r1.ebuild
Removed: kdelibs-4.3.3.ebuild
Log:
Revision bump. Apply the plasma-pixmap-cache fix.
(Portage version: 2.2_rc53/cvs/Linux x86_64)
Revision Changes Path
1.644 kde-base/kdelibs/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/ChangeLog?rev=1.644&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/ChangeLog?rev=1.644&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/ChangeLog?r1=1.643&r2=1.644
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v
retrieving revision 1.643
retrieving revision 1.644
diff -u -r1.643 -r1.644
--- ChangeLog 20 Nov 2009 18:47:59 -0000 1.643
+++ ChangeLog 28 Nov 2009 20:38:55 -0000 1.644
@@ -1,6 +1,13 @@
# ChangeLog for kde-base/kdelibs
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.643 2009/11/20 18:47:59 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/ChangeLog,v 1.644 2009/11/28 20:38:55 scarabeus Exp $
+
+*kdelibs-4.3.3-r1 (28 Nov 2009)
+
+ 28 Nov 2009; Tomáš Chvátal <scarabeus@gentoo.org>
+ -kdelibs-4.3.3.ebuild, +kdelibs-4.3.3-r1.ebuild,
+ +files/kdelibs-4.3.3-plasma-pixmap-cache.patch:
+ Revision bump. Apply the plasma-pixmap-cache fix.
20 Nov 2009; Jonathan Callen <abcd@gentoo.org> kdelibs-3.5.10-r6.ebuild:
Switch to EAPI=2 to add a USE dep
1.1 kde-base/kdelibs/kdelibs-4.3.3-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/kdelibs-4.3.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kdelibs/kdelibs-4.3.3-r1.ebuild?rev=1.1&content-type=text/plain
Index: kdelibs-4.3.3-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kdelibs/kdelibs-4.3.3-r1.ebuild,v 1.1 2009/11/28 20:38:55 scarabeus Exp $
EAPI="2"
CPPUNIT_REQUIRED="optional"
OPENGL_REQUIRED="optional"
WEBKIT_REQUIRED="always"
inherit kde4-base fdo-mime
DESCRIPTION="KDE libraries needed by all KDE programs."
HOMEPAGE="http://www.kde.org/"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
LICENSE="LGPL-2.1"
IUSE="3dnow acl alsa altivec bindist +bzip2 debug doc fam +handbook jpeg2k kerberos
lzma mmx nls openexr +semantic-desktop spell sse sse2 ssl zeroconf"
# needs the kate regression testsuite from svn
RESTRICT="test"
COMMONDEPEND="
>=app-misc/strigi-0.6.3[dbus,qt4]
dev-libs/libpcre
dev-libs/libxml2
dev-libs/libxslt
>=kde-base/automoc-0.9.87
media-libs/fontconfig
media-libs/freetype:2
media-libs/giflib
media-libs/jpeg
media-libs/libpng
>=media-sound/phonon-4.4_pre[xcb]
sys-apps/dbus[X]
sys-libs/libutempter
sys-libs/zlib
x11-libs/libICE
x11-libs/libSM
x11-libs/libX11
x11-libs/libXau
x11-libs/libXcursor
x11-libs/libXdmcp
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXft
x11-libs/libXpm
x11-libs/libXrender
x11-libs/libXtst
>=x11-misc/shared-mime-info-0.60
acl? ( virtual/acl )
alsa? ( media-libs/alsa-lib )
bzip2? ( app-arch/bzip2 )
fam? ( virtual/fam )
jpeg2k? ( media-libs/jasper )
kerberos? ( virtual/krb5 )
lzma? ( app-arch/xz-utils )
openexr? (
media-libs/openexr
media-libs/ilmbase
)
semantic-desktop? ( >=dev-libs/soprano-2.3.0[dbus] )
spell? (
app-dicts/aspell-en
app-text/aspell
app-text/enchant
)
ssl? ( dev-libs/openssl )
zeroconf? (
|| (
net-dns/avahi[mdnsresponder-compat]
!bindist? ( net-misc/mDNSResponder )
)
)
"
DEPEND="${COMMONDEPEND}
doc? ( app-doc/doxygen )
nls? ( virtual/libintl )
"
RDEPEND="${COMMONDEPEND}
!<=kde-misc/kdnssd-avahi-0.1.2:0
!x11-libs/qt-phonon
>=app-crypt/gnupg-2.0.11
x11-apps/iceauth
x11-apps/rgb
>=x11-misc/xdg-utils-1.0.2-r3
"
PDEPEND="
$(add_kdebase_dep kde-env)
$(add_kdebase_dep kdebase-data)
$(add_kdebase_dep ktimezoned)
"
# Blockers added due to packages from old versions, removed in the meanwhile
# as well as for file collisions
add_blocker kitchensync 4.1.50
add_blocker knewsticker 4.1.50
add_blocker kpercentage 4.1.50
add_blocker ktnef 4.1.50
add_blocker libkworkspace 4.2.50
add_blocker libplasma
# Block some old versions of KDE-3.5 packages that don't work well with KDE-4
add_blocker kdebase 0 3.5.9-r4:3.5
add_blocker kdebase-startkde 0 3.5.10:3.5
add_blocker kdelibs 0 '<3.5.10'
PATCHES=(
"${FILESDIR}/dist/01_gentoo_set_xdg_menu_prefix.patch"
"${FILESDIR}/dist/02_gentoo_append_xdg_config_dirs.patch"
"${FILESDIR}/dist/23_solid_no_double_build.patch"
"${FILESDIR}/${P}-glibc-2.11.patch"
"${FILESDIR}/${P}-plasma-pixmap-cache.patch"
)
src_prepare() {
kde4-base_src_prepare
# Rename applications.menu (needs 01_gentoo_set_xdg_menu_prefix.patch to work)
local menu_prefix="kde-${SLOT}-"
sed -e "s|FILES[[:space:]]applications.menu|FILES applications.menu RENAME ${menu_prefix}applications.menu|g" \
-i kded/CMakeLists.txt || die "Sed on CMakeLists.txt for applications.menu failed."
sed -e "s|@REPLACE_MENU_PREFIX@|${menu_prefix}|" \
-i kded/vfolder_menu.cpp || die "Sed on vfolder_menu.cpp failed."
# FIXME Remove experimental folder from CMakeLists - we have
# kde-base/libknotificationitem for now
sed -e "/macro_optional_add_subdirectory( experimental )/ s:^:#:" \
-i CMakeLists.txt || die "Failed to sed-out experimental."
}
src_configure() {
if use zeroconf; then
if has_version net-dns/avahi; then
mycmakeargs="${mycmakeargs} -DWITH_Avahi=ON -DWITH_DNSSD=OFF"
elif has_version net-misc/mDNSResponder; then
mycmakeargs="${mycmakeargs} -DWITH_Avahi=OFF -DWITH_DNSSD=ON"
else
die "USE=\"zeroconf\" enabled but neither net-dns/avahi nor net-misc/mDNSResponder were found."
fi
else
mycmakeargs="${mycmakeargs} -DWITH_Avahi=OFF -DWITH_DNSSD=OFF"
fi
if use kdeprefix; then
HME=".kde${SLOT}"
else
HME=".kde4"
fi
mycmakeargs="${mycmakeargs}
-DWITH_HSPELL=OFF
-DKDE_DEFAULT_HOME=${HME}
$(cmake-utils_use_build handbook doc)
$(cmake-utils_use_has 3dnow X86_3DNOW)
$(cmake-utils_use_has altivec PPC_ALTIVEC)
$(cmake-utils_use_has mmx X86_MMX)
$(cmake-utils_use_has sse X86_SSE)
$(cmake-utils_use_has sse2 X86_SSE2)
$(cmake-utils_use_with acl)
$(cmake-utils_use_with alsa)
$(cmake-utils_use_with bzip2 BZip2)
$(cmake-utils_use_with fam)
$(cmake-utils_use_with jpeg2k Jasper)
$(cmake-utils_use_with kerberos GSSAPI)
$(cmake-utils_use_with lzma LibLZMA)
$(cmake-utils_use_with nls Libintl)
$(cmake-utils_use_with openexr OpenEXR)
$(cmake-utils_use_with opengl OpenGL)
$(cmake-utils_use_with semantic-desktop Soprano)
$(cmake-utils_use_with spell ASPELL)
$(cmake-utils_use_with spell ENCHANT)
$(cmake-utils_use_with ssl OpenSSL)
"
kde4-base_src_configure
}
src_compile() {
kde4-base_src_compile
# The building of apidox is not managed anymore by the build system
if use doc; then
einfo "Building API documentation"
cd "${S}"/doc/api/
./doxygen.sh "${S}" || die "APIDOX generation failed"
fi
}
src_install() {
kde4-base_src_install
if use doc; then
einfo "Installing API documentation. This could take a bit of time."
cd "${S}"/doc/api/
docinto /HTML/en/kdelibs-apidox
dohtml -r ${P}-apidocs/* || die "Install phase of KDE4 API Documentation failed"
fi
}
pkg_postinst() {
fdo-mime_mime_database_update
if use zeroconf; then
echo
elog "To make zeroconf support available in KDE make sure that the 'mdnsd' daemon"
elog "is running. Make sure also that multicast dns lookups are enabled by editing"
elog "the 'hosts:' line in /etc/nsswitch.conf to include 'mdns', e.g.:"
elog " hosts: files mdns dns"
echo
fi
elog "Your homedir is set to "'${HOME}'"/${HME}"
elog
local config_path="${ROOT}usr/share/config"
[[ ${PREFIX} != "${ROOT}usr" ]] && config_path+=" ${PREFIX}/share/config"
elog "If you experience weird application behavior (missing texts, etc.) run as root:"
elog "# chmod 755 -R ${config_path}"
kde4-base_pkg_postinst
}
pkg_prerm() {
# Remove ksycoca4 global database
rm -f "${PREFIX}"/share/kde4/services/ksycoca4
}
pkg_postrm() {
fdo-mime_mime_database_update
kde4-base_pkg_postrm
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2009-11-28 20:39 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-11-28 20:38 [gentoo-commits] gentoo-x86 commit in kde-base/kdelibs: ChangeLog kdelibs-4.3.3-r1.ebuild kdelibs-4.3.3.ebuild Tomas Chvatal (scarabeus)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox