* [gentoo-commits] gentoo-x86 commit in media-gfx/dcraw: dcraw-9.23.ebuild ChangeLog
@ 2015-01-31 8:22 Tim Harder (radhermit)
0 siblings, 0 replies; only message in thread
From: Tim Harder (radhermit) @ 2015-01-31 8:22 UTC (permalink / raw
To: gentoo-commits
radhermit 15/01/31 08:22:33
Modified: ChangeLog
Added: dcraw-9.23.ebuild
Log:
Version bump.
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)
Revision Changes Path
1.94 media-gfx/dcraw/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/dcraw/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/dcraw/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/dcraw/ChangeLog?r1=1.93&r2=1.94
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/dcraw/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog 26 Oct 2014 00:25:21 -0000 1.93
+++ ChangeLog 31 Jan 2015 08:22:33 -0000 1.94
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/dcraw
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/dcraw/ChangeLog,v 1.93 2014/10/26 00:25:21 radhermit Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/dcraw/ChangeLog,v 1.94 2015/01/31 08:22:33 radhermit Exp $
+
+*dcraw-9.23 (31 Jan 2015)
+
+ 31 Jan 2015; Tim Harder <radhermit@gentoo.org> +dcraw-9.23.ebuild:
+ Version bump.
*dcraw-9.22-r1 (26 Oct 2014)
1.1 media-gfx/dcraw/dcraw-9.23.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/dcraw/dcraw-9.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/dcraw/dcraw-9.23.ebuild?rev=1.1&content-type=text/plain
Index: dcraw-9.23.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/dcraw/dcraw-9.23.ebuild,v 1.1 2015/01/31 08:22:33 radhermit Exp $
EAPI=5
inherit eutils readme.gentoo toolchain-funcs
DESCRIPTION="Converts the native (RAW) format of various digital cameras into netpbm portable pixmap (.ppm) image"
HOMEPAGE="http://www.cybercom.net/~dcoffin/dcraw/"
SRC_URI="http://www.cybercom.net/~dcoffin/dcraw/archive/${P}.tar.gz
mirror://gentoo/parse-1.73.tar.bz2
gimp? ( mirror://gentoo/rawphoto-1.32.tar.bz2 )"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
LANGS=" ca cs de da eo es fr hu it nl pl pt ru sv zh_CN zh_TW"
IUSE="nls gimp jpeg jpeg2k lcms ${LANGS// / linguas_}"
COMMON_DEPEND="
jpeg? ( virtual/jpeg )
lcms? ( media-libs/lcms:2 )
jpeg2k? ( media-libs/jasper )
gimp? ( media-gfx/gimp )
"
DEPEND="${COMMON_DEPEND}
nls? ( sys-devel/gettext )
gimp? ( virtual/pkgconfig )
"
RDEPEND="${COMMON_DEPEND}
media-libs/netpbm
"
S=${WORKDIR}/dcraw
DOC_CONTENTS="
See conversion-examples.txt.gz on how to convert
the PPM files produced by dcraw to other image formats.\n
\nThe functionality of the external program 'fujiturn' was
incorporated into dcraw and is automatically used now.\n
\nThere's an example wrapper script included called 'dcwrap'.
This package also includes 'dcparse', which extracts
thumbnail images (preferably JPEGs) from any raw digital
camera formats that have them, and shows table contents.
"
run_build() {
einfo "${@}"
${@} || die
}
src_prepare() {
rename dcraw_ dcraw. dcraw_*.1 || die "Failed to rename"
}
src_compile() {
local ECFLAGS="-O2" # Without optimisation build fails
local ELIBS="-lm"
use lcms && ELIBS="-llcms2 ${ELIBS}" || ECFLAGS+=" -DNO_LCMS=yes"
use jpeg && ELIBS="-ljpeg ${ELIBS}" || ECFLAGS+=" -DNO_JPEG=yes"
use jpeg2k && ELIBS="-ljasper ${ELIBS}" || ECFLAGS+=" -DNO_JASPER=yes"
use nls && ECFLAGS+=" -DLOCALEDIR=\"/usr/share/locale/\""
run_build $(tc-getCC) ${ECFLAGS} ${CFLAGS} ${LDFLAGS} -o dcraw dcraw.c ${ELIBS}
run_build $(tc-getCC) -O2 ${CFLAGS} ${LDFLAGS} -o dcparse parse.c
# rawphoto gimp plugin
if use gimp; then
run_build $(tc-getCC) ${CFLAGS} ${LDFLAGS} \
$(pkg-config --cflags gimpui-2.0) rawphoto.c -o rawphoto \
$(pkg-config --libs gimpui-2.0)
fi
if use nls; then
for lang in ${LANGS}; do
use linguas_${lang} && run_build msgfmt -c -o dcraw_${lang}.mo dcraw_${lang}.po
done
fi
}
src_install() {
dobin dcraw dcparse
dodoc "${FILESDIR}"/{conversion-examples.txt,dcwrap}
# rawphoto gimp plugin
if use gimp; then
insinto "$(pkg-config --variable=gimplibdir gimp-2.0)/plug-ins"
insopts -m0755
doins rawphoto
fi
doman dcraw.1
if use nls; then
for lang in ${LANGS}; do
if use linguas_${lang}; then
[[ -f dcraw.${lang}.1 ]] && doman dcraw.${lang}.1
insinto /usr/share/locale/${lang}/LC_MESSAGES
newins dcraw_${lang}.mo dcraw.mo || die "failed to install dcraw_${lang}.mo"
fi
done
fi
readme.gentoo_create_doc
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-01-31 8:22 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-01-31 8:22 [gentoo-commits] gentoo-x86 commit in media-gfx/dcraw: dcraw-9.23.ebuild ChangeLog Tim Harder (radhermit)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox