* [gentoo-commits] gentoo-x86 commit in x11-libs/cairo: cairo-1.12.16-r4.ebuild ChangeLog
@ 2014-11-29 23:37 Michal Gorny (mgorny)
0 siblings, 0 replies; 3+ messages in thread
From: Michal Gorny (mgorny) @ 2014-11-29 23:37 UTC (permalink / raw
To: gentoo-commits
mgorny 14/11/29 23:37:46
Modified: ChangeLog
Added: cairo-1.12.16-r4.ebuild
Log:
Stop wrapping cairo-features.h. Now that we pass consistent configure options, it should be the same on all ABIs. Fixes compatibility with dev-haskell/cairo hackery, bug #531120.
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
Revision Changes Path
1.386 x11-libs/cairo/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.386&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.386&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?r1=1.385&r2=1.386
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v
retrieving revision 1.385
retrieving revision 1.386
diff -u -r1.385 -r1.386
--- ChangeLog 20 Nov 2014 09:29:25 -0000 1.385
+++ ChangeLog 29 Nov 2014 23:37:46 -0000 1.386
@@ -1,6 +1,13 @@
# ChangeLog for x11-libs/cairo
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.385 2014/11/20 09:29:25 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.386 2014/11/29 23:37:46 mgorny Exp $
+
+*cairo-1.12.16-r4 (29 Nov 2014)
+
+ 29 Nov 2014; Michał Górny <mgorny@gentoo.org> +cairo-1.12.16-r4.ebuild:
+ Stop wrapping cairo-features.h. Now that we pass consistent configure options,
+ it should be the same on all ABIs. Fixes compatibility with dev-haskell/cairo
+ hackery, bug #531120.
20 Nov 2014; Michał Górny <mgorny@gentoo.org> cairo-1.12.16-r3.ebuild,
cairo-9999.ebuild:
1.1 x11-libs/cairo/cairo-1.12.16-r4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?rev=1.1&content-type=text/plain
Index: cairo-1.12.16-r4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild,v 1.1 2014/11/29 23:37:46 mgorny Exp $
EAPI=5
inherit check-reqs eutils flag-o-matic autotools multilib-minimal
if [[ ${PV} == *9999* ]]; then
inherit git-2
EGIT_REPO_URI="git://anongit.freedesktop.org/git/cairo"
SRC_URI=""
else
SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
fi
DESCRIPTION="A vector graphics library with cross-device output support"
HOMEPAGE="http://cairographics.org/"
LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
SLOT="0"
IUSE="X aqua debug directfb drm gallium gles2 +glib legacy-drivers lto opengl openvg qt4 static-libs +svg valgrind xcb xlib-xcb"
# gtk-doc regeneration doesn't seem to work with out-of-source builds
#[[ ${PV} == *9999* ]] && IUSE="${IUSE} doc" # API docs are provided in tarball, no need to regenerate
# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
RESTRICT="test"
RDEPEND=">=dev-libs/lzo-2.06-r1[${MULTILIB_USEDEP}]
>=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}]
>=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}]
>=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}]
>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
>=x11-libs/pixman-0.32.4[${MULTILIB_USEDEP}]
directfb? ( dev-libs/DirectFB )
gles2? ( >=media-libs/mesa-9.1.6[gles2,${MULTILIB_USEDEP}] )
glib? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
opengl? ( || ( >=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}] media-libs/opengl-apple ) )
openvg? ( >=media-libs/mesa-9.1.6[openvg,${MULTILIB_USEDEP}] )
qt4? ( >=dev-qt/qtgui-4.8:4[${MULTILIB_USEDEP}] )
X? (
>=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
drm? (
>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
gallium? ( >=media-libs/mesa-9.1.6[gallium,${MULTILIB_USEDEP}] )
)
)
xcb? (
>=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
)
abi_x86_32? (
!<=app-emulation/emul-linux-x86-gtklibs-20131008-r1
!app-emulation/emul-linux-x86-gtklibs[-abi_x86_32(-)]
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
>=sys-devel/libtool-2
X? (
>=x11-proto/renderproto-0.11.1-r1[${MULTILIB_USEDEP}]
drm? (
>=x11-proto/xproto-7.0.24[${MULTILIB_USEDEP}]
>=x11-proto/xextproto-7.2.1-r1[${MULTILIB_USEDEP}]
)
)"
#[[ ${PV} == *9999* ]] && DEPEND="${DEPEND}
# doc? (
# >=dev-util/gtk-doc-1.6
# ~app-text/docbook-xml-dtd-4.2
# )"
# drm module requires X
# for gallium we need to enable drm
REQUIRED_USE="
drm? ( X )
gallium? ( drm )
gles2? ( !opengl )
openvg? ( || ( gles2 opengl ) )
xlib-xcb? ( xcb )
"
MULTILIB_WRAPPED_HEADERS=(
/usr/include/cairo/cairo-directfb.h
)
CHECKREQS_MEMORY="768M"
pkg_pretend() {
if [[ ${MERGE_TYPE} != "binary" ]] && use lto; then
einfo "Checking for sufficient memory to build $PN with USE=lto"
check-reqs_pkg_pretend
fi
}
pkg_setup() {
if [[ ${MERGE_TYPE} != "binary" ]] && use lto; then
check-reqs_pkg_setup
fi
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-1.8.8-interix.patch
use legacy-drivers && epatch "${FILESDIR}"/${PN}-1.10.0-buggy_gradients.patch
epatch "${FILESDIR}"/${PN}-respect-fontconfig.patch
# all-clipped handling from 1.13
epatch "${FILESDIR}"/${PN}-1.12.16-all-clipped-{1,2}.patch
# bug #507478, https://bugs.freedesktop.org/show_bug.cgi?id=77931
epatch "${FILESDIR}"/${PN}-1.12.16-all-clipped-3.patch
# allow the automagically injected -flto flag to be not injected
epatch "${FILESDIR}"/${PN}-1.12.16-lto-optional.patch
# tests and perf tools require X, bug #483574
if ! use X; then
sed -e '/^SUBDIRS/ s#boilerplate test perf# #' -i Makefile.am || die
fi
epatch_user
# Slightly messed build system YAY
if [[ ${PV} == *9999* ]]; then
touch boilerplate/Makefile.am.features
touch src/Makefile.am.features
touch ChangeLog
fi
# We need to run elibtoolize to ensure correct so versioning on FreeBSD
# upgraded to an eautoreconf for the above interix patch.
eautoreconf
}
multilib_src_configure() {
local myopts
[[ ${CHOST} == *-interix* ]] && append-flags -D_REENTRANT
use elibc_FreeBSD && myopts+=" --disable-symbol-lookup"
# TODO: remove this (and add USE-dep) when DirectFB is converted,
# bug #484248 -- but beware of the circular dep.
if ! multilib_is_native_abi; then
myopts+=" --disable-directfb"
fi
# TODO: remove this (and add USE-dep) when qtgui is converted, bug #498010
if ! multilib_is_native_abi; then
myopts+=" --disable-qt"
fi
# [[ ${PV} == *9999* ]] && myopts+=" $(use_enable doc gtk-doc)"
ECONF_SOURCE="${S}" \
econf \
--disable-dependency-tracking \
$(use_with X x) \
$(use_enable X tee) \
$(use_enable X xlib) \
$(use_enable X xlib-xrender) \
$(use_enable aqua quartz) \
$(use_enable aqua quartz-image) \
$(use_enable debug test-surfaces) \
$(use_enable drm) \
$(use_enable directfb) \
$(use_enable gallium) \
$(use_enable gles2 glesv2) \
$(use_enable glib gobject) \
$(use_enable lto) \
$(use_enable openvg vg) \
$(use_enable opengl gl) \
$(use_enable qt4 qt) \
$(use_enable static-libs static) \
$(use_enable svg) \
$(use_enable valgrind) \
$(use_enable xcb) \
$(use_enable xcb xcb-shm) \
$(use_enable xlib-xcb) \
--enable-ft \
--enable-pdf \
--enable-png \
--enable-ps \
${myopts}
}
multilib_src_install() {
# parallel make install fails
emake -j1 DESTDIR="${D}" install
}
multilib_src_install_all() {
prune_libtool_files --all
einstalldocs
}
pkg_postinst() {
if use !xlib-xcb; then
if has_version net-misc/nxserver-freenx \
|| has_version net-misc/x2goserver; then
ewarn "cairo-1.12 is known to cause GTK+ errors with NX servers."
ewarn "Enable USE=\"xlib-xcb\" if you notice incorrect behavior in GTK+"
ewarn "applications that are running inside NX sessions. For details, see"
ewarn "https://bugs.gentoo.org/441878 or https://bugs.freedesktop.org/59173"
fi
fi
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in x11-libs/cairo: cairo-1.12.16-r4.ebuild ChangeLog
@ 2015-01-09 11:39 Jeroen Roovers (jer)
0 siblings, 0 replies; 3+ messages in thread
From: Jeroen Roovers (jer) @ 2015-01-09 11:39 UTC (permalink / raw
To: gentoo-commits
jer 15/01/09 11:39:45
Modified: cairo-1.12.16-r4.ebuild ChangeLog
Log:
Stable for HPPA (bug #525300).
(Portage version: 2.2.15/cvs/Linux x86_64, RepoMan options: --ignore-arches, signed Manifest commit with key A792A613)
Revision Changes Path
1.4 x11-libs/cairo/cairo-1.12.16-r4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?r1=1.3&r2=1.4
Index: cairo-1.12.16-r4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- cairo-1.12.16-r4.ebuild 8 Jan 2015 20:46:56 -0000 1.3
+++ cairo-1.12.16-r4.ebuild 9 Jan 2015 11:39:45 -0000 1.4
@@ -1,6 +1,6 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild,v 1.3 2015/01/08 20:46:56 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild,v 1.4 2015/01/09 11:39:45 jer Exp $
EAPI=5
@@ -12,7 +12,7 @@
SRC_URI=""
else
SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
- KEYWORDS="~alpha ~amd64 arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+ KEYWORDS="~alpha ~amd64 arm ~arm64 hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
fi
DESCRIPTION="A vector graphics library with cross-device output support"
1.396 x11-libs/cairo/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.396&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.396&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?r1=1.395&r2=1.396
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v
retrieving revision 1.395
retrieving revision 1.396
diff -u -r1.395 -r1.396
--- ChangeLog 8 Jan 2015 20:46:56 -0000 1.395
+++ ChangeLog 9 Jan 2015 11:39:45 -0000 1.396
@@ -1,6 +1,9 @@
# ChangeLog for x11-libs/cairo
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.395 2015/01/08 20:46:56 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.396 2015/01/09 11:39:45 jer Exp $
+
+ 09 Jan 2015; Jeroen Roovers <jer@gentoo.org> cairo-1.12.16-r4.ebuild:
+ Stable for HPPA (bug #525300).
08 Jan 2015; Markus Meier <maekke@gentoo.org> cairo-1.12.16-r4.ebuild:
arm stable, bug #525300
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in x11-libs/cairo: cairo-1.12.16-r4.ebuild ChangeLog
@ 2015-01-31 14:12 Agostino Sarubbo (ago)
0 siblings, 0 replies; 3+ messages in thread
From: Agostino Sarubbo (ago) @ 2015-01-31 14:12 UTC (permalink / raw
To: gentoo-commits
ago 15/01/31 14:12:14
Modified: cairo-1.12.16-r4.ebuild ChangeLog
Log:
Stable for amd64, wrt bug #525300
(Portage version: 2.2.14/cvs/Linux x86_64, RepoMan options: --include-arches="amd64", signed Manifest commit with key 7194459F)
Revision Changes Path
1.5 x11-libs/cairo/cairo-1.12.16-r4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild?r1=1.4&r2=1.5
Index: cairo-1.12.16-r4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- cairo-1.12.16-r4.ebuild 9 Jan 2015 11:39:45 -0000 1.4
+++ cairo-1.12.16-r4.ebuild 31 Jan 2015 14:12:14 -0000 1.5
@@ -1,6 +1,6 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild,v 1.4 2015/01/09 11:39:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.12.16-r4.ebuild,v 1.5 2015/01/31 14:12:14 ago Exp $
EAPI=5
@@ -12,7 +12,7 @@
SRC_URI=""
else
SRC_URI="http://cairographics.org/releases/${P}.tar.xz"
- KEYWORDS="~alpha ~amd64 arm ~arm64 hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+ KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
fi
DESCRIPTION="A vector graphics library with cross-device output support"
1.397 x11-libs/cairo/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.397&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.397&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/cairo/ChangeLog?r1=1.396&r2=1.397
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v
retrieving revision 1.396
retrieving revision 1.397
diff -u -r1.396 -r1.397
--- ChangeLog 9 Jan 2015 11:39:45 -0000 1.396
+++ ChangeLog 31 Jan 2015 14:12:14 -0000 1.397
@@ -1,6 +1,9 @@
# ChangeLog for x11-libs/cairo
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.396 2015/01/09 11:39:45 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.397 2015/01/31 14:12:14 ago Exp $
+
+ 31 Jan 2015; Agostino Sarubbo <ago@gentoo.org> cairo-1.12.16-r4.ebuild:
+ Stable for amd64, wrt bug #525300
09 Jan 2015; Jeroen Roovers <jer@gentoo.org> cairo-1.12.16-r4.ebuild:
Stable for HPPA (bug #525300).
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2015-01-31 14:12 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-01-31 14:12 [gentoo-commits] gentoo-x86 commit in x11-libs/cairo: cairo-1.12.16-r4.ebuild ChangeLog Agostino Sarubbo (ago)
-- strict thread matches above, loose matches on Subject: below --
2015-01-09 11:39 Jeroen Roovers (jer)
2014-11-29 23:37 Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox