* [gentoo-commits] gentoo-x86 commit in sys-boot/unetbootin: ChangeLog unetbootin-619.ebuild
@ 2015-08-08 6:28 Jeroen Roovers (jer)
0 siblings, 0 replies; only message in thread
From: Jeroen Roovers (jer) @ 2015-08-08 6:28 UTC (permalink / raw
To: gentoo-commits
jer 15/08/08 06:28:42
Modified: ChangeLog
Added: unetbootin-619.ebuild
Log:
Version bump (bug #556938 by Manuel Rüger).
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A792A613)
Revision Changes Path
1.110 sys-boot/unetbootin/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?rev=1.110&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?rev=1.110&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/ChangeLog?r1=1.109&r2=1.110
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v
retrieving revision 1.109
retrieving revision 1.110
diff -u -r1.109 -r1.110
--- ChangeLog 2 Nov 2014 14:14:49 -0000 1.109
+++ ChangeLog 8 Aug 2015 06:28:42 -0000 1.110
@@ -1,6 +1,11 @@
# ChangeLog for sys-boot/unetbootin
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.109 2014/11/02 14:14:49 jer Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/ChangeLog,v 1.110 2015/08/08 06:28:42 jer Exp $
+
+*unetbootin-619 (08 Aug 2015)
+
+ 08 Aug 2015; Jeroen Roovers <jer@gentoo.org> +unetbootin-619.ebuild:
+ Version bump (bug #556938 by Manuel Rüger).
02 Nov 2014; Jeroen Roovers <jer@gentoo.org> unetbootin-608.ebuild:
Drop <sys-boot/syslinux-5 dependency (bug #474648).
1.1 sys-boot/unetbootin/unetbootin-619.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/unetbootin-619.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/unetbootin/unetbootin-619.ebuild?rev=1.1&content-type=text/plain
Index: unetbootin-619.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/unetbootin/unetbootin-619.ebuild,v 1.1 2015/08/08 06:28:42 jer Exp $
EAPI=5
inherit eutils qt4-r2
DESCRIPTION="UNetbootin installs Linux/BSD distributions to a partition or USB drive"
HOMEPAGE="https://github.com/unetbootin/unetbootin"
SRC_URI="${HOMEPAGE}/archive/619.tar.gz -> ${PV}.tar.gz"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
UNBI_LINGUAS="
am ar ast be bg bn ca cs da de el eo es et eu fa fi fo fr gl he hr hu id it
ja lt lv ml ms nan nb nl nn pl pt_BR pt ro ru si sk sl sr sv sw tr uk ur vi
zh_CN zh_TW
"
for lingua in ${UNBI_LINGUAS}; do
IUSE="${IUSE} linguas_${lingua}"
done
S=${WORKDIR}/${P}/src/${PN}
DEPEND="dev-qt/qtgui:4"
RDEPEND="
${DEPEND}
app-arch/p7zip
sys-boot/syslinux
sys-fs/mtools
"
src_prepare() {
epatch "${FILESDIR}/${PN}-581-desktop.patch"
# QA check in case linguas are added or removed
enum() {
echo ${#}
}
[[ $(enum ${UNBI_LINGUAS}) -eq $(( $(enum $(echo ${PN}_*.ts) ) -1 )) ]] \
|| die "Numbers of recorded and actual linguas do not match"
unset enum
# Make room between the last line of TRANSLATIONS and the next definition
sed -i \
-e '/^DEFINES/s|.*|\n&|g' \
${PN}.pro || die
# Remove localisations
local lingua
for lingua in ${UNBI_LINGUAS}; do
if ! use linguas_${lingua}; then
sed -i ${PN}.pro -e "/\.*${PN}_${lingua}\.ts.*/d" || die
rm ${PN}_${lingua}.ts || die
fi
done
}
src_configure() {
sed -i -e '/^RESOURCES/d' unetbootin.pro || die
lupdate ${PN}.pro || die
lrelease ${PN}.pro || die
eqmake4 ${PN}.pro || die
}
src_install() {
dobin ${PN}
domenu ${PN}.desktop
for file in ${PN}*.png; do
size="${file/${PN}_}"
size="${size/.png}x${size/.png}"
insinto /usr/share/icons/hicolor/${size}/apps
newins ${file} ${PN}.png
done
local lingua
for lingua in ${UNBI_LINGUAS}; do
if use linguas_${lingua}; then
insinto /usr/share/${PN}
doins ${PN}_${lingua}.qm
fi
done
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-08-08 6:28 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-08-08 6:28 [gentoo-commits] gentoo-x86 commit in sys-boot/unetbootin: ChangeLog unetbootin-619.ebuild Jeroen Roovers (jer)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox