[gentoo-commits] gentoo-x86 commit in sys-apps/memtest86: memtest86-4.3.5.ebuild ChangeLog

["Lars Wendler (polynomial-c)" <polynomial-c@gentoo.org>]

polynomial-c    15/06/03 09:17:39

  Modified:             ChangeLog
  Added:                memtest86-4.3.5.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.47                 sys-apps/memtest86/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/memtest86/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	29 May 2015 08:06:27 -0000	1.46
+++ ChangeLog	3 Jun 2015 09:17:39 -0000	1.47
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/memtest86
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/memtest86/ChangeLog,v 1.46 2015/05/29 08:06:27 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/memtest86/ChangeLog,v 1.47 2015/06/03 09:17:39 polynomial-c Exp $
+
+*memtest86-4.3.5 (03 Jun 2015)
+
+  02 Jun 2015; Lars Wendler <polynomial-c@gentoo.org> +memtest86-4.3.5.ebuild:
+  Version bump.
 
 *memtest86-4.3.4 (29 May 2015)
 



1.1                  sys-apps/memtest86/memtest86-4.3.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/memtest86-4.3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/memtest86-4.3.5.ebuild?rev=1.1&content-type=text/plain

Index: memtest86-4.3.5.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/memtest86/memtest86-4.3.5.ebuild,v 1.1 2015/06/03 09:17:39 polynomial-c Exp $

EAPI=5

inherit mount-boot eutils toolchain-funcs

DESCRIPTION="A stand alone memory test for x86 computers"
HOMEPAGE="http://www.memtest86.com/"
SRC_URI="http://www.memtest86.com/downloads/${P}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="serial"
S="${WORKDIR}/src"

BOOTDIR=/boot/memtest86

src_prepare() {
	epatch "${FILESDIR}"/${PN}-4.3.3-build-nopie.patch #66630 + #206726

	sed -i -e 's,0x10000,0x100000,' memtest.lds || die

	if use serial ; then
		sed -i \
			-e '/^#define SERIAL_CONSOLE_DEFAULT/s:0:1:' \
			config.h \
			|| die "sed failed"
	fi

	tc-export AS CC LD
}

src_test() { :; }

src_install() {
	insinto ${BOOTDIR}
	newins memtest.bin memtest
	dosym memtest ${BOOTDIR}/memtest.bin

	exeinto /etc/grub.d
	doexe "${FILESDIR}"/39_memtest86

	dodoc README README.build-process README.background
}

pkg_postinst() {
	mount-boot_pkg_postinst
	elog
	elog "memtest has been installed in ${BOOTDIR}/"
	elog "You may wish to update your bootloader configs"
	elog "by adding these lines:"
	elog " - For grub2 just run grub-mkconfig, a configuration file is installed"
	elog "   as /etc/grub/39_${PN}"
	elog " - For grub legacy: (replace '?' with correct numbers for your boot partition)"
	elog "    > title=${PN}"
	elog "    > root (hd?,?)"
	elog "    > kernel ${BOOTDIR}/memtest"
	elog " - For lilo:"
	elog "    > image  = ${BOOTDIR}/memtest"
	elog "    > label  = ${PN}"
	elog
}