[gentoo-commits] gentoo-x86 commit in dev-libs/icu: ChangeLog icu-4.2.1.ebuild

["Arfrever Frehtes Taifersar Arahesis (arfrever)" <arfrever@gentoo.org>]

arfrever    09/07/03 21:49:04

  Modified:             ChangeLog
  Added:                icu-4.2.1.ebuild
  Log:
  Version bump.
  (Portage version: 13767-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.89                 dev-libs/icu/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/ChangeLog?rev=1.89&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/ChangeLog?rev=1.89&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/ChangeLog?r1=1.88&r2=1.89

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v
retrieving revision 1.88
retrieving revision 1.89
diff -u -r1.88 -r1.89
--- ChangeLog	28 Jun 2009 16:57:03 -0000	1.88
+++ ChangeLog	3 Jul 2009 21:49:04 -0000	1.89
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/icu
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v 1.88 2009/06/28 16:57:03 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/ChangeLog,v 1.89 2009/07/03 21:49:04 arfrever Exp $
+
+*icu-4.2.1 (03 Jul 2009)
+
+  03 Jul 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +icu-4.2.1.ebuild:
+  Version bump.
 
   28 Jun 2009; Tobias Klausmann <klausman@gentoo.org> icu-4.2.ebuild:
   Stable on alpha, bug #275593



1.1                  dev-libs/icu/icu-4.2.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/icu-4.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/icu/icu-4.2.1.ebuild?rev=1.1&content-type=text/plain

Index: icu-4.2.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/icu/icu-4.2.1.ebuild,v 1.1 2009/07/03 21:49:04 arfrever Exp $

EAPI="2"

inherit eutils versionator

DESCRIPTION="International Components for Unicode"
HOMEPAGE="http://www.icu-project.org/ http://ibm.com/software/globalization/icu/"

BASEURI="http://download.icu-project.org/files/${PN}4c/${PV}"
DOCS_PV="$(get_version_component_range 1-2)"
DOCS_BASEURI="http://download.icu-project.org/files/${PN}4c/${DOCS_PV}"
DOCS_PV="${DOCS_PV/./_}"
SRCPKG="${PN}4c-${PV//./_}-src.tgz"
APIDOCS="${PN}4c-${DOCS_PV}-docs.zip"

SRC_URI="${BASEURI}/${SRCPKG}
	doc? ( ${DOCS_BASEURI}/${APIDOCS} )"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples"

DEPEND="doc? ( app-arch/unzip )"
RDEPEND=""

S="${WORKDIR}/${PN}/source"

src_unpack() {
	unpack ${SRCPKG}
	if use doc; then
		mkdir apidocs
		pushd apidocs > /dev/null
		unpack ${APIDOCS}
		popd > /dev/null
	fi
}

src_prepare() {
	# Do not hardcode used CFLAGS, LDFLAGS etc. into icu-config
	# Bug 202059
	# http://bugs.icu-project.org/trac/ticket/6102
	for x in ARFLAGS CFLAGS CPPFLAGS CXXFLAGS FFLAGS LDFLAGS; do
		sed -i -e "/^${x} =.*/s:@${x}@::" "config/Makefile.inc.in" || die "sed failed"
	done
}

src_configure() {
	econf \
		--enable-static \
		$(use_enable debug) \
		$(use_enable examples samples)
}

src_test() {
	emake check || die "emake check failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dohtml ../readme.html
	dodoc ../unicode-license.txt
	if use doc; then
		insinto /usr/share/doc/${PF}/html/apidocs
		doins -r "${WORKDIR}"/apidocs/*
	fi
}