[gentoo-commits] gentoo-x86 commit in x11-terms/gnome-terminal: gnome-terminal-3.16.2-r2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-terms/gnome-terminal: gnome-terminal-3.16.2-r2.ebuild ChangeLog

[Gilles Dartiguelongue (eva)]

eva         15/06/09 09:43:38

  Modified:             ChangeLog
  Added:                gnome-terminal-3.16.2-r2.ebuild
  Log:
  Version bump for Gnome 3.16.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.300                x11-terms/gnome-terminal/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/ChangeLog?rev=1.300&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/ChangeLog?rev=1.300&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/ChangeLog?r1=1.299&r2=1.300

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v
retrieving revision 1.299
retrieving revision 1.300
diff -u -r1.299 -r1.300
--- ChangeLog	19 May 2015 14:10:09 -0000	1.299
+++ ChangeLog	9 Jun 2015 09:43:38 -0000	1.300
@@ -1,6 +1,14 @@
 # ChangeLog for x11-terms/gnome-terminal
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v 1.299 2015/05/19 14:10:09 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/ChangeLog,v 1.300 2015/06/09 09:43:38 eva Exp $
+
+*gnome-terminal-3.16.2-r2 (09 Jun 2015)
+
+  09 Jun 2015; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-terminal-3.16.2-r2.ebuild,
+  +files/gnome-terminal-3.16.2-restore-dark.patch,
+  +files/gnome-terminal-3.16.2-restore-transparency.patch:
+  Version bump for Gnome 3.16.
 
   19 May 2015; Alexandre Rostovtsev <tetromino@gentoo.org>
   gnome-terminal-3.14.2-r2.ebuild, gnome-terminal-3.14.3.ebuild:



1.1                  x11-terms/gnome-terminal/gnome-terminal-3.16.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.16.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.16.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: gnome-terminal-3.16.2-r2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/gnome-terminal/gnome-terminal-3.16.2-r2.ebuild,v 1.1 2015/06/09 09:43:38 eva Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"

inherit eutils gnome2 readme.gentoo

DESCRIPTION="The Gnome Terminal"
HOMEPAGE="https://wiki.gnome.org/Apps/Terminal/"

LICENSE="GPL-3+"
SLOT="0"
IUSE="debug +gnome-shell +nautilus vanilla"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux"

# FIXME: automagic dependency on gtk+[X]
RDEPEND="
	>=dev-libs/glib-2.40:2[dbus]
	>=x11-libs/gtk+-3.10:3[X]
	>=x11-libs/vte-0.40.2:2.91
	>=gnome-base/dconf-0.14
	>=gnome-base/gsettings-desktop-schemas-0.1.0
	sys-apps/util-linux
	x11-libs/libSM
	x11-libs/libICE
	gnome-shell? ( gnome-base/gnome-shell )
	nautilus? ( >=gnome-base/nautilus-3 )
"
# itstool required for help/* with non-en LINGUAS, see bug #549358
# xmllint required for glib-compile-resources, see bug #549304
DEPEND="${RDEPEND}
	app-text/yelp-tools
	dev-libs/libxml2
	dev-util/gdbus-codegen
	dev-util/itstool
	>=dev-util/intltool-0.50
	sys-devel/gettext
	virtual/pkgconfig
"

DOC_CONTENTS="To get previous working directory inherited in new opened
	tab you will need to add the following line to your ~/.bashrc:\n
	. /etc/profile.d/vte.sh"

src_prepare() {
	gnome2_src_prepare
	if ! use vanilla; then
		# Fedora patch, https://bugzilla.gnome.org/show_bug.cgi?id=695371
		epatch "${FILESDIR}"/${PN}-3.16.2-restore-transparency.patch
		# Fedora patch, https://bugzilla.gnome.org/show_bug.cgi?id=721932
		epatch "${FILESDIR}"/${PN}-3.16.2-restore-dark.patch
	fi
}

src_configure() {
	gnome2_src_configure \
		--disable-static \
		--disable-migration \
		$(use_enable debug) \
		$(use_enable gnome-shell search-provider) \
		$(use_with nautilus nautilus-extension) \
		VALAC=$(type -P true)
}

src_install() {
	DOCS="AUTHORS ChangeLog HACKING NEWS"
	gnome2_src_install
	readme.gentoo_create_doc
}

pkg_postinst() {
	gnome2_pkg_postinst
	readme.gentoo_print_elog
}