* [gentoo-commits] gentoo-x86 commit in sci-libs/scikits_learn: ChangeLog scikits_learn-0.15.1.ebuild
@ 2014-10-26 17:58 Justin Lecher (jlec)
0 siblings, 0 replies; 2+ messages in thread
From: Justin Lecher (jlec) @ 2014-10-26 17:58 UTC (permalink / raw
To: gentoo-commits
jlec 14/10/26 17:58:12
Modified: ChangeLog
Added: scikits_learn-0.15.1.ebuild
Log:
sci-libs/scikits_learn: Version Bump, #521042
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)
Revision Changes Path
1.25 sci-libs/scikits_learn/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/ChangeLog?r1=1.24&r2=1.25
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog 18 Sep 2013 10:55:51 -0000 1.24
+++ ChangeLog 26 Oct 2014 17:58:12 -0000 1.25
@@ -1,6 +1,11 @@
# ChangeLog for sci-libs/scikits_learn
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.24 2013/09/18 10:55:51 jlec Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.25 2014/10/26 17:58:12 jlec Exp $
+
+*scikits_learn-0.15.1 (26 Oct 2014)
+
+ 26 Oct 2014; Justin Lecher <jlec@gentoo.org> +scikits_learn-0.15.1.ebuild:
+ Version Bump, #521042
18 Sep 2013; Justin Lecher <jlec@gentoo.org> scikits_learn-0.13.1.ebuild,
scikits_learn-0.14.1.ebuild, metadata.xml:
1.1 sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild?rev=1.1&content-type=text/plain
Index: scikits_learn-0.15.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild,v 1.1 2014/10/26 17:58:12 jlec Exp $
EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
DISTUTILS_NO_PARALLEL_BUILD=true
inherit distutils-r1 eutils multilib flag-o-matic
MYPN="${PN/scikits_/scikit-}"
MYP="${MYPN}-${PV}"
DESCRIPTION="Python modules for machine learning and data mining"
HOMEPAGE="http://scikit-learn.org"
SRC_URI="mirror://pypi/${MYPN:0:1}/${MYPN}/${MYP}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples test"
RDEPEND="
dev-python/joblib[${PYTHON_USEDEP}]
sci-libs/scikits[${PYTHON_USEDEP}]
dev-python/numpy[lapack,${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]"
DEPEND="
dev-python/cython[${PYTHON_USEDEP}]
dev-python/numpy[lapack,${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]
doc? (
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}] )
test? (
dev-python/joblib[${PYTHON_USEDEP}]
dev-python/nose[${PYTHON_USEDEP}] )"
S="${WORKDIR}/${MYP}"
python_prepare_all() {
# bug #397605
[[ ${CHOST} == *-darwin* ]] \
&& append-ldflags -bundle "-undefined dynamic_lookup" \
|| append-ldflags -shared
# scikits-learn now uses the horrible numpy.distutils automagic
export SCIPY_FCONFIG="config_fc --noopt --noarch"
# use system joblib
rm -r sklearn/externals/joblib/* || die
echo "from joblib import *" > sklearn/externals/joblib/__init__.py
sed -i -e '/joblib\/test/d' sklearn/externals/setup.py || die
sed -i -e 's/..externals.joblib/joblib/g' \
sklearn/decomposition/tests/test_sparse_pca.py \
sklearn/metrics/pairwise.py || die
# use gentoo cblas infrastructure
epatch "${FILESDIR}"/${PN}-0.14.1-system-cblas.patch
distutils-r1_python_prepare_all
}
python_compile() {
distutils-r1_python_compile ${SCIPY_FCONFIG}
}
python_compile_all() {
if use doc; then
cd "${S}/doc"
local d="${BUILD_DIR}"/lib
ln -s "${S}"/sklearn/datasets/{data,descr,images} \
"${d}"/sklearn/datasets
VARTEXFONTS="${T}"/fonts \
MPLCONFIGDIR="${BUILD_DIR}" \
PYTHONPATH="${d}" \
emake html
rm -r "${d}"/sklearn/datasets/{data,desr,images}
fi
}
python_test() {
# doc builds and runs tests
use doc && return
distutils_install_for_testing ${SCIPY_FCONFIG}
esetup.py \
install --root="${T}/test-${EPYTHON}" \
--no-compile ${SCIPY_FCONFIG}
pushd "${T}/test-${EPYTHON}/$(python_get_sitedir)" || die > /dev/null
nosetests -v sklearn --exe || die
popd > /dev/null
}
python_install() {
distutils-r1_python_install ${SCIPY_FCONFIG}
}
python_install_all() {
find "${S}" -name \*LICENSE.txt -delete
use doc && HTML_DOCS=( doc/_build/html/. )
distutils-r1_python_install_all
if use examples; then
insinto /usr/share/doc/${PF}
doins -r examples
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sci-libs/scikits_learn: ChangeLog scikits_learn-0.15.1.ebuild
@ 2014-10-26 18:33 Justin Lecher (jlec)
0 siblings, 0 replies; 2+ messages in thread
From: Justin Lecher (jlec) @ 2014-10-26 18:33 UTC (permalink / raw
To: gentoo-commits
jlec 14/10/26 18:33:23
Modified: ChangeLog scikits_learn-0.15.1.ebuild
Log:
sci-libs/scikits_learn: Add missing dep for doc building, #451834
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)
Revision Changes Path
1.26 sci-libs/scikits_learn/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/ChangeLog?r1=1.25&r2=1.26
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog 26 Oct 2014 17:58:12 -0000 1.25
+++ ChangeLog 26 Oct 2014 18:33:23 -0000 1.26
@@ -1,6 +1,9 @@
# ChangeLog for sci-libs/scikits_learn
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.25 2014/10/26 17:58:12 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.26 2014/10/26 18:33:23 jlec Exp $
+
+ 26 Oct 2014; Justin Lecher <jlec@gentoo.org> scikits_learn-0.15.1.ebuild:
+ Add missing dep for doc building, #451834
*scikits_learn-0.15.1 (26 Oct 2014)
1.2 sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild?r1=1.1&r2=1.2
Index: scikits_learn-0.15.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- scikits_learn-0.15.1.ebuild 26 Oct 2014 17:58:12 -0000 1.1
+++ scikits_learn-0.15.1.ebuild 26 Oct 2014 18:33:23 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild,v 1.1 2014/10/26 17:58:12 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.15.1.ebuild,v 1.2 2014/10/26 18:33:23 jlec Exp $
EAPI=5
@@ -33,8 +33,10 @@
dev-python/setuptools[${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]
doc? (
+ dev-python/joblib[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
dev-python/sphinx[${PYTHON_USEDEP}]
- dev-python/matplotlib[${PYTHON_USEDEP}] )
+ )
test? (
dev-python/joblib[${PYTHON_USEDEP}]
dev-python/nose[${PYTHON_USEDEP}] )"
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2014-10-26 18:33 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-10-26 18:33 [gentoo-commits] gentoo-x86 commit in sci-libs/scikits_learn: ChangeLog scikits_learn-0.15.1.ebuild Justin Lecher (jlec)
-- strict thread matches above, loose matches on Subject: below --
2014-10-26 17:58 Justin Lecher (jlec)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox