[gentoo-commits] gentoo-x86 commit in sys-apps/less: ChangeLog less-476.ebuild less-474.ebuild

[gentoo-commits] gentoo-x86 commit in sys-apps/less: ChangeLog less-476.ebuild less-474.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    15/05/11 09:52:49

  Modified:             ChangeLog
  Added:                less-476.ebuild
  Removed:              less-474.ebuild
  Log:
  Version bump. Removed old
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.194                sys-apps/less/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.194&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.194&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?r1=1.193&r2=1.194

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v
retrieving revision 1.193
retrieving revision 1.194
diff -u -r1.193 -r1.194
--- ChangeLog	10 Mar 2015 10:14:43 -0000	1.193
+++ ChangeLog	11 May 2015 09:52:49 -0000	1.194
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/less
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.193 2015/03/10 10:14:43 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.194 2015/05/11 09:52:49 polynomial-c Exp $
+
+*less-476 (11 May 2015)
+
+  11 May 2015; Lars Wendler <polynomial-c@gentoo.org> -less-474.ebuild,
+  +less-476.ebuild:
+  Version bump. Removed old.
 
 *less-475 (10 Mar 2015)
 



1.1                  sys-apps/less/less-476.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-476.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-476.ebuild?rev=1.1&content-type=text/plain

Index: less-476.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/less-476.ebuild,v 1.1 2015/05/11 09:52:49 polynomial-c Exp $

EAPI="4"

inherit eutils

CODE2COLOR_PV="0.2"
CODE2COLOR_P="code2color-${CODE2COLOR_PV}"
DESCRIPTION="Excellent text file viewer"
HOMEPAGE="http://www.greenwoodsoftware.com/less/"
SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz
	http://www-zeuthen.desy.de/~friebel/unix/less/code2color -> ${CODE2COLOR_P}"

LICENSE="|| ( GPL-3 BSD-2 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="pcre unicode"

DEPEND=">=app-misc/editor-wrapper-3
	>=sys-libs/ncurses-5.2
	pcre? ( dev-libs/libpcre )"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${P}.tar.gz
	cp "${DISTDIR}"/${CODE2COLOR_P} "${S}"/code2color || die
}

src_prepare() {
	epatch "${FILESDIR}"/${CODE2COLOR_P}.patch
	chmod a+x configure || die
}

src_configure() {
	export ac_cv_lib_ncursesw_initscr=$(usex unicode)
	export ac_cv_lib_ncurses_initscr=$(usex !unicode)
	econf \
		--with-regex=$(usex pcre pcre posix) \
		--with-editor="${EPREFIX}"/usr/libexec/editor
}

src_install() {
	default

	dobin code2color
	newbin "${FILESDIR}"/lesspipe.sh lesspipe
	dosym lesspipe /usr/bin/lesspipe.sh
	newenvd "${FILESDIR}"/less.envd 70less

	dodoc "${FILESDIR}"/README.Gentoo
}

pkg_postinst() {
	elog "lesspipe offers colorization options.  Run 'lesspipe -h' for info."
}