[gentoo-commits] gentoo-x86 commit in app-portage/eix: eix-0.30.8.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-portage/eix: eix-0.30.8.ebuild ChangeLog

[Ian Stakenvicius (axs)]

axs         15/04/13 16:54:24

  Modified:             ChangeLog
  Added:                eix-0.30.8.ebuild
  Log:
  version bump; minor fixes, and treatment of /etc/portage/package.* has become more compatible to portage (concerning sorting); also, users of eix-remote will need to upgrade to avoid strange errors and incomplete data from zugaina.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 2B6559ED)

Revision  Changes    Path
1.490                app-portage/eix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/ChangeLog?rev=1.490&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/ChangeLog?rev=1.490&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/ChangeLog?r1=1.489&r2=1.490

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/eix/ChangeLog,v
retrieving revision 1.489
retrieving revision 1.490
diff -u -r1.489 -r1.490
--- ChangeLog	16 Mar 2015 16:35:23 -0000	1.489
+++ ChangeLog	13 Apr 2015 16:54:24 -0000	1.490
@@ -1,6 +1,13 @@
 # ChangeLog for app-portage/eix
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/eix/ChangeLog,v 1.489 2015/03/16 16:35:23 axs Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/eix/ChangeLog,v 1.490 2015/04/13 16:54:24 axs Exp $
+
+*eix-0.30.8 (13 Apr 2015)
+
+  13 Apr 2015; Ian Stakenvicius (_AxS_) <axs@gentoo.org> +eix-0.30.8.ebuild:
+  version bump; minor fixes, and treatment of /etc/portage/package.* has become
+  more compatible to portage (concerning sorting); also, users of eix-remote
+  will need to upgrade to avoid strange errors and incomplete data from zugaina.
 
 *eix-0.30.7 (16 Mar 2015)
 



1.1                  app-portage/eix/eix-0.30.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/eix-0.30.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/eix/eix-0.30.8.ebuild?rev=1.1&content-type=text/plain

Index: eix-0.30.8.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/eix/eix-0.30.8.ebuild,v 1.1 2015/04/13 16:54:24 axs Exp $

EAPI=5

PLOCALES="de ru"
inherit bash-completion-r1 eutils l10n

DESCRIPTION="Search and query ebuilds, portage incl. local settings, ext. overlays, version changes, and more"
HOMEPAGE="http://github.com/vaeth/eix/"
SRC_URI="http://dev.gentoo.org/~axs/distfiles/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
IUSE="debug +dep doc nls optimization security strong-optimization strong-security sqlite swap-remote tools"

BOTHDEPEND="sqlite? ( >=dev-db/sqlite-3 )
	nls? ( virtual/libintl )"
RDEPEND="${BOTHDEPEND}
	app-shells/push"
DEPEND="${BOTHDEPEND}
	app-arch/xz-utils
	nls? ( sys-devel/gettext )"

pkg_setup() {
	case " ${REPLACING_VERSIONS}" in
	*\ 0.[0-9].*|*\ 0.1[0-9].*|*\ 0.2[0-4].*|*\ 0.25.0*)
		local eixcache="${EROOT}/var/cache/${PN}"
		test -f "${eixcache}" && rm -f -- "${eixcache}";;
	esac
}

src_prepare() {
	sed -i -e "s'/'${EPREFIX}/'" -- "${S}"/tmpfiles.d/eix.conf
	epatch_user
}

src_configure() {
	econf $(use_with sqlite) $(use_with doc extra-doc) \
		$(use_enable nls) $(use_enable tools separate-tools) \
		$(use_enable security) $(use_enable optimization) \
		$(use_enable strong-security) \
		$(use_enable strong-optimization) $(use_enable debug debugging) \
		$(use_enable swap-remote) \
		$(use_with prefix always-accept-keywords) \
		$(use_with dep dep-default) \
		--with-zsh-completion \
		--with-portage-rootpath="${ROOTPATH}" \
		--with-eprefix-default="${EPREFIX}" \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--htmldir="${EPREFIX}/usr/share/doc/${PF}/html"
}

src_install() {
	default
	dobashcomp bash/eix
	insinto "/usr/lib/tmpfiles.d"
	doins tmpfiles.d/eix.conf
}

pkg_postinst() {
	test -d "${EROOT}var/cache/${PN}" || {
		mkdir "${EROOT}var/cache/${PN}"
		use prefix || chown portage:portage "${EROOT}var/cache/${PN}"
	}
	local obs="${EROOT}var/cache/eix.previous"
	! test -f "${obs}" || ewarn "Found obsolete ${obs}, please remove it"
}

pkg_postrm() {
	[ -n "${REPLACED_BY_VERSION}" ] || rm -rf -- "${EROOT}var/cache/${PN}"
}