[gentoo-commits] gentoo-x86 commit in dev-python/flask: flask-0.10.1-r2.ebuild ChangeLog flask-0.10.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/flask: flask-0.10.1-r2.ebuild ChangeLog flask-0.10.1.ebuild

[Ian Delaney (idella4)]

idella4     14/10/26 04:38:06

  Modified:             ChangeLog
  Added:                flask-0.10.1-r2.ebuild
  Removed:              flask-0.10.1.ebuild
  Log:
  revbump; add IUSE doc, docs build, install
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.38                 dev-python/flask/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	26 Oct 2014 03:54:09 -0000	1.37
+++ ChangeLog	26 Oct 2014 04:38:06 -0000	1.38
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/flask
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.37 2014/10/26 03:54:09 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/ChangeLog,v 1.38 2014/10/26 04:38:06 idella4 Exp $
+
+*flask-0.10.1-r2 (26 Oct 2014)
+
+  26 Oct 2014; Ian Delaney <idella4@gentoo.org> +flask-0.10.1-r2.ebuild,
+  -flask-0.10.1.ebuild, flask-0.10.1-r1.ebuild:
+  revbump; add IUSE doc, docs build, install
 
   10 Oct 2014; Ian Delaney <idella4@gentoo.org> flask-0.10.1-r1.ebuild,
   flask-9999.ebuild:



1.1                  dev-python/flask/flask-0.10.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/flask-0.10.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/flask/flask-0.10.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: flask-0.10.1-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/flask/flask-0.10.1-r2.ebuild,v 1.1 2014/10/26 04:38:06 idella4 Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )

inherit distutils-r1

DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
MY_PN="Flask"
MY_P="${MY_PN}-${PV}"
SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
HOMEPAGE="https://github.com/mitsuhiko/flask/"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="doc examples"

RDEPEND="dev-python/blinker[${PYTHON_USEDEP}]
	>=dev-python/itsdangerous-0.21[${PYTHON_USEDEP}]
	>=dev-python/jinja-2.4[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	>=dev-python/werkzeug-0.7[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
DEPEND="${RDEPEND}"
# Usual; test phase
DISTUTILS_IN_SOURCE_BUILD=1

S="${WORKDIR}/${MY_P}"

PATCHES=( "${FILESDIR}"/${P}-is_package.patch
		"${FILESDIR}"/${P}-sort_json.patch
		"${FILESDIR}"/${P}-test_appcontext.patch )

python_prepare_all() {
	 # Prevent un-needed d'loading
	sed -e "s/ 'sphinx.ext.intersphinx',//" -i docs/conf.py || die

	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C docs html
}

python_test() {
	"${PYTHON}" run-tests.py || die "Testing failed with ${EPYTHON}"
}

python_install_all() {
	use examples && local EXAMPLES=( examples/. )
	use doc && HTML_DOCS=( docs/_build/html/. )

	distutils-r1_python_install_all
}