* [gentoo-commits] gentoo-x86 commit in x11-wm/openbox: openbox-3.6.ebuild ChangeLog
@ 2015-06-13 14:24 Markos Chandras (hwoarang)
0 siblings, 0 replies; only message in thread
From: Markos Chandras (hwoarang) @ 2015-06-13 14:24 UTC (permalink / raw
To: gentoo-commits
hwoarang 15/06/13 14:24:59
Modified: ChangeLog
Added: openbox-3.6.ebuild
Log:
Version bump. Bug #551372
(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)
Revision Changes Path
1.295 x11-wm/openbox/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/ChangeLog?rev=1.295&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/ChangeLog?rev=1.295&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/ChangeLog?r1=1.294&r2=1.295
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v
retrieving revision 1.294
retrieving revision 1.295
diff -u -r1.294 -r1.295
--- ChangeLog 8 Apr 2015 17:29:20 -0000 1.294
+++ ChangeLog 13 Jun 2015 14:24:59 -0000 1.295
@@ -1,6 +1,11 @@
# ChangeLog for x11-wm/openbox
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v 1.294 2015/04/08 17:29:20 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/ChangeLog,v 1.295 2015/06/13 14:24:59 hwoarang Exp $
+
+*openbox-3.6 (13 Jun 2015)
+
+ 13 Jun 2015; Markos Chandras <hwoarang@gentoo.org> +openbox-3.6.ebuild:
+ Version bump. Bug #551372
08 Apr 2015; Michał Górny <mgorny@gentoo.org> openbox-3.5.2-r1.ebuild,
openbox-9999.ebuild:
1.1 x11-wm/openbox/openbox-3.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/openbox-3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/openbox/openbox-3.6.ebuild?rev=1.1&content-type=text/plain
Index: openbox-3.6.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-3.6.ebuild,v 1.1 2015/06/13 14:24:59 hwoarang Exp $
EAPI="5"
PYTHON_COMPAT=( python2_7 )
inherit multilib autotools python-r1 eutils
DESCRIPTION="A standards compliant, fast, light-weight, extensible window manager"
HOMEPAGE="http://openbox.org/"
if [[ ${PV} == *9999* ]]; then
inherit git-2
EGIT_REPO_URI="git://git.openbox.org/dana/openbox"
SRC_URI="branding? (
http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
KEYWORDS=""
else
SRC_URI="http://openbox.org/dist/openbox/${P}.tar.gz
branding? ( http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~arm-linux ~x86-linux"
fi
LICENSE="GPL-2"
SLOT="3"
IUSE="branding debug imlib nls session startup-notification static-libs svg xdg"
REQUIRED_USE="xdg? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="dev-libs/glib:2
>=dev-libs/libxml2-2.0
>=media-libs/fontconfig-2
x11-libs/libXft
x11-libs/libXinerama
x11-libs/libXrandr
x11-libs/libXt
>=x11-libs/pango-1.8[X]
imlib? ( media-libs/imlib2 )
startup-notification? ( >=x11-libs/startup-notification-0.8 )
svg? ( gnome-base/librsvg:2 )
xdg? (
${PYTHON_DEPS}
dev-python/pyxdg[${PYTHON_USEDEP}]
)
"
DEPEND="${RDEPEND}
sys-devel/gettext
virtual/pkgconfig
x11-proto/xextproto
x11-proto/xf86vidmodeproto
x11-proto/xineramaproto"
src_unpack() {
if [[ ${PV} == *9999* ]]; then
git-2_src_unpack
else
unpack ${A}
fi
}
src_prepare() {
use xdg && python_export_best
epatch "${FILESDIR}"/${PN}-3.5.2-gnome-session.patch
sed -i \
-e "s:-O0 -ggdb ::" \
-e 's/-fno-strict-aliasing//' \
"${S}"/m4/openbox.m4 || die
epatch_user
eautoreconf
}
src_configure() {
econf \
--docdir="${EPREFIX}/usr/share/doc/${PF}" \
$(use_enable debug) \
$(use_enable static-libs static) \
$(use_enable nls) \
$(use_enable imlib imlib2) \
$(use_enable svg librsvg) \
$(use_enable startup-notification) \
$(use_enable session session-management) \
--with-x
}
src_install() {
dodir /etc/X11/Sessions
echo "/usr/bin/openbox-session" > "${ED}/etc/X11/Sessions/${PN}"
fperms a+x /etc/X11/Sessions/${PN}
emake DESTDIR="${D}" install
if use branding; then
insinto /usr/share/themes
doins -r "${WORKDIR}"/Surreal_Gentoo
# make it the default theme
sed -i \
-e "/<theme>/{n; s@<name>.*</name>@<name>Surreal_Gentoo</name>@}" \
"${D}"/etc/xdg/openbox/rc.xml \
|| die "failed to set Surreal Gentoo as the default theme"
fi
use static-libs || prune_libtool_files --all
if use xdg ; then
python_replicate_script "${ED}"/usr/libexec/openbox-xdg-autostart
else
rm "${ED}"/usr/libexec/openbox-xdg-autostart || die
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-06-13 14:25 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-06-13 14:24 [gentoo-commits] gentoo-x86 commit in x11-wm/openbox: openbox-3.6.ebuild ChangeLog Markos Chandras (hwoarang)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox