* [gentoo-commits] gentoo-x86 commit in sci-libs/plplot: plplot-5.9.4.ebuild ChangeLog
@ 2009-08-25 2:59 Markus Dittrich (markusle)
0 siblings, 0 replies; 2+ messages in thread
From: Markus Dittrich (markusle) @ 2009-08-25 2:59 UTC (permalink / raw
To: gentoo-commits
markusle 09/08/25 02:59:51
Modified: ChangeLog
Added: plplot-5.9.4.ebuild
Log:
Version bump.
(Portage version: 2.1.6.13/cvs/Linux x86_64)
Revision Changes Path
1.22 sci-libs/plplot/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/ChangeLog?r1=1.21&r2=1.22
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog 14 Mar 2009 13:57:15 -0000 1.21
+++ ChangeLog 25 Aug 2009 02:59:51 -0000 1.22
@@ -1,6 +1,11 @@
# ChangeLog for sci-libs/plplot
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v 1.21 2009/03/14 13:57:15 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v 1.22 2009/08/25 02:59:51 markusle Exp $
+
+*plplot-5.9.4 (25 Aug 2009)
+
+ 25 Aug 2009; Markus Dittrich <markusle@gentoo.org> +plplot-5.9.4.ebuild:
+ Version bump.
14 Mar 2009; Sébastien Fabbro <bicatali@gentoo.org> -plplot-5.9.0.ebuild,
plplot-5.9.2.ebuild:
1.1 sci-libs/plplot/plplot-5.9.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild?rev=1.1&content-type=text/plain
Index: plplot-5.9.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild,v 1.1 2009/08/25 02:59:51 markusle Exp $
EAPI="2"
WX_GTK_VER="2.8"
inherit eutils fortran cmake-utils wxwidgets java-pkg-opt-2
DESCRIPTION="Multi-language scientific plotting library"
HOMEPAGE="http://plplot.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ada cairo doc examples fortran gd gnome java jpeg latex octave
pdf perl png python qhull svg svga tcl threads tk truetype wxwindows X"
RDEPEND="ada? ( virtual/gnat )
cairo? ( x11-libs/cairo[svg?,X?] )
java? ( >=virtual/jre-1.5 )
gd? ( media-libs/gd[jpeg?,png?] )
gnome? ( gnome-base/libgnomeui
gnome-base/libgnomeprintui
python? ( dev-python/gnome-python ) )
latex? ( virtual/latex-base virtual/ghostscript )
octave? ( >=sci-mathematics/octave-3 )
pdf? ( media-libs/libharu )
perl? ( dev-perl/PDL dev-perl/XML-DOM )
python? ( dev-python/numpy )
svga? ( media-libs/svgalib )
tcl? ( dev-lang/tcl dev-tcltk/itcl )
tk? ( dev-lang/tk dev-tcltk/itk )
truetype? ( media-fonts/freefont-ttf
media-libs/lasi
gd? ( media-libs/gd[truetype] ) )
wxwindows? ( x11-libs/wxGTK:2.8[X] x11-libs/agg )
X? ( x11-libs/libX11 x11-libs/libXau x11-libs/libXdmcp )"
DEPEND="${RDEPEND}
>=dev-util/cmake-2.6
dev-util/pkgconfig
doc? ( app-text/opensp
app-text/jadetex
app-text/docbook2X
app-text/docbook-dsssl-stylesheets
dev-perl/XML-DOM
virtual/latex-base
virtual/ghostscript
sys-apps/texinfo )
java? ( >=virtual/jdk-1.5 dev-lang/swig )
python? ( dev-lang/swig )
qhull? ( media-libs/qhull )"
pkg_setup() {
if use fortran; then
FORTRAN="gfortran ifc g77"
fortran_pkg_setup
fi
export FC=${FORTRANC} F77=${FORTRANC}
wxwidgets_pkg_setup
}
src_prepare() {
# path for python independent of python version
epatch "${FILESDIR}"/${PN}-5.9.0-python.patch
# remove license
sed -i -e '/COPYING.LIB/d' CMakeLists.txt || die
# change default install directories for doc and examples
sed -i \
-e 's:${DATA_DIR}/examples:${DOC_DIR}/examples:g' \
examples/CMakeLists.txt examples/*/CMakeLists.txt || die
sed -i \
-e 's:${VERSION}::g' \
-e "s:doc/\${PACKAGE}:doc/${PF}:" \
cmake/modules/instdirs.cmake || die
# haru pdf devide does not build with HPDF_SHARED
sed -i \
-e 's:-DHPDF_SHARED::' \
cmake/modules/pdf.cmake || die
# default location for docbook crap
sed -i \
-e 's:xml/declaration:sgml:' \
cmake/modules/docbook.cmake || die
}
src_configure() {
# see http://www.miscdebris.net/plplot_wiki/index.php?title=CMake_options_for_PLplot
cmake-utils_pld() { _use_me_now PLD "$@" ; }
mycmakeargs="
-DUSE_RPATH=OFF
-DDEFAULT_ALL_DEVICES=ON
-DCMAKE_INSTALL_LIBDIR=/usr/$(get_libdir)
$(cmake-utils_has python numpy)
$(cmake-utils_has qhull QHULL)
$(cmake-utils_has threads PTHREAD)
$(cmake-utils_has truetype FREETYPE)
$(cmake-utils_use_enable ada ada)
$(cmake-utils_use_enable fortran f77)
$(cmake-utils_use_enable java java)
$(cmake-utils_use_enable gnome gnome2)
$(cmake-utils_use_enable octave octave)
$(cmake-utils_use_enable perl pdl)
$(cmake-utils_use_enable python python)
$(cmake-utils_use_enable tcl tcl)
$(cmake-utils_use_enable tcl itcl)
$(cmake-utils_use_enable tk tk)
$(cmake-utils_use_enable tk itk)
$(cmake-utils_use_enable wxwindows wxwidgets)
$(cmake-utils_pld pdf pdf)
$(cmake-utils_pld truetype psttf)
$(cmake-utils_pld latex pstex)
$(cmake-utils_pld svga linuxvga)"
use fortran && [[ ${FORTRANC} != g77 ]] && \
mycmakeargs="${mycmakeargs} $(cmake-utils_use_enable fortran f95)"
use truetype && mycmakeargs="${mycmakeargs}
-DPL_FREETYPE_FONT_PATH:PATH=/usr/share/fonts/freefont-ttf"
if use python && use gnome; then
mycmakeargs="${mycmakeargs} -DENABLE_pygcw=ON"
else
mycmakeargs="${mycmakeargs} -DENABLE_pygcw=OFF"
fi
if use cairo; then
# memcairo buggy, see cmake/modules/drivers-init.cmake
mycmakeargs="${mycmakeargs}
-DPLD_memcairo=OFF
-DPLD_extcairo=OFF
-DPLD_pdfcairo=ON
-DPLD_pngcairo=ON
-DPLD_pscairo=ON
$(cmake-utils_pld svg svgcairo)
$(cmake-utils_pld X xcairo)"
else
mycmakeargs="${mycmakeargs}
-DPLD_memcairo=OFF
-DPLD_extcairo=OFF
-DPLD_pdfcairo=OFF
-DPLD_pngcairo=OFF
-DPLD_pscairo=OFF
-DPLD_svgcairo=OFF
-DPLD_xcairo=OFF"
fi
cmake-utils_src_configure
}
src_compile() {
# separate doc and normal because doc building crashes with parallel
cmake-utils_src_make
if use doc; then
mycmakeargs="${mycmakeargs} -DBUILD_DOC=ON"
mycmakeargs="${mycmakeargs} -DHAVE_DB_DTD=ON"
mycmakeargs="${mycmakeargs} -DHAVE_DSSSL_DTD=ON"
mycmakeargs="${mycmakeargs} -DHAVE_HTML_SS=ON"
mycmakeargs="${mycmakeargs} -DHAVE_PRINT_SS=ON"
cmake-utils_src_configure
cmake-utils_src_make -j1
fi
}
src_install() {
cmake-utils_src_install
use examples || rm -rf "${D}"usr/share/doc/${PF}/examples
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sci-libs/plplot: plplot-5.9.4.ebuild ChangeLog
@ 2009-09-02 14:28 Markus Dittrich (markusle)
0 siblings, 0 replies; 2+ messages in thread
From: Markus Dittrich (markusle) @ 2009-09-02 14:28 UTC (permalink / raw
To: gentoo-commits
markusle 09/09/02 14:28:54
Modified: plplot-5.9.4.ebuild ChangeLog
Log:
Fixed error due to missing pdf.rc reference file (see #282688).
(Portage version: 2.1.6.13/cvs/Linux x86_64)
Revision Changes Path
1.2 sci-libs/plplot/plplot-5.9.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild?r1=1.1&r2=1.2
Index: plplot-5.9.4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- plplot-5.9.4.ebuild 25 Aug 2009 02:59:51 -0000 1.1
+++ plplot-5.9.4.ebuild 2 Sep 2009 14:28:54 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild,v 1.1 2009/08/25 02:59:51 markusle Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/plplot-5.9.4.ebuild,v 1.2 2009/09/02 14:28:54 markusle Exp $
EAPI="2"
WX_GTK_VER="2.8"
@@ -66,6 +66,9 @@
# path for python independent of python version
epatch "${FILESDIR}"/${PN}-5.9.0-python.patch
+ # we're missing the proper reference file pdf.rc
+ epatch "${FILESDIR}"/${P}-pdf-driver.patch
+
# remove license
sed -i -e '/COPYING.LIB/d' CMakeLists.txt || die
@@ -91,7 +94,6 @@
src_configure() {
# see http://www.miscdebris.net/plplot_wiki/index.php?title=CMake_options_for_PLplot
-
cmake-utils_pld() { _use_me_now PLD "$@" ; }
mycmakeargs="
1.23 sci-libs/plplot/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/plplot/ChangeLog?r1=1.22&r2=1.23
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog 25 Aug 2009 02:59:51 -0000 1.22
+++ ChangeLog 2 Sep 2009 14:28:54 -0000 1.23
@@ -1,6 +1,10 @@
# ChangeLog for sci-libs/plplot
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v 1.22 2009/08/25 02:59:51 markusle Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/plplot/ChangeLog,v 1.23 2009/09/02 14:28:54 markusle Exp $
+
+ 02 Sep 2009; Markus Dittrich <markusle@gentoo.org> plplot-5.9.4.ebuild,
+ +files/plplot-5.9.4-pdf-driver.patch:
+ Fixed error due to missing pdf.rc reference file (see #282688).
*plplot-5.9.4 (25 Aug 2009)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2009-09-02 9:20 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-08-25 2:59 [gentoo-commits] gentoo-x86 commit in sci-libs/plplot: plplot-5.9.4.ebuild ChangeLog Markus Dittrich (markusle)
-- strict thread matches above, loose matches on Subject: below --
2009-09-02 14:28 Markus Dittrich (markusle)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox