* [gentoo-commits] gentoo-x86 commit in sys-apps/pacman: pacman-4.0.3-r1.ebuild ChangeLog
@ 2014-10-24 23:03 Michal Gorny (mgorny)
0 siblings, 0 replies; 2+ messages in thread
From: Michal Gorny (mgorny) @ 2014-10-24 23:03 UTC (permalink / raw
To: gentoo-commits
mgorny 14/10/24 23:03:37
Modified: ChangeLog
Added: pacman-4.0.3-r1.ebuild
Log:
Add missing aliases for completions, bug #526316.
(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
Revision Changes Path
1.13 sys-apps/pacman/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/ChangeLog?r1=1.12&r2=1.13
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pacman/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog 2 Jul 2012 06:03:57 -0000 1.12
+++ ChangeLog 24 Oct 2014 23:03:37 -0000 1.13
@@ -1,6 +1,11 @@
# ChangeLog for sys-apps/pacman
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/ChangeLog,v 1.12 2012/07/02 06:03:57 binki Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/ChangeLog,v 1.13 2014/10/24 23:03:37 mgorny Exp $
+
+*pacman-4.0.3-r1 (24 Oct 2014)
+
+ 24 Oct 2014; Michał Górny <mgorny@gentoo.org> +pacman-4.0.3-r1.ebuild:
+ Add missing aliases for completions, bug #526316.
*pacman-4.0.3 (02 Jul 2012)
1.1 sys-apps/pacman/pacman-4.0.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild?rev=1.1&content-type=text/plain
Index: pacman-4.0.3-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild,v 1.1 2014/10/24 23:03:37 mgorny Exp $
EAPI=4
inherit autotools autotools-utils bash-completion-r1 eutils
DESCRIPTION="Archlinux's binary package manager"
HOMEPAGE="http://archlinux.org/pacman/"
SRC_URI="ftp://ftp.archlinux.org/other/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl debug doc gpg test"
COMMON_DEPEND="app-arch/libarchive
dev-libs/openssl
virtual/libiconv
virtual/libintl
sys-devel/gettext
curl? ( net-misc/curl )
gpg? ( app-crypt/gpgme )"
RDEPEND="${COMMON_DEPEND}
app-arch/xz-utils"
# autoconf macros from gpgme requied unconditionally
# makepkg collision with old bash-completion
DEPEND="${COMMON_DEPEND}
app-crypt/gpgme
doc? ( app-doc/doxygen
app-text/asciidoc )
test? ( dev-lang/python )
!<=app-shells/bash-completion-2.1-r90"
RESTRICT="test"
src_prepare() {
# Adds AM_GPGME_PATH call which requires app-crypt/gpgme to be
# DEPENDed on unconditionally:
epatch "${FILESDIR}"/${PN}-4.0.0-gpgme.patch
# Remove a line that adds -Werror in ./configure when --enable-debug
# is passed:
sed -i -e '/-Werror/d' configure.ac || die "-Werror"
# autopoint is unwilling to replace m4/gettext.m4 with the correct
# version even though it'll gladly replace */po/Makefile.in.in,
# creating an inconsistency between gettext m4 macros and
# Makefile.in.in. Also, AM_MKINSTALLDIRS apparently doesn't exist
# anymore, so we need newer gettext macros. #420469
rm m4/gettext.m4 || die
sed -i -e '/AM_GNU_GETTEXT_VERSION/s/0\.13\.1/0.18.1/' configure.ac || die
eautoreconf
}
src_configure() {
local myeconfargs=(
--localstatedir=/var
--disable-git-version
--with-openssl
# Help protect user from shooting his/her Gentoo installation in
# its foot.
--with-root-dir="${EPREFIX}"/var/chroot/archlinux
$(use_enable debug)
$(use_enable doc)
$(use_enable doc doxygen)
$(use_with curl libcurl)
$(use_with gpg gpgme)
)
autotools-utils_src_configure
}
src_install() {
autotools-utils_src_install
dodir /etc/pacman.d
newbashcomp "${AUTOTOOLS_BUILD_DIR}"/contrib/bash_completion pacman
bashcomp_alias pacman pacman-key makepkg
}
pkg_postinst() {
einfo "Please see http://ohnopub.net/~ohnobinki/gentoo/arch/ for information"
einfo "about setting up an archlinux chroot."
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sys-apps/pacman: pacman-4.0.3-r1.ebuild ChangeLog
@ 2015-01-05 21:46 Michal Gorny (mgorny)
0 siblings, 0 replies; 2+ messages in thread
From: Michal Gorny (mgorny) @ 2015-01-05 21:46 UTC (permalink / raw
To: gentoo-commits
mgorny 15/01/05 21:46:57
Modified: pacman-4.0.3-r1.ebuild ChangeLog
Log:
Use python-any-r1 for tests.
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
Revision Changes Path
1.2 sys-apps/pacman/pacman-4.0.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild?r1=1.1&r2=1.2
Index: pacman-4.0.3-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- pacman-4.0.3-r1.ebuild 24 Oct 2014 23:03:37 -0000 1.1
+++ pacman-4.0.3-r1.ebuild 5 Jan 2015 21:46:57 -0000 1.2
@@ -1,10 +1,11 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild,v 1.1 2014/10/24 23:03:37 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/pacman-4.0.3-r1.ebuild,v 1.2 2015/01/05 21:46:57 mgorny Exp $
EAPI=4
-inherit autotools autotools-utils bash-completion-r1 eutils
+PYTHON_COMPAT=( python2_7 )
+inherit autotools autotools-utils bash-completion-r1 eutils python-any-r1
DESCRIPTION="Archlinux's binary package manager"
HOMEPAGE="http://archlinux.org/pacman/"
@@ -30,7 +31,7 @@
app-crypt/gpgme
doc? ( app-doc/doxygen
app-text/asciidoc )
- test? ( dev-lang/python )
+ test? ( ${PYTHON_DEPS} )
!<=app-shells/bash-completion-2.1-r90"
RESTRICT="test"
1.14 sys-apps/pacman/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pacman/ChangeLog?r1=1.13&r2=1.14
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pacman/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog 24 Oct 2014 23:03:37 -0000 1.13
+++ ChangeLog 5 Jan 2015 21:46:57 -0000 1.14
@@ -1,6 +1,9 @@
# ChangeLog for sys-apps/pacman
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/ChangeLog,v 1.13 2014/10/24 23:03:37 mgorny Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pacman/ChangeLog,v 1.14 2015/01/05 21:46:57 mgorny Exp $
+
+ 05 Jan 2015; Michał Górny <mgorny@gentoo.org> pacman-4.0.3-r1.ebuild:
+ Use python-any-r1 for tests.
*pacman-4.0.3-r1 (24 Oct 2014)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2015-01-05 21:47 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-01-05 21:46 [gentoo-commits] gentoo-x86 commit in sys-apps/pacman: pacman-4.0.3-r1.ebuild ChangeLog Michal Gorny (mgorny)
-- strict thread matches above, loose matches on Subject: below --
2014-10-24 23:03 Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox