* [gentoo-commits] gentoo-x86 commit in sys-libs/ncurses: ChangeLog ncurses-5.7-r2.ebuild
@ 2009-10-11 7:30 Mike Frysinger (vapier)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Frysinger (vapier) @ 2009-10-11 7:30 UTC (permalink / raw
To: gentoo-commits
vapier 09/10/11 07:30:29
Modified: ChangeLog
Added: ncurses-5.7-r2.ebuild
Log:
Add fix from upstream for db issues #245370 by Graham Murray. Fix cross-compiling hang with tic and older ncurses #249363.
(Portage version: 2.2_rc42/cvs/Linux x86_64)
Revision Changes Path
1.165 sys-libs/ncurses/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ChangeLog?rev=1.165&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ChangeLog?rev=1.165&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ChangeLog?r1=1.164&r2=1.165
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ChangeLog,v
retrieving revision 1.164
retrieving revision 1.165
diff -u -r1.164 -r1.165
--- ChangeLog 11 Oct 2009 05:38:15 -0000 1.164
+++ ChangeLog 11 Oct 2009 07:30:28 -0000 1.165
@@ -1,6 +1,13 @@
# ChangeLog for sys-libs/ncurses
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ChangeLog,v 1.164 2009/10/11 05:38:15 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ChangeLog,v 1.165 2009/10/11 07:30:28 vapier Exp $
+
+*ncurses-5.7-r2 (11 Oct 2009)
+
+ 11 Oct 2009; Mike Frysinger <vapier@gentoo.org> +ncurses-5.7-r2.ebuild,
+ +files/ncurses-5.7-hashdb-open.patch:
+ Add fix from upstream for db issues #245370 by Graham Murray. Fix
+ cross-compiling hang with tic and older ncurses #249363.
11 Oct 2009; Mike Frysinger <vapier@gentoo.org> ncurses-5.6-r2.ebuild:
Force gawk #259510 by Linubie.
1.1 sys-libs/ncurses/ncurses-5.7-r2.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild?rev=1.1&content-type=text/plain
Index: ncurses-5.7-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild,v 1.1 2009/10/11 07:30:28 vapier Exp $
EAPI="1"
inherit eutils flag-o-matic toolchain-funcs
MY_PV=${PV:0:3}
PV_SNAP=${PV:4}
MY_P=${PN}-${MY_PV}
DESCRIPTION="console display library"
HOMEPAGE="http://www.gnu.org/software/ncurses/ http://dickey.his.com/ncurses/"
SRC_URI="mirror://gnu/ncurses/${MY_P}.tar.gz"
LICENSE="MIT"
SLOT="5"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="ada +cxx debug doc gpm minimal profile trace unicode"
DEPEND="gpm? ( sys-libs/gpm )"
# berkdb? ( sys-libs/db )"
S=${WORKDIR}/${MY_P}
src_unpack() {
unpack ${A}
cd "${S}"
[[ -n ${PV_SNAP} ]] && epatch "${WORKDIR}"/${MY_P}-${PV_SNAP}-patch.sh
epatch "${FILESDIR}"/${PN}-5.6-gfbsd.patch
epatch "${FILESDIR}"/${PN}-5.7-emacs.patch #270527
epatch "${FILESDIR}"/${PN}-5.7-nongnu.patch
epatch "${FILESDIR}"/${P}-hashdb-open.patch #245370
}
src_compile() {
unset TERMINFO #115036
tc-export BUILD_CC
export BUILD_CPPFLAGS+=" -D_GNU_SOURCE" #214642
# when cross-compiling, we need to build up our own tic
# because people often don't keep matching host/target
# ncurses versions #249363
if tc-is-cross-compiler ; then
make_flags="-C progs tic"
CHOST=${CBUILD} \
CFLAGS=${BUILD_CFLAGS} \
CXXFLAGS=${BUILD_CXXFLAGS} \
CPPFLAGS=${BUILD_CPPFLAGS} \
LDFLAGS="${BUILD_LDFLAGS} -static" \
do_compile cross --without-shared
fi
make_flags=""
do_compile narrowc
use unicode && do_compile widec --enable-widec --includedir=/usr/include/ncursesw
}
do_compile() {
ECONF_SOURCE=${S}
mkdir "${WORKDIR}"/$1
cd "${WORKDIR}"/$1
shift
# The chtype/mmask-t settings below are to retain ABI compat
# with ncurses-5.4 so dont change em !
local conf_abi="
--with-chtype=long \
--with-mmask-t=long \
--disable-ext-colors \
--disable-ext-mouse \
--without-pthread \
--without-reentrant \
"
# We need the basic terminfo files in /etc, bug #37026. We will
# add '--with-terminfo-dirs' and then populate /etc/terminfo in
# src_install() ...
# $(use_with berkdb hashed-db)
econf \
--libdir="/$(get_libdir)" \
--with-terminfo-dirs="/etc/terminfo:/usr/share/terminfo" \
--with-shared \
--without-hashed-db \
$(use_with ada) \
$(use_with cxx) \
$(use_with cxx cxx-binding) \
$(use_with debug) \
$(use_with profile) \
$(use_with gpm) \
--disable-termcap \
--enable-symlinks \
--with-rcs-ids \
--with-manpage-format=normal \
--enable-const \
--enable-colorfgbg \
--enable-echo \
$(use_enable !ada warnings) \
$(use_with debug assertions) \
$(use_with !debug leaks) \
$(use_with debug expanded) \
$(use_with !debug macros) \
$(use_with trace) \
${conf_abi} \
"$@" \
|| die "configure failed"
# A little hack to fix parallel builds ... they break when
# generating sources so if we generate the sources first (in
# non-parallel), we can then build the rest of the package
# in parallel. This is not really a perf hit since the source
# generation is quite small. -vapier
emake -j1 sources || die "make sources failed"
emake ${make_flags} || die "make ${make_flags} failed"
}
src_install() {
# use the cross-compiled tic (if need be) #249363
export PATH=${WORKDIR}/cross/progs:${PATH}
# install unicode version second so that the binaries in /usr/bin
# support both wide and narrow
cd "${WORKDIR}"/narrowc
emake DESTDIR="${D}" install || die "make narrowc install failed"
if use unicode ; then
cd "${WORKDIR}"/widec
emake DESTDIR="${D}" install || die "make widec install failed"
fi
# Move static and extraneous ncurses libraries out of /lib
dodir /usr/$(get_libdir)
cd "${D}"/$(get_libdir)
mv lib{form,menu,panel}.so* *.a "${D}"/usr/$(get_libdir)/
gen_usr_ldscript lib{,n}curses.so
if use unicode ; then
mv lib{form,menu,panel}w.so* "${D}"/usr/$(get_libdir)/
gen_usr_ldscript libncursesw.so
fi
# if ! use berkdb ; then
# We need the basic terminfo files in /etc, bug #37026
einfo "Installing basic terminfo files in /etc..."
for x in ansi console dumb linux rxvt screen sun vt{52,100,102,200,220} \
xterm xterm-color xterm-xfree86
do
local termfile=$(find "${D}"/usr/share/terminfo/ -name "${x}" 2>/dev/null)
local basedir=$(basename $(dirname "${termfile}"))
if [[ -n ${termfile} ]] ; then
dodir /etc/terminfo/${basedir}
mv ${termfile} "${D}"/etc/terminfo/${basedir}/
dosym ../../../../etc/terminfo/${basedir}/${x} \
/usr/share/terminfo/${basedir}/${x}
fi
done
# Build fails to create this ...
dosym ../share/terminfo /usr/$(get_libdir)/terminfo
# fi
echo "CONFIG_PROTECT_MASK=\"/etc/terminfo\"" > "${T}"/50ncurses
doenvd "${T}"/50ncurses
use minimal && rm -r "${D}"/usr/share/terminfo*
# Because ncurses5-config --terminfo returns the directory we keep it
keepdir /usr/share/terminfo #245374
cd "${S}"
dodoc ANNOUNCE MANIFEST NEWS README* TO-DO doc/*.doc
use doc && dohtml -r doc/html/
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sys-libs/ncurses: ChangeLog ncurses-5.7-r2.ebuild
@ 2009-10-22 12:30 Mike Frysinger (vapier)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Frysinger (vapier) @ 2009-10-22 12:30 UTC (permalink / raw
To: gentoo-commits
vapier 09/10/22 12:30:59
Modified: ChangeLog ncurses-5.7-r2.ebuild
Log:
Fix up ncurses tic script to better detect cross-compiling #288881 by Sergiy Borodych.
(Portage version: 2.2_rc46/cvs/Linux x86_64)
Revision Changes Path
1.166 sys-libs/ncurses/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ChangeLog?rev=1.166&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ChangeLog?rev=1.166&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ChangeLog?r1=1.165&r2=1.166
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ChangeLog,v
retrieving revision 1.165
retrieving revision 1.166
diff -u -r1.165 -r1.166
--- ChangeLog 11 Oct 2009 07:30:28 -0000 1.165
+++ ChangeLog 22 Oct 2009 12:30:58 -0000 1.166
@@ -1,6 +1,11 @@
# ChangeLog for sys-libs/ncurses
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ChangeLog,v 1.165 2009/10/11 07:30:28 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ChangeLog,v 1.166 2009/10/22 12:30:58 vapier Exp $
+
+ 22 Oct 2009; Mike Frysinger <vapier@gentoo.org> ncurses-5.7-r2.ebuild,
+ +files/ncurses-5.7-tic-cross-detection.patch:
+ Fix up ncurses tic script to better detect cross-compiling #288881 by
+ Sergiy Borodych.
*ncurses-5.7-r2 (11 Oct 2009)
1.2 sys-libs/ncurses/ncurses-5.7-r2.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild?r1=1.1&r2=1.2
Index: ncurses-5.7-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ncurses-5.7-r2.ebuild 11 Oct 2009 07:30:28 -0000 1.1
+++ ncurses-5.7-r2.ebuild 22 Oct 2009 12:30:58 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild,v 1.1 2009/10/11 07:30:28 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/ncurses/ncurses-5.7-r2.ebuild,v 1.2 2009/10/22 12:30:58 vapier Exp $
EAPI="1"
inherit eutils flag-o-matic toolchain-funcs
@@ -29,6 +29,7 @@
epatch "${FILESDIR}"/${PN}-5.6-gfbsd.patch
epatch "${FILESDIR}"/${PN}-5.7-emacs.patch #270527
epatch "${FILESDIR}"/${PN}-5.7-nongnu.patch
+ epatch "${FILESDIR}"/${PN}-5.7-tic-cross-detection.patch #288881
epatch "${FILESDIR}"/${P}-hashdb-open.patch #245370
}
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2009-10-22 12:31 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-10-22 12:30 [gentoo-commits] gentoo-x86 commit in sys-libs/ncurses: ChangeLog ncurses-5.7-r2.ebuild Mike Frysinger (vapier)
-- strict thread matches above, loose matches on Subject: below --
2009-10-11 7:30 Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox