[gentoo-commits] gentoo-x86 commit in app-editors/nano: ChangeLog nano-2.1.2-r1.ebuild

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      08/06/29 11:19:03

  Modified:             ChangeLog
  Added:                nano-2.1.2-r1.ebuild
  Log:
  Fix from upstream for search history when justify is disabled.
  (Portage version: 2.2_rc1/cvs/Linux 2.6.25 x86_64)

Revision  Changes    Path
1.193                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.193&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?rev=1.193&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/ChangeLog?r1=1.192&r2=1.193

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.192
retrieving revision 1.193
diff -u -r1.192 -r1.193
--- ChangeLog	27 Jun 2008 16:43:58 -0000	1.192
+++ ChangeLog	29 Jun 2008 11:19:03 -0000	1.193
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.192 2008/06/27 16:43:58 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.193 2008/06/29 11:19:03 vapier Exp $
+
+*nano-2.1.2-r1 (29 Jun 2008)
+
+  29 Jun 2008; Mike Frysinger <vapier@gentoo.org>
+  +files/nano-2.1.2-history-justify.patch, +nano-2.1.2-r1.ebuild:
+  Fix from upstream for search history when justify is disabled.
 
 *nano-2.1.2 (27 Jun 2008)
 



1.1                  app-editors/nano/nano-2.1.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/nano/nano-2.1.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.1.2-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.1.2-r1.ebuild,v 1.1 2008/06/29 11:19:03 vapier Exp $

inherit eutils
if [[ ${PV} == "9999" ]] ; then
	ECVS_SERVER="savannah.gnu.org:/cvsroot/nano"
	ECVS_MODULE="nano"
	ECVS_AUTH="pserver"
	ECVS_USER="anonymous"
	inherit cvs
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="debug justify minimal ncurses nls slang spell unicode"

DEPEND=">=sys-libs/ncurses-5.2
	nls? ( sys-devel/gettext )
	!ncurses? ( slang? ( sys-libs/slang ) )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-history-justify.patch
	if [[ ! -e configure ]] ; then
		./autogen.sh || die "autogen failed"
	fi
}

src_compile() {
	local myconf=""
	use ncurses \
		&& myconf="--without-slang" \
		|| myconf="${myconf} $(use_with slang)"

	econf \
		--bindir=/bin \
		$(use_enable !minimal color) \
		$(use_enable !minimal multibuffer) \
		$(use_enable !minimal nanorc) \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		${myconf} \
		|| die "configure failed"
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
	dohtml *.html
	insinto /etc
	newins doc/nanorc.sample nanorc

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano

	insinto /usr/share/nano
	local f
	for f in "${FILESDIR}"/*.nanorc ; do
		[[ -e ${D}/usr/share/nano/${f##*/} ]] && continue
		doins "${f}" || die
		echo "# include \"/usr/share/nano/${f##*/}\"" >> "${D}"/etc/nanorc
	done
}

pkg_postinst() {
	elog "More helpful info about nano, visit the GDP page:"
	elog "http://www.gentoo.org/doc/en/nano-basics-guide.xml"
}



-- 
gentoo-commits@lists.gentoo.org mailing list