[gentoo-commits] gentoo-x86 commit in dev-libs/libgit2: ChangeLog libgit2-0.21.2.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/libgit2: ChangeLog libgit2-0.21.2.ebuild

[Tim Harder (radhermit)]

radhermit    14/10/28 00:48:01

  Modified:             ChangeLog
  Added:                libgit2-0.21.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.25                 dev-libs/libgit2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libgit2/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	8 Aug 2014 16:49:02 -0000	1.24
+++ ChangeLog	28 Oct 2014 00:48:01 -0000	1.25
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libgit2
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/ChangeLog,v 1.24 2014/08/08 16:49:02 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/ChangeLog,v 1.25 2014/10/28 00:48:01 radhermit Exp $
+
+*libgit2-0.21.2 (28 Oct 2014)
+
+  28 Oct 2014; Tim Harder <radhermit@gentoo.org> +libgit2-0.21.2.ebuild:
+  Version bump.
 
 *libgit2-0.21.1 (08 Aug 2014)
 



1.1                  dev-libs/libgit2/libgit2-0.21.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/libgit2-0.21.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libgit2/libgit2-0.21.2.ebuild?rev=1.1&content-type=text/plain

Index: libgit2-0.21.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgit2/libgit2-0.21.2.ebuild,v 1.1 2014/10/28 00:48:01 radhermit Exp $

EAPI=5

inherit cmake-utils multilib

DESCRIPTION="A linkable library for Git"
HOMEPAGE="http://libgit2.github.com/"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2-with-linking-exception"
SLOT="0/21"
KEYWORDS="~amd64 ~x86 ~ppc-macos"
IUSE="examples ssh test threads trace"

RDEPEND="
	sys-libs/zlib
	net-libs/http-parser
	ssh? ( net-libs/libssh2 )"
DEPEND="${RDEPEND}"

DOCS=( AUTHORS CONTRIBUTING.md CONVENTIONS.md README.md )

src_prepare() {
	# skip online tests
	sed -i '/libgit2_clar/s/-ionline/-xonline/' CMakeLists.txt || die

	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DLIB_INSTALL_DIR="${EPREFIX}/usr/$(get_libdir)"
		$(cmake-utils_use_build test CLAR)
		$(cmake-utils_use_enable trace TRACE)
		$(cmake-utils_use_use ssh SSH)
		$(cmake-utils_use threads THREADSAFE)
	)
	cmake-utils_src_configure
}

src_test() {
	if [[ ${EUID} -eq 0 ]] ; then
		# repo::iterator::fs_preserves_error fails if run as root
		# since root can still access dirs with 0000 perms
		ewarn "Skipping tests: non-root privileges are required for all tests to pass"
	else
		local TEST_VERBOSE=1
		cmake-utils_src_test
	fi
}

src_install() {
	cmake-utils_src_install

	if use examples ; then
		find examples -name .gitignore -delete || die
		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
	fi
}