[gentoo-commits] gentoo-x86 commit in gnome-extra/gucharmap: ChangeLog gucharmap-3.14.2.ebuild gucharmap-3.10.1.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-extra/gucharmap: ChangeLog gucharmap-3.14.2.ebuild gucharmap-3.10.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         14/12/22 23:33:51

  Modified:             ChangeLog
  Added:                gucharmap-3.14.2.ebuild
  Removed:              gucharmap-3.10.1.ebuild
  Log:
  Version bump for Gnome 3.14. Clean up old revision.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.225                gnome-extra/gucharmap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/ChangeLog?rev=1.225&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/ChangeLog?rev=1.225&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/ChangeLog?r1=1.224&r2=1.225

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v
retrieving revision 1.224
retrieving revision 1.225
diff -u -r1.224 -r1.225
--- ChangeLog	11 Oct 2014 12:15:52 -0000	1.224
+++ ChangeLog	22 Dec 2014 23:33:51 -0000	1.225
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gucharmap
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v 1.224 2014/10/11 12:15:52 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v 1.225 2014/12/22 23:33:51 eva Exp $
+
+*gucharmap-3.14.2 (22 Dec 2014)
+
+  22 Dec 2014; Gilles Dartiguelongue <eva@gentoo.org> -gucharmap-3.10.1.ebuild,
+  +gucharmap-3.14.2.ebuild:
+  Version bump for Gnome 3.14. Clean up old revision.
 
   11 Oct 2014; Markus Meier <maekke@gentoo.org> gucharmap-3.12.1.ebuild:
   arm stable, bug #512012



1.1                  gnome-extra/gucharmap/gucharmap-3.14.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.14.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.14.2.ebuild?rev=1.1&content-type=text/plain

Index: gucharmap-3.14.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.14.2.ebuild,v 1.1 2014/12/22 23:33:51 eva Exp $

EAPI="5"
GCONF_DEBUG="yes"
VALA_MIN_API_VERSION="0.16"
VALA_USE_DEPEND="vapigen"

inherit gnome2 vala

DESCRIPTION="Unicode character map viewer and library"
HOMEPAGE="http://live.gnome.org/Gucharmap"

LICENSE="GPL-3"
SLOT="2.90"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="cjk +introspection test vala"
REQUIRED_USE="vala? ( introspection )"

COMMON_DEPEND="
	>=dev-libs/glib-2.32:2
	>=x11-libs/pango-1.2.1[introspection?]
	>=x11-libs/gtk+-3.4.0:3[introspection?]

	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
"
RDEPEND="${COMMON_DEPEND}
	!<gnome-extra/gucharmap-3:0
"
DEPEND="${RDEPEND}
	app-text/yelp-tools
	dev-util/appdata-tools
	dev-util/desktop-file-utils
	>=dev-util/gtk-doc-am-1
	>=dev-util/intltool-0.40
	sys-devel/gettext
	virtual/pkgconfig
	test? (	app-text/docbook-xml-dtd:4.1.2 )
	vala? ( $(vala_depend) )
"

src_prepare() {
	# prevent file collisions with slot 0
	sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
		-i configure.ac configure || die "sed configure.ac configure failed"

	# avoid autoreconf
	sed -e 's/-Wall //g' -i configure || die "sed failed"

	use vala && vala_src_prepare
	gnome2_src_prepare
}

src_configure() {
	# Do not add ITSTOOL=$(type -P true); yelp-tools is a true required
	# dependency here for some LINGUAS.
	gnome2_src_configure \
		--disable-static \
		$(use_enable introspection) \
		$(use_enable cjk unihan) \
		$(use_enable vala)
}