* [gentoo-commits] gentoo-x86 commit in dev-lang/rust: rust-1.0.0_alpha.ebuild ChangeLog rust-999-r1.ebuild rust-0.11.0-r2.ebuild rust-9999-r3.ebuild rust-0.12.0.ebuild
@ 2015-02-10 11:35 Jauhien Piatlicki (jauhien)
0 siblings, 0 replies; only message in thread
From: Jauhien Piatlicki (jauhien) @ 2015-02-10 11:35 UTC (permalink / raw
To: gentoo-commits
jauhien 15/02/10 11:35:29
Modified: ChangeLog
Added: rust-1.0.0_alpha.ebuild
Removed: rust-999-r1.ebuild rust-0.11.0-r2.ebuild
rust-9999-r3.ebuild rust-0.12.0.ebuild
Log:
version bump, remove old versions, move all live stuff to the rust overlay
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0xB2EFA1D4)
Revision Changes Path
1.11 dev-lang/rust/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rust/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rust/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rust/ChangeLog?r1=1.10&r2=1.11
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/rust/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog 12 Jan 2015 18:07:32 -0000 1.10
+++ ChangeLog 10 Feb 2015 11:35:29 -0000 1.11
@@ -1,6 +1,17 @@
# ChangeLog for dev-lang/rust
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/rust/ChangeLog,v 1.10 2015/01/12 18:07:32 williamh Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/rust/ChangeLog,v 1.11 2015/02/10 11:35:29 jauhien Exp $
+
+*rust-1.0.0_alpha (10 Feb 2015)
+
+ 10 Feb 2015; Jauhien Piatlicki <jauhien@gentoo.org>
+ +files/rust-0.13.0-no-ldconfig.patch, +rust-1.0.0_alpha.ebuild,
+ -files/50rust-mode-gentoo.el, -files/rust-0.11.0-libdir.patch,
+ -files/rust-0.11.0-stage0.patch, -files/rust-0.12.0-libdir.patch,
+ -files/rust-0.12.0-no-ldconfig.patch, -files/rust-0.12.0-stage0.patch,
+ -rust-0.11.0-r2.ebuild, -rust-0.12.0.ebuild, -rust-999-r1.ebuild,
+ -rust-9999-r3.ebuild:
+ version bump, remove old versions, move all live stuff to the rust overlay
12 Jan 2015; William Hubbs <williamh@gentoo.org> metadata.xml:
add myself as a maintainer
1.1 dev-lang/rust/rust-1.0.0_alpha.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rust/rust-1.0.0_alpha.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/rust/rust-1.0.0_alpha.ebuild?rev=1.1&content-type=text/plain
Index: rust-1.0.0_alpha.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/rust/rust-1.0.0_alpha.ebuild,v 1.1 2015/02/10 11:35:29 jauhien Exp $
EAPI="5"
PYTHON_COMPAT=( python{2_6,2_7} )
inherit eutils python-any-r1
MY_PV="rustc-1.0.0-alpha"
DESCRIPTION="Systems programming language from Mozilla"
HOMEPAGE="http://www.rust-lang.org/"
SRC_URI="http://static.rust-lang.org/dist/${MY_PV}-src.tar.gz
x86? ( http://static.rust-lang.org/stage0-snapshots/rust-stage0-2015-01-07-9e4e524-linux-i386-d8b73fc9aa3ad72ce1408a41e35d78dba10eb4d4.tar.bz2 )
amd64? ( http://static.rust-lang.org/stage0-snapshots/rust-stage0-2015-01-07-9e4e524-linux-x86_64-697880d3640e981bbbf23284363e8e9a158b588d.tar.bz2 )"
LICENSE="|| ( MIT Apache-2.0 ) BSD-1 BSD-2 BSD-4 UoI-NCSA"
SLOT="1.0"
KEYWORDS="~amd64 ~x86"
IUSE="clang debug libcxx +system-llvm"
REQUIRED_USE="libcxx? ( clang )"
CDEPEND="libcxx? ( sys-libs/libcxx )
>=app-admin/eselect-rust-0.2_pre20141128
!dev-lang/rust:0
"
DEPEND="${CDEPEND}
${PYTHON_DEPS}
>=dev-lang/perl-5.0
clang? ( sys-devel/clang )
system-llvm? ( >=sys-devel/llvm-3.6.0[multitarget(-)] )
"
RDEPEND="${CDEPEND}
"
S=${WORKDIR}/${MY_PV}
src_unpack() {
unpack "${MY_PV}-src.tar.gz" || die
mkdir "${MY_PV}/dl" || die
cp "${DISTDIR}/rust-stage0"* "${MY_PV}/dl/" || die
}
src_prepare() {
epatch "${FILESDIR}/${PN}-0.13.0-no-ldconfig.patch"
local postfix="gentoo-${SLOT}"
sed -i -e "s/CFG_FILENAME_EXTRA=.*/CFG_FILENAME_EXTRA=${postfix}/" mk/main.mk || die
}
src_configure() {
use amd64 && ARCH_POSTFIX="x86_64"
use x86 && ARCH_POSTFIX="i686"
LOCAL_RUST_PATH="${WORKDIR}/rust-1.0.0-alpha-${ARCH_POSTFIX}-unknown-linux-gnu/bin"
local system_llvm
use system-llvm && system_llvm="--llvm-root=${EPREFIX}/usr"
"${ECONF_SOURCE:-.}"/configure \
--prefix="${EPREFIX}/usr" \
--libdir="${EPREFIX}/usr/lib/${P}" \
--mandir="${EPREFIX}/usr/share/${P}/man" \
$(use_enable clang) \
$(use_enable debug) \
$(use_enable debug llvm-assertions) \
$(use_enable !debug optimize) \
$(use_enable !debug optimize-cxx) \
$(use_enable !debug optimize-llvm) \
$(use_enable !debug optimize-tests) \
$(use_enable libcxx libcpp) \
${system_llvm} \
--disable-manage-submodules \
--disable-verify-install \
--disable-docs \
|| die
}
src_compile() {
emake VERBOSE=1
}
src_install() {
default
mv "${D}/usr/bin/rustc" "${D}/usr/bin/rustc-${PV}" || die
mv "${D}/usr/bin/rustdoc" "${D}/usr/bin/rustdoc-${PV}" || die
mv "${D}/usr/bin/rust-gdb" "${D}/usr/bin/rust-gdb-${PV}" || die
dodoc COPYRIGHT LICENSE-APACHE LICENSE-MIT
rm "${D}/usr/share/doc/rust" -rf
# le kludge that fixes https://github.com/Heather/gentoo-rust/issues/41
mv "${D}/usr/lib/rust-${PV}/rust-${PV}/rustlib"/* "${D}/usr/lib/rust-${PV}/rustlib/"
rmdir "${D}/usr/lib/rust-${PV}/rust-${PV}/rustlib"
mv "${D}/usr/lib/rust-${PV}/rust-${PV}/"/* "${D}/usr/lib/rust-${PV}/"
rmdir "${D}/usr/lib/rust-${PV}/rust-${PV}/"
cat <<-EOF > "${T}"/50${P}
LDPATH="/usr/lib/${P}"
MANPATH="/usr/share/${P}/man"
EOF
doenvd "${T}"/50${P}
dodir /etc/env.d/rust
touch "${D}/etc/env.d/rust/provider-${P}" || die
}
pkg_postinst() {
eselect rust update --if-unset
elog "Rust uses slots now, use 'eselect rust list'"
elog "and 'eselect rust set' to list and set rust version."
elog "For more information see 'eselect rust help'"
elog "and http://wiki.gentoo.org/wiki/Project:Eselect/User_guide"
elog "Rust installs a helper script for calling GDB now,"
elog "for your convenience it is installed under /usr/bin/rust-gdb-${PV}."
if has_version app-editors/emacs || has_version app-editors/emacs-vcs; then
elog "install app-emacs/rust-mode to get emacs support for rust."
fi
if has_version app-editors/gvim || has_version app-editors/vim; then
elog "install app-vim/rust-mode to get vim support for rust."
fi
if has_version 'app-shells/zsh'; then
elog "install app-shells/rust-zshcomp to get zsh completion for rust."
fi
}
pkg_postrm() {
eselect rust unset --if-invalid
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-02-10 11:35 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-02-10 11:35 [gentoo-commits] gentoo-x86 commit in dev-lang/rust: rust-1.0.0_alpha.ebuild ChangeLog rust-999-r1.ebuild rust-0.11.0-r2.ebuild rust-9999-r3.ebuild rust-0.12.0.ebuild Jauhien Piatlicki (jauhien)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox