From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1622310-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 95A4B158044
for <garchives@archives.gentoo.org>; Thu, 18 Apr 2024 16:24:14 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id CF0CEE2A22;
Thu, 18 Apr 2024 16:24:13 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id AF7B1E2A20
for <gentoo-commits@lists.gentoo.org>; Thu, 18 Apr 2024 16:24:13 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id E05B03434B5
for <gentoo-commits@lists.gentoo.org>; Thu, 18 Apr 2024 16:24:12 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 800D61722
for <gentoo-commits@lists.gentoo.org>; Thu, 18 Apr 2024 16:24:11 +0000 (UTC)
From: "David Roman" <davidroman96@gmail.com>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "David Roman" <davidroman96@gmail.com>
Message-ID: <1713457412.a45e71960e8b8082311688ea39f90c05cdc99c06.davidroman@gentoo>
Subject: [gentoo-commits] repo/proj/guru:master commit in: media-sound/TauonMusicBox/
X-VCS-Repository: repo/proj/guru
X-VCS-Files: media-sound/TauonMusicBox/Manifest media-sound/TauonMusicBox/TauonMusicBox-7.7.2.ebuild
X-VCS-Directories: media-sound/TauonMusicBox/
X-VCS-Committer: davidroman
X-VCS-Committer-Name: David Roman
X-VCS-Revision: a45e71960e8b8082311688ea39f90c05cdc99c06
X-VCS-Branch: master
Date: Thu, 18 Apr 2024 16:24:11 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 7a194ec3-ef18-44fe-b119-3dcc1475844d
X-Archives-Hash: 40dd61687ada73a59411085fbf8d2c99
Message-ID: <20240418162411.07qPziQt2ytV_YdwtVKELi5C5JI8zMF6IZxFBncHlnU@z>
commit: a45e71960e8b8082311688ea39f90c05cdc99c06
Author: David Roman <davidroman96 <AT> gmail <DOT> com>
AuthorDate: Thu Apr 18 16:23:32 2024 +0000
Commit: David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Thu Apr 18 16:23:32 2024 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=a45e7196
media-sound/TauonMusicBox: add 7.7.2
Signed-off-by: David Roman <davidroman96 <AT> gmail.com>
media-sound/TauonMusicBox/Manifest | 1 +
.../TauonMusicBox/TauonMusicBox-7.7.2.ebuild | 114 +++++++++++++++++++++
2 files changed, 115 insertions(+)
diff --git a/media-sound/TauonMusicBox/Manifest b/media-sound/TauonMusicBox/Manifest
index c93e2ad79d..4dd1cd780f 100644
--- a/media-sound/TauonMusicBox/Manifest
+++ b/media-sound/TauonMusicBox/Manifest
@@ -1 +1,2 @@
DIST TauonMusicBox-7.7.1.tar.gz 1049204 BLAKE2B 0d1c4fbf7264bedbdb33fba00de141edffbd2290f3b39faf6e9b82a64f6a75ad30233f6e6071fa351bb9fba935e1d5323e550b25cc8fb4a9a35df34e38531774 SHA512 671d626f14358b6db96da24169ef428911a9e50501b2cc61e1bbc43f8fa7f6b76682e438f86fb94d1e4772085150d602a6a87d3e8bd74a5f77aba11efcda397f
+DIST TauonMusicBox-7.7.2.tar.gz 992102 BLAKE2B a7aca5e3aea42e045147f3768a57d74cf877f9b4e0114b982dc4f6291acdeacda9b5f709a4b26a340d162b9768bb1de4847f82839ec894d03d744531028e6584 SHA512 42a47b5795f2e49adb8bf0673fb932b10d3a3b8ad309b2fc88ed54f44f2b5ced4391d653773a1b34ef4dbbb18d16016b9d3b30eb1d99fac725fc6ac4c8e01d27
diff --git a/media-sound/TauonMusicBox/TauonMusicBox-7.7.2.ebuild b/media-sound/TauonMusicBox/TauonMusicBox-7.7.2.ebuild
new file mode 100644
index 0000000000..ca5357061a
--- /dev/null
+++ b/media-sound/TauonMusicBox/TauonMusicBox-7.7.2.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit cmake desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+ EGIT_SUBMODULES=()
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+ SRC_URI="https://github.com/Taiko2k/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+ dev-libs/miniaudio
+ media-libs/flac
+ media-libs/libopenmpt
+ media-libs/opus
+ media-libs/opusfile
+ media-libs/libsamplerate
+ media-libs/libvorbis
+ media-sound/mpg123
+ media-sound/wavpack
+ sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+ dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+ dev-python/natsort[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/PySDL2[${PYTHON_USEDEP}]
+ dev-python/setproctitle[${PYTHON_USEDEP}]
+ dev-python/send2trash[${PYTHON_USEDEP}]
+ media-video/ffmpeg
+ media-libs/mutagen[${PYTHON_USEDEP}]
+ media-libs/sdl2-image
+
+ ${PHAZOR_DEPS}
+"
+
+RDEPEND="
+ ${DEPEND}
+
+ dev-libs/libappindicator
+"
+
+BDEPEND="sys-devel/gettext"
+
+src_prepare() {
+ distutils-r1_src_prepare
+ cmake_src_prepare
+}
+
+src_configure() {
+ distutils-r1_src_configure
+ cmake_src_configure
+}
+
+src_compile() {
+ distutils-r1_src_compile
+ cmake_src_compile
+
+ build_locale() {
+ msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+ }
+
+ plocale_for_each_locale build_locale
+}
+
+src_test() {
+ distutils-r1_src_test
+ cmake_src_test
+}
+
+python_install() {
+ newbin tauon.py tauon
+ dolib.so "${WORKDIR}/${P}_build/libphazor.so"
+ dosym "/usr/$(get_libdir)/libphazor.so" "/usr/share/${PN}/lib/libphazor.so"
+
+ install_locale() {
+ insinto "/usr/share/locale/${1}/LC_MESSAGES"
+ doins "locale/${1}/LC_MESSAGES/tauon.mo"
+ }
+
+ plocale_for_each_locale install_locale
+
+ insinto "/usr/share/${PN}"
+ doins -r assets theme templates
+ doins input.txt
+
+ sed -i 's/\/opt\/tauon-music-box\/tauonmb.sh/tauon/g' extra/tauonmb.desktop || die
+ sed -i 's/Actions=PlayPause;Previous;Next/Actions=PlayPause;Previous;Next;Stop/g' extra/tauonmb.desktop || die
+ domenu extra/tauonmb.desktop
+ doicon -s scalable extra/tauonmb.svg
+
+ distutils-r1_python_install
+}
+
+pkg_postinst() {
+ optfeature "last fm support" dev-python/pylast
+}