[gentoo-commits] gentoo-x86 commit in games-action/cs2d: cs2d-0127.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in games-action/cs2d: cs2d-0127.ebuild ChangeLog

[Maxim Koltsov (maksbotan)]

maksbotan    15/06/28 11:08:47

  Modified:             ChangeLog
  Added:                cs2d-0127.ebuild
  Log:
  Bump to 0127, use QA_PREBUILD, bug #453428. Thanks to Oleg Kravchenko.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key F8DBDADE)

Revision  Changes    Path
1.14                 games-action/cs2d/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/cs2d/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/cs2d/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/cs2d/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-action/cs2d/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	1 Jun 2015 22:05:45 -0000	1.13
+++ ChangeLog	28 Jun 2015 11:08:47 -0000	1.14
@@ -1,6 +1,11 @@
 # ChangeLog for games-action/cs2d
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-action/cs2d/ChangeLog,v 1.13 2015/06/01 22:05:45 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-action/cs2d/ChangeLog,v 1.14 2015/06/28 11:08:47 maksbotan Exp $
+
+*cs2d-0127 (28 Jun 2015)
+
+  28 Jun 2015; Maxim Koltsov <maksbotan@gentoo.org> +cs2d-0127.ebuild:
+  Bump to 0127, use QA_PREBUILD, bug #453428. Thanks to Oleg Kravchenko.
 
   01 Jun 2015; Michael Sterrett <mr_bones_@gentoo.org> cs2d-0123.ebuild:
   clean up app-emulation/emul-linux which has been removed



1.1                  games-action/cs2d/cs2d-0127.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/cs2d/cs2d-0127.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-action/cs2d/cs2d-0127.ebuild?rev=1.1&content-type=text/plain

Index: cs2d-0127.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/cs2d/cs2d-0127.ebuild,v 1.1 2015/06/28 11:08:47 maksbotan Exp $

EAPI=5

inherit eutils games

DESCRIPTION="Counter-Strike 2D is freeware clone of Counter-Strike with some added features in gameplay"
HOMEPAGE="http://www.cs2d.com/"
SRC_URI="http://dev.gentoo.org/~maksbotan/cs2d/cs2d_${PV}_linux.zip
	http://dev.gentoo.org/~maksbotan/cs2d/cs2d_${PV}_win.zip
	http://dev.gentoo.org/~maksbotan/cs2d/cs2d.png"
LICENSE="freedist"

SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE=""

DEPEND="app-arch/unzip"
RDEPEND="
	x86? (
		media-libs/openal
		media-libs/freetype:2
		x11-libs/libX11
		x11-libs/libXxf86vm
		virtual/opengl
	)
	amd64? (
		>=media-libs/openal-1.15.1[abi_x86_32(-)]
		>=virtual/opengl-7.0-r1[abi_x86_32(-)]
		>=media-libs/freetype-2.5.0.1:2[abi_x86_32(-)]
		>=x11-libs/libX11-1.6.2[abi_x86_32(-)]
		>=x11-libs/libXxf86vm-1.1.3[abi_x86_32(-)]
	)"

QA_PREBUILT="opt/cs2d/CounterStrike2D"

S=${WORKDIR}

src_prepare() {
	# removing windows files
	rm -f *.exe *.bat || die

	# OpenAL is default sound driver
	sed -i \
		-e 's:^sounddriver.*$:sounddriver OpenAL Default:' \
		sys/config.cfg || die
}

src_install() {
	insinto "${GAMES_PREFIX_OPT}"/${PN}
	doins -r .
	# avoid file collision with untracked file
	rm -f "${ED%/}/${GAMES_PREFIX_OPT}"/${PN}/sys/core/started.cfg

	make_desktop_entry CounterStrike2D "Counter Strike 2D"
	make_desktop_entry "CounterStrike2D -fullscreen -24bit" "Counter Strike 2D - FULLSCREEN"
	games_make_wrapper CounterStrike2D ./CounterStrike2D \
		"${GAMES_PREFIX_OPT}"/${PN} "${GAMES_PREFIX_OPT}"/${PN}

	doicon "${DISTDIR}"/${PN}.png

	prepgamesdirs

	# fixing permissions
	fperms -R g+w "${GAMES_PREFIX_OPT}"/${PN}/maps
	fperms -R g+w "${GAMES_PREFIX_OPT}"/${PN}/screens
	fperms -R g+w "${GAMES_PREFIX_OPT}"/${PN}/sys
	fperms ug+x "${GAMES_PREFIX_OPT}"/${PN}/CounterStrike2D
}