* [gentoo-commits] gentoo-x86 commit in dev-libs/libusb: ChangeLog libusb-0.1.12-r4.ebuild
@ 2008-06-25 3:25 Robin H. Johnson (robbat2)
0 siblings, 0 replies; only message in thread
From: Robin H. Johnson (robbat2) @ 2008-06-25 3:25 UTC (permalink / raw
To: gentoo-commits
robbat2 08/06/25 03:25:45
Modified: ChangeLog
Added: libusb-0.1.12-r4.ebuild
Log:
Bug #225879, fix infinite looping during usb_bulk operations.
(Portage version: 2.2_rc1/cvs/Linux 2.6.26-rc4-00103-g1beee8d x86_64)
Revision Changes Path
1.81 dev-libs/libusb/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libusb/ChangeLog?rev=1.81&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libusb/ChangeLog?rev=1.81&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libusb/ChangeLog?r1=1.80&r2=1.81
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libusb/ChangeLog,v
retrieving revision 1.80
retrieving revision 1.81
diff -p -w -b -B -u -u -r1.80 -r1.81
--- ChangeLog 7 Jun 2008 00:59:04 -0000 1.80
+++ ChangeLog 25 Jun 2008 03:25:44 -0000 1.81
@@ -1,6 +1,12 @@
# ChangeLog for dev-libs/libusb
# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/ChangeLog,v 1.80 2008/06/07 00:59:04 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/ChangeLog,v 1.81 2008/06/25 03:25:44 robbat2 Exp $
+
+*libusb-0.1.12-r4 (25 Jun 2008)
+
+ 25 Jun 2008; Robin H. Johnson <robbat2@gentoo.org>
+ +files/libusb-0.1.12-no-infinite-bulk.patch, +libusb-0.1.12-r4.ebuild:
+ Bug #225879, fix infinite looping during usb_bulk operations.
*libusb-0.1.12-r3 (07 Jun 2008)
1.1 dev-libs/libusb/libusb-0.1.12-r4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libusb/libusb-0.1.12-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/libusb/libusb-0.1.12-r4.ebuild?rev=1.1&content-type=text/plain
Index: libusb-0.1.12-r4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/libusb-0.1.12-r4.ebuild,v 1.1 2008/06/25 03:25:44 robbat2 Exp $
WANT_AUTOMAKE="latest"
WANT_AUTOCONF="latest"
inherit eutils libtool autotools toolchain-funcs
DESCRIPTION="Userspace access to USB devices"
HOMEPAGE="http://libusb.sourceforge.net/"
SRC_URI="mirror://sourceforge/libusb/${P}.tar.gz"
LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc nocxx"
RESTRICT="test"
RDEPEND=""
DEPEND="doc? ( app-text/openjade
app-text/docbook-dsssl-stylesheets
app-text/docbook-sgml-utils
~app-text/docbook-sgml-dtd-4.2 )"
src_unpack() {
unpack ${A}
cd "${S}"
sed -i -e 's:-Werror::' Makefile.am
sed -i 's:AC_LANG_CPLUSPLUS:AC_PROG_CXX:' configure.in #213800
epatch "${FILESDIR}"/${PV}-fbsd.patch
use nocxx && epatch "${FILESDIR}"/${PN}-0.1.12-nocpp.patch
epatch "${FILESDIR}"/${PN}-0.1.12-no-infinite-bulk.patch
eautoreconf
elibtoolize
# Ensure that the documentation actually finds the DTD it needs
docbookdtd="/usr/share/sgml/docbook/sgml-dtd-4.2/docbook.dtd"
sysid='"-//OASIS//DTD DocBook V4.2//EN"'
sed -r -i -e \
"s,(${sysid}) \[\$,\1 \"${docbookdtd}\" \[,g" \
"${S}"/doc/manual.sgml
}
src_compile() {
econf \
$(use_enable debug debug all) \
$(use_enable doc build-docs) \
--libdir /usr/$(get_libdir) \
|| die "econf failed"
emake || die "emake failed"
}
src_install() {
emake -j1 DESTDIR="${D}" install || die "make install failed"
dodir /$(get_libdir)
mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir) \
|| die "Failed to put dynamic libs in /$(get_libdir)"
use nocxx && rm -f "${D}"/usr/include/usbpp.h
gen_usr_ldscript libusb.so
use nocxx || gen_usr_ldscript libusbpp.so
dodoc AUTHORS NEWS README || die "dodoc failed"
if use doc ; then
dohtml doc/html/*.html || die "dohtml failed"
fi
}
--
gentoo-commits@lists.gentoo.org mailing list
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2008-06-25 3:25 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-06-25 3:25 [gentoo-commits] gentoo-x86 commit in dev-libs/libusb: ChangeLog libusb-0.1.12-r4.ebuild Robin H. Johnson (robbat2)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox