[gentoo-commits] gentoo-x86 commit in media-libs/libchamplain: libchamplain-0.12.10.ebuild metadata.xml ChangeLog libchamplain-0.12.8.ebuild libchamplain-0.12.7.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/libchamplain: libchamplain-0.12.10.ebuild metadata.xml ChangeLog libchamplain-0.12.8.ebuild libchamplain-0.12.7.ebuild

[Pacho Ramos (pacho)]

pacho       15/03/19 11:51:00

  Modified:             metadata.xml ChangeLog
  Added:                libchamplain-0.12.10.ebuild
  Removed:              libchamplain-0.12.8.ebuild
                        libchamplain-0.12.7.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.8                  media-libs/libchamplain/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/metadata.xml?r1=1.7&r2=1.8

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libchamplain/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml	31 Mar 2013 18:56:47 -0000	1.7
+++ metadata.xml	19 Mar 2015 11:51:00 -0000	1.8
@@ -5,9 +5,4 @@
 	<maintainer>
 		<email>jlec@gentoo.org</email>
 	</maintainer>
-	<use>
-		<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
-		introspection</flag>
-		<flag name="vala">Generate bindings for <pkg>dev-lang/vala</pkg></flag>
-	</use>
 </pkgmetadata>



1.62                 media-libs/libchamplain/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/ChangeLog?rev=1.62&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/ChangeLog?rev=1.62&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/ChangeLog?r1=1.61&r2=1.62

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libchamplain/ChangeLog,v
retrieving revision 1.61
retrieving revision 1.62
diff -u -r1.61 -r1.62
--- ChangeLog	19 Dec 2014 13:40:14 -0000	1.61
+++ ChangeLog	19 Mar 2015 11:51:00 -0000	1.62
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libchamplain
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/ChangeLog,v 1.61 2014/12/19 13:40:14 pacho Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/ChangeLog,v 1.62 2015/03/19 11:51:00 pacho Exp $
+
+*libchamplain-0.12.10 (19 Mar 2015)
+
+  19 Mar 2015; Pacho Ramos <pacho@gentoo.org> +libchamplain-0.12.10.ebuild,
+  -files/libchamplain-0.12.5-configure-maemo.patch, -libchamplain-0.12.7.ebuild,
+  -libchamplain-0.12.8.ebuild, metadata.xml:
+  Version bump, drop old
 
   19 Dec 2014; Pacho Ramos <pacho@gentoo.org> libchamplain-0.12.9.ebuild:
   amd64 stable, bug 529964



1.1                  media-libs/libchamplain/libchamplain-0.12.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/libchamplain-0.12.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libchamplain/libchamplain-0.12.10.ebuild?rev=1.1&content-type=text/plain

Index: libchamplain-0.12.10.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libchamplain/libchamplain-0.12.10.ebuild,v 1.1 2015/03/19 11:51:00 pacho Exp $

EAPI="5"
GCONF_DEBUG=no
VALA_MIN_API_VERSION=0.14
VALA_USE_DEPEND=vapigen

inherit gnome2 vala

DESCRIPTION="Clutter based world map renderer"
HOMEPAGE="https://wiki.gnome.org/Projects/libchamplain"

SLOT="0.12"
LICENSE="LGPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

IUSE="debug +gtk +introspection vala"
REQUIRED_USE="vala? ( introspection )"

RDEPEND="
	dev-db/sqlite:3
	dev-libs/glib:2
	>=media-libs/clutter-1.12:1.0[introspection?]
	media-libs/memphis:0.2[introspection?]
	media-libs/cogl:=
	>=net-libs/libsoup-2.34:2.4
	x11-libs/cairo
	gtk? (
		x11-libs/gtk+:3[introspection?]
		media-libs/clutter-gtk:1.0 )
	introspection? ( dev-libs/gobject-introspection )
"
DEPEND="${RDEPEND}
	dev-util/gtk-doc-am
	virtual/pkgconfig
	vala? ( $(vala_depend) )
"
# segfaults with vala:0.12
# vala-0.14.2-r1 required for bug #402013

src_prepare() {
	# Fix documentation slotability
	sed \
		-e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-${SLOT}/" \
		-i docs/reference/Makefile.{am,in} || die "sed (1) failed"
	sed \
		-e "s/^DOC_MODULE.*/DOC_MODULE = ${PN}-gtk-${SLOT}/" \
		-i docs/reference-gtk/Makefile.{am,in} || die "sed (2) failed"
	mv "${S}"/docs/reference/${PN}{,-${SLOT}}-docs.sgml || die "mv (1) failed"
	mv "${S}"/docs/reference-gtk/${PN}-gtk{,-${SLOT}}-docs.sgml || die "mv (2) failed"

	use vala && vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	# Vala demos are only built, so just disable them
	gnome2_src_configure \
		--disable-static \
		--disable-maemo \
		--disable-vala-demos \
		--enable-memphis \
		$(use_enable debug) \
		$(use_enable gtk) \
		$(use_enable introspection)
}