[gentoo-commits] gentoo-x86 commit in media-tv/gentoo-vdr-scripts: ChangeLog gentoo-vdr-scripts-2.5_rc4.ebuild gentoo-vdr-scripts-2.5_rc3.ebuild

["Joerg Bornkessel (hd_brummy)" <hd_brummy@gentoo.org>]

hd_brummy    14/10/22 10:59:09

  Modified:             ChangeLog
  Added:                gentoo-vdr-scripts-2.5_rc4.ebuild
  Removed:              gentoo-vdr-scripts-2.5_rc3.ebuild
  Log:
  bump (again), something goes wrong with last commit
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 34C2808A)

Revision  Changes    Path
1.129                media-tv/gentoo-vdr-scripts/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog?r1=1.128&r2=1.129

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog	21 Oct 2014 21:00:54 -0000	1.128
+++ ChangeLog	22 Oct 2014 10:59:08 -0000	1.129
@@ -1,6 +1,12 @@
 # ChangeLog for media-tv/gentoo-vdr-scripts
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.128 2014/10/21 21:00:54 hd_brummy Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/ChangeLog,v 1.129 2014/10/22 10:59:08 hd_brummy Exp $
+
+*gentoo-vdr-scripts-2.5_rc4 (22 Oct 2014)
+
+  22 Oct 2014; Joerg Bornkessel <hd_brummy@gentoo.org>
+  -gentoo-vdr-scripts-2.5_rc3.ebuild, +gentoo-vdr-scripts-2.5_rc4.ebuild:
+  bump (again), something goes wrong with last commit
 
 *gentoo-vdr-scripts-2.5_rc3 (21 Oct 2014)
 



1.1                  media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-2.5_rc4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-2.5_rc4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-2.5_rc4.ebuild?rev=1.1&content-type=text/plain

Index: gentoo-vdr-scripts-2.5_rc4.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-tv/gentoo-vdr-scripts/gentoo-vdr-scripts-2.5_rc4.ebuild,v 1.1 2014/10/22 10:59:08 hd_brummy Exp $

EAPI=5

inherit eutils user

DESCRIPTION="Scripts necessary for use of vdr as a set-top-box"
HOMEPAGE="http://www.gentoo.org/"
SRC_URI="mirror://gentoo/${P}.tar.bz2
	http://dev.gentoo.org/~hd_brummy/distfiles/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="nvram"

RDEPEND="nvram? ( sys-power/nvram-wakeup )
	app-admin/sudo
	sys-process/wait_on_pid"

VDR_HOME=/var/vdr

pkg_setup() {
	enewgroup vdr

	# Add user vdr to these groups:
	#   video - accessing dvb-devices
	#   audio - playing sound when using software-devices
	#   cdrom - playing dvds/audio-cds ...
	enewuser vdr -1 /bin/bash "${VDR_HOME}" vdr,video,audio,cdrom
}

src_prepare() {
	# moved into own package
	sed -e '/SUBDIRS =/s# bin # #' -i usr/Makefile
	sed -e '/all:/s#compile##' -i Makefile
}

src_install() {
	emake -s install DESTDIR="${D}" || die "make install failed"
	dodoc README TODO ChangeLog README.grub2

	# create necessary directories
	diropts -ovdr -gvdr
	keepdir "${VDR_HOME}"

	local kd
	for kd in shutdown-data merged-config-files dvd-images tmp; do
		keepdir "${VDR_HOME}/${kd}"
	done
}

pkg_preinst() {
	local PLUGINS_NEW=0
	if [[ -f "${ROOT}"/etc/conf.d/vdr.plugins ]]; then
		PLUGINS_NEW=$(grep -v '^#' "${ROOT}"/etc/conf.d/vdr.plugins |grep -v '^$'|wc -l)
	fi
	if [[ ${PLUGINS_NEW} > 0 ]]; then
		cp "${ROOT}"/etc/conf.d/vdr.plugins "${D}"/etc/conf.d/vdr.plugins
	else
		einfo "Migrating PLUGINS setting from /etc/conf.d/vdr to /etc/conf.d/vdr.plugins"
		local PLUGIN
		for PLUGIN in $(source "${ROOT}"/etc/conf.d/vdr;echo $PLUGINS); do
			echo ${PLUGIN} >> "${D}"/etc/conf.d/vdr.plugins
		done
	fi

	has_version "<${CATEGORY}/${PN}-0.5.4"
	previous_less_than_0_5_4=$?
}

VDRSUDOENTRY="vdr ALL=NOPASSWD:/usr/share/vdr/bin/vdrshutdown-really.sh"

pkg_postinst() {
	if [[ $previous_less_than_0_5_4 = 0 ]] ; then
		einfo "\nVDR use now default the --cachedir parameter to store the epg.file"
		einfo "Please do not override this with the EPGFILE variable\n"

		einfo "svdrp port 2001 support removed\n"

		einfo "--rcu support removed, use media-plugin/vdr-rcu\n"
	fi

	elog "nvram wakeup is optional."
	elog "To make use of it emerge sys-power/nvram-wakeup."
	elog

	elog "Plugins which should be used are now set via its"
	elog "own config-file called /etc/conf.d/vdr.plugins"
	elog "or enabled via the frontend eselect vdr-plugin."
	elog

	if [[ -f "${ROOT}/etc/init.d/dvbsplash" ]]; then
		ewarn
		ewarn "You have dvbsplash installed!"
		ewarn "/etc/init.d/dvbsplash will now be deleted"
		ewarn "as it causes difficult to debug problems."
		ewarn
		rm "${ROOT}/etc/init.d/dvbsplash"
	fi

	if [[ -f "${ROOT}"/etc/conf.d/vdr.dvdswitch ]] &&
		grep -q ^DVDSWITCH_BURNSPEED= "${ROOT}"/etc/conf.d/vdr.dvdswitch
	then
		ewarn "You are setting DVDSWITCH_BURNSPEED in /etc/conf.d/vdr.dvdswitch"
		ewarn "This no longer has any effect, please use"
		ewarn "VDR_DVDBURNSPEED in /etc/conf.d/vdr.cd-dvd"
	fi

	einfo "Up from this version systemd is supported by gentoo-vdr-scripts"
	einfo "Please see for detailed info on this:"
	einfo "Also please report problems with systemd on gentoo-vdr-scripts direct in this bug"
	einfo "https://bugs.gentoo.org/show_bug.cgi?id=353492"

}

pkg_config() {
	if grep -q /usr/share/vdr/bin/vdrshutdown-really.sh "${ROOT}"/etc/sudoers; then

		einfo "Removing depricated entry from /etc/sudoers:"
		einfo "-  ${VDRSUDOENTRY}"

		cd "${T}"
		cat >sudoedit-vdr.sh <<-SUDOEDITOR
			#!/bin/bash
			sed -i \${1} -e '/\/usr\/share\/vdr\/bin\/vdrshutdown-really.sh *$/d'

		SUDOEDITOR
		chmod a+x sudoedit-vdr.sh

		VISUAL="${T}"/sudoedit-vdr.sh visudo -f "${ROOT}"/etc/sudoers || die "visudo failed"

		einfo "Edited /etc/sudoers"
	fi
}