[gentoo-commits] gentoo-x86 commit in net-p2p/retroshare: retroshare-0.6.0_rc2_pre8551.ebuild ChangeLog retroshare-0.6.0_pre20150415.ebuild

[gentoo-commits] gentoo-x86 commit in net-p2p/retroshare: retroshare-0.6.0_rc2_pre8551.ebuild ChangeLog retroshare-0.6.0_pre20150415.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    15/06/28 17:24:32

  Modified:             ChangeLog
  Added:                retroshare-0.6.0_rc2_pre8551.ebuild
  Removed:              retroshare-0.6.0_pre20150415.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x60C0742D1F357D42)

Revision  Changes    Path
1.13                 net-p2p/retroshare/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/ChangeLog?r1=1.12&r2=1.13

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/retroshare/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog	15 Jun 2015 00:14:17 -0000	1.12
+++ ChangeLog	28 Jun 2015 17:24:32 -0000	1.13
@@ -1,6 +1,13 @@
 # ChangeLog for net-p2p/retroshare
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/retroshare/ChangeLog,v 1.12 2015/06/15 00:14:17 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/retroshare/ChangeLog,v 1.13 2015/06/28 17:24:32 pinkbyte Exp $
+
+*retroshare-0.6.0_rc2_pre8551 (28 Jun 2015)
+
+  28 Jun 2015; Sergey Popov <pinkbyte@gentoo.org>
+  -retroshare-0.6.0_pre20150415.ebuild, +retroshare-0.6.0_rc2_pre8551.ebuild,
+  -files/retroshare-0.6.0-force-sqlcipher.patch:
+  Version bump, drop old
 
 *retroshare-0.6.0_rc1 (15 Jun 2015)
 



1.1                  net-p2p/retroshare/retroshare-0.6.0_rc2_pre8551.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/retroshare-0.6.0_rc2_pre8551.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/retroshare/retroshare-0.6.0_rc2_pre8551.ebuild?rev=1.1&content-type=text/plain

Index: retroshare-0.6.0_rc2_pre8551.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/retroshare/retroshare-0.6.0_rc2_pre8551.ebuild,v 1.1 2015/06/28 17:24:32 pinkbyte Exp $

EAPI=5

inherit eutils gnome2-utils multilib qmake-utils

MY_PV="${PV/_rc/.RC}"
MY_PV="${MY_PV/_pre/~}"

DESCRIPTION="P2P private sharing application"
HOMEPAGE="http://retroshare.sourceforge.net"
SRC_URI="mirror://sourceforge/retroshare/${PN}_${MY_PV}_src.tgz"

# pegmarkdown can also be used with MIT
LICENSE="GPL-2 GPL-3 Apache-2.0 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="cli feedreader +qt5 voip"
REQUIRED_USE="|| ( cli qt5 )
	feedreader? ( qt5 )
	voip? ( qt5 )"

RDEPEND="
	app-arch/bzip2
	dev-db/sqlcipher
	dev-libs/openssl:0
	gnome-base/libgnome-keyring
	net-libs/libmicrohttpd
	net-libs/libupnp
	sys-libs/zlib
	cli? (
		dev-libs/protobuf
		net-libs/libssh[server]
	)
	feedreader? (
		dev-libs/libxml2
		dev-libs/libxslt
		net-misc/curl
	)
	qt5? (
		x11-libs/libX11
		x11-libs/libXScrnSaver
		dev-qt/designer:5
		dev-qt/qtcore:5
		dev-qt/qtgui:5
		dev-qt/qtmultimedia:5
		dev-qt/qtnetwork:5
		dev-qt/qtprintsupport:5
		dev-qt/qtscript:5
		dev-qt/qtwidgets:5
		dev-qt/qtx11extras:5
		dev-qt/qtxml:5
	)
	voip? (
		media-libs/opencv
		media-libs/speex
	)"
DEPEND="${RDEPEND}
	dev-qt/qtcore:5
	virtual/pkgconfig"

S="${WORKDIR}/retroshare06-0.6.0/src"

src_prepare() {
	local dir

	sed -i \
		-e "s|/usr/lib/retroshare/extensions6/|/usr/$(get_libdir)/${PN}/extensions6/|" \
		libretroshare/src/rsserver/rsinit.cc \
		|| die "sed on libretroshare/src/rsserver/rsinit.cc failed"

	rs_src_dirs="libbitdht/src openpgpsdk/src libresapi/src libretroshare/src supportlibs/pegmarkdown"
	use cli && rs_src_dirs="${rs_src_dirs} retroshare-nogui/src"
	use feedreader && rs_src_dirs="${rs_src_dirs} plugins/FeedReader"
	use qt5 && rs_src_dirs="${rs_src_dirs} retroshare-gui/src"
	use voip && rs_src_dirs="${rs_src_dirs} plugins/VOIP"

	# Force linking to sqlcipher ONLY
	sed -i \
		-e '/isEmpty(SQLCIPHER_OK) {/aerror(libsqlcipher not found)' \
		retroshare-gui/src/retroshare-gui.pro \
		retroshare-nogui/src/retroshare-nogui.pro || die 'sed on retroshare-gui/src/retroshare-gui.pro failed'

	epatch_user
}

src_configure() {
	for dir in ${rs_src_dirs} ; do
		pushd "${S}/${dir}" 2>/dev/null || die
		eqmake5
		popd 2>/dev/null || die
	done
}

src_compile() {
	local dir

	for dir in ${rs_src_dirs} ; do
		emake -C "${dir}"
	done

	unset rs_src_dirs
}

src_install() {
	local i
	local extension_dir="/usr/$(get_libdir)/${PN}/extensions6/"

	use cli && dobin retroshare-nogui/src/retroshare-nogui
	use qt5 && dobin retroshare-gui/src/RetroShare

	exeinto "${extension_dir}"
	use feedreader && doexe plugins/FeedReader/*.so*
	use voip && doexe plugins/VOIP/*.so*

	insinto /usr/share/RetroShare06
	doins libbitdht/src/bitdht/bdboot.txt

	insinto /usr/share/RetroShare06/webui
	doins libresapi/src/webfiles/*

	dodoc README.txt
	make_desktop_entry RetroShare
	for i in 24 48 64 ; do
		doicon -s ${i} "build_scripts/Debian+Ubuntu/data/${i}x${i}/${PN}.png"
	done
	doicon -s 128 "build_scripts/Debian+Ubuntu/data/${PN}.png"
}

pkg_preinst() {
	if [[ "${REPLACING_VERSIONS}" = "0.5*"  ]]; then
		elog "You are upgrading from Retroshare 0.5.* to ${PV}"
		elog "Version 0.6.* is backward-incompatible with 0.5 branch"
		elog "and clients with 0.6.* can not connect to clients that have 0.5.*"
		elog "It's recommended to drop all your configuration and either"
		elog "generate a new certificate or import existing from a backup"
	fi
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}