[gentoo-commits] gentoo-x86 commit in sci-visualization/gnuplot: ChangeLog gnuplot-4.2.5-r1.ebuild

["Ulrich Mueller (ulm)" <ulm@gentoo.org>]

ulm         09/06/20 16:39:24

  Modified:             ChangeLog
  Added:                gnuplot-4.2.5-r1.ebuild
  Log:
  Fix "cb axis range undefined or overflow" error after fit, bug 274693.
  (Portage version: 2.2_rc33/cvs/Linux i686)

Revision  Changes    Path
1.106                sci-visualization/gnuplot/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/gnuplot/ChangeLog?rev=1.106&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/gnuplot/ChangeLog?rev=1.106&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/gnuplot/ChangeLog?r1=1.105&r2=1.106

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-visualization/gnuplot/ChangeLog,v
retrieving revision 1.105
retrieving revision 1.106
diff -u -r1.105 -r1.106
--- ChangeLog	18 Jun 2009 05:43:16 -0000	1.105
+++ ChangeLog	20 Jun 2009 16:39:24 -0000	1.106
@@ -1,6 +1,14 @@
 # ChangeLog for sci-visualization/gnuplot
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gnuplot/ChangeLog,v 1.105 2009/06/18 05:43:16 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gnuplot/ChangeLog,v 1.106 2009/06/20 16:39:24 ulm Exp $
+
+*gnuplot-4.2.5-r1 (20 Jun 2009)
+
+  20 Jun 2009; Ulrich Mueller <ulm@gentoo.org> +gnuplot-4.2.5-r1.ebuild,
+  +files/gnuplot-4.2.5-colorbox_accounting.patch:
+  Fix "cb axis range undefined or overflow" error after fit. Patch from
+  upstream, thanks to Christopher Schwan <cschwan@stamaonline.de> and
+  Ottxor <kleiner_otti@gmx.de>, bug 274693.
 
   18 Jun 2009; Jeroen Roovers <jer@gentoo.org> gnuplot-4.2.5.ebuild:
   Stable for HPPA (bug #274558).



1.1                  sci-visualization/gnuplot/gnuplot-4.2.5-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/gnuplot/gnuplot-4.2.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-visualization/gnuplot/gnuplot-4.2.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnuplot-4.2.5-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gnuplot/gnuplot-4.2.5-r1.ebuild,v 1.1 2009/06/20 16:39:24 ulm Exp $

EAPI=2
WX_GTK_VER="2.8"

inherit autotools elisp-common eutils multilib wxwidgets

MY_P="${P/_/.}"

DESCRIPTION="Command-line driven interactive plotting program"
HOMEPAGE="http://www.gnuplot.info/"
SRC_URI="mirror://sourceforge/gnuplot/${MY_P}.tar.gz
	mirror://gentoo/${P}-lua-term.patch.bz2"

LICENSE="gnuplot"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-fbsd"
IUSE="doc emacs gd ggi latex lua pdf plotutils readline svga wxwindows X xemacs"
RESTRICT="wxwindows? ( test )"

RDEPEND="
	xemacs? ( virtual/xemacs app-xemacs/texinfo app-xemacs/xemacs-base )
	emacs? ( virtual/emacs !app-emacs/gnuplot-mode )
	pdf? ( media-libs/pdflib )
	lua? ( >=dev-lang/lua-5.1 )
	ggi? ( media-libs/libggi )
	gd? ( >=media-libs/gd-2[png] )
	doc? ( virtual/latex-base
		virtual/ghostscript )
	latex? ( virtual/latex-base
		lua? ( dev-tex/pgf
			>=dev-texlive/texlive-latexrecommended-2008-r2 ) )
	X? ( x11-libs/libXaw )
	svga? ( media-libs/svgalib )
	readline? ( >=sys-libs/readline-4.2 )
	plotutils? ( media-libs/plotutils )
	wxwindows? ( =x11-libs/wxGTK-2.8*
		>=x11-libs/cairo-0.9
		>=x11-libs/pango-1.10.3
		>=x11-libs/gtk+-2.8 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_P}"
E_SITEFILE="50${PN}-gentoo.el"
TEXMF="/usr/share/texmf-site"

pkg_setup() {
	use wxwindows && wxwidgets_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-4.2.2-disable_texi_generation.patch #194216
	epatch "${FILESDIR}"/${PN}-4.2.3-app-defaults.patch #219323
	epatch "${FILESDIR}"/${PN}-4.2.3-disable-texhash.patch #201871
	epatch "${WORKDIR}"/${P}-lua-term.patch #233475
	epatch "${FILESDIR}"/${P}-configure-pkgconfig.patch #233475 c9
	epatch "${FILESDIR}"/${P}-colorbox_accounting.patch #274693
	# Add Gentoo version identification since the licence requires it
	epatch "${FILESDIR}"/${PN}-gentoo-version.patch

	eautoreconf
}

src_configure() {
	# See bug #156427.
	if use latex ; then
		sed -i -e "s:\`kpsexpand.*\`:${TEXMF}/tex/latex/${PN}:" \
			share/LaTeX/Makefile.in || die
	else
		sed -i \
			-e '/^SUBDIRS/ s/LaTeX//' share/LaTeX/Makefile.in || die
	fi

	local myconf="--with-gihdir=/usr/share/${PN}/gih"

	myconf="${myconf} $(use_with X x)"
	myconf="${myconf} $(use_with svga linux-vga)"
	myconf="${myconf} $(use_with gd)"
	myconf="${myconf} $(use_enable wxwindows wxwidgets)"
	myconf="${myconf} $(use_with plotutils plot /usr/$(get_libdir))"
	myconf="${myconf} $(use_with pdf pdf /usr/$(get_libdir))"
	myconf="${myconf} $(use_with lua)"
	myconf="${myconf} $(use_with doc tutorial)"

	use ggi \
		&& myconf="${myconf} --with-ggi=/usr/$(get_libdir)
		--with-xmi=/usr/$(get_libdir)" \
		|| myconf="${myconf} --without-ggi"

	use readline \
		&& myconf="${myconf} --with-readline=gnu --enable-history-file" \
		|| myconf="${myconf} --with-readline"

	myconf="${myconf} --without-lisp-files"

	TEMACS=no
	use xemacs && TEMACS=xemacs
	use emacs && TEMACS=emacs

	CFLAGS="${CFLAGS} -DGENTOO_REVISION=\\\"${PR}\\\"" \
	EMACS=${TEMACS} \
		econf ${myconf} || die
}

src_compile() {
	# Prevent access violations, see bug 201871
	VARTEXFONTS="${T}/fonts"

	# This is a hack to avoid sandbox violations when using the Linux console.
	# Creating the DVI and PDF tutorials require /dev/svga to build the
	# example plots.
	addwrite /dev/svga:/dev/mouse:/dev/tts/0

	emake || die

	if use doc ; then
		cd docs
		emake pdf || die
		cd ../tutorial
		emake pdf || die
	fi
}

src_install () {
	emake DESTDIR="${D}" install || die

	if use emacs; then
		cd lisp
		einfo "Configuring gnuplot-mode for GNU Emacs..."
		EMACS="emacs" econf --with-lispdir="${SITELISP}/${PN}" || die
		emake DESTDIR="${D}" install || die
		emake clean
		cd ..

		# Gentoo emacs site-lisp configuration
		echo -e "\n;;; ${PN} site-lisp configuration\n" > ${E_SITEFILE}
		echo -e "(add-to-list 'load-path \"@SITELISP@\")\n" >> ${E_SITEFILE}
		sed '/^;; move/,+3 d' lisp/dotemacs >> ${E_SITEFILE}
		elisp-site-file-install ${E_SITEFILE}
	fi

	if use xemacs; then
		cd lisp
		einfo "Configuring gnuplot-mode for XEmacs..."
		EMACS="xemacs" \
			econf --with-lispdir="/usr/lib/xemacs/site-packages/${PN}" || die
		emake DESTDIR="${D}" install || die
		cd ..
	fi

	if use latex && use lua; then
		# install style file in an (additional) place where TeX can find it
		insinto "${TEXMF}/tex/latex/${PN}"
		doins term/lua/gnuplot-lua-tikz.sty || die
	fi

	dodoc BUGS ChangeLog FAQ NEWS PATCHLEVEL PGPKEYS PORTING README* \
		TODO VERSION
	use lua && newdoc term/lua/README README-lua

	if use doc; then
		# Demo files
		insinto /usr/share/${PN}/demo
		doins demo/*
		# Manual
		insinto /usr/share/doc/${PF}/manual
		doins docs/gnuplot.pdf
		# Tutorial
		insinto /usr/share/doc/${PF}/tutorial
		doins tutorial/{tutorial.dvi,tutorial.pdf}
		# Documentation for making PostScript files
		insinto /usr/share/doc/${PF}/psdoc
		doins docs/psdoc/{*.doc,*.tex,*.ps,*.gpi,README}
	fi

	if ! use X; then
		# see bug 194527
		rm -rf "${D}/usr/$(get_libdir)/X11"
	fi
}

pkg_postinst() {
	use emacs && elisp-site-regen
	use latex && texmf-update

	if use svga ; then
		einfo "In order to enable ordinary users to use SVGA console graphics"
		einfo "gnuplot needs to be set up as setuid root.  Please note that"
		einfo "this is usually considered to be a security hazard."
		einfo "As root, manually \"chmod u+s /usr/bin/gnuplot\"."
	fi
}

pkg_postrm() {
	use emacs && elisp-site-regen
	use latex && texmf-update
}