* [gentoo-commits] gentoo-x86 commit in dev-libs/rasqal: rasqal-0.9.32.ebuild ChangeLog
@ 2014-10-21 4:45 Samuli Suominen (ssuominen)
0 siblings, 0 replies; only message in thread
From: Samuli Suominen (ssuominen) @ 2014-10-21 4:45 UTC (permalink / raw
To: gentoo-commits
ssuominen 14/10/21 04:45:11
Modified: ChangeLog
Added: rasqal-0.9.32.ebuild
Log:
Version bump wrt #526156 by Arfrever Frehtes Taifersar Arahesis. Still missing handling of --with-random-approach since .28. Punt useless USE="doc", use FEATURES="nodoc" or INSTALL_MASK if you don't want the prebuilt documentation.
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)
Revision Changes Path
1.91 dev-libs/rasqal/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/ChangeLog?rev=1.91&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/ChangeLog?rev=1.91&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/ChangeLog?r1=1.90&r2=1.91
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v
retrieving revision 1.90
retrieving revision 1.91
diff -u -r1.90 -r1.91
--- ChangeLog 1 Mar 2014 22:12:53 -0000 1.90
+++ ChangeLog 21 Oct 2014 04:45:11 -0000 1.91
@@ -1,6 +1,13 @@
# ChangeLog for dev-libs/rasqal
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v 1.90 2014/03/01 22:12:53 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/ChangeLog,v 1.91 2014/10/21 04:45:11 ssuominen Exp $
+
+*rasqal-0.9.32 (21 Oct 2014)
+
+ 21 Oct 2014; Samuli Suominen <ssuominen@gentoo.org> +rasqal-0.9.32.ebuild:
+ Version bump wrt #526156 by Arfrever Frehtes Taifersar Arahesis. Still missing
+ handling of --with-random-approach since .28. Punt useless USE="doc", use
+ FEATURES="nodoc" or INSTALL_MASK if you don't want the prebuilt documentation.
01 Mar 2014; Michał Górny <mgorny@gentoo.org> rasqal-0.9.28.ebuild,
rasqal-0.9.29.ebuild, rasqal-0.9.30.ebuild:
1.1 dev-libs/rasqal/rasqal-0.9.32.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/rasqal-0.9.32.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/rasqal/rasqal-0.9.32.ebuild?rev=1.1&content-type=text/plain
Index: rasqal-0.9.32.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/rasqal/rasqal-0.9.32.ebuild,v 1.1 2014/10/21 04:45:11 ssuominen Exp $
EAPI=5
inherit eutils libtool
DESCRIPTION="library that handles Resource Description Framework (RDF)"
HOMEPAGE="http://librdf.org/rasqal/"
SRC_URI="http://download.librdf.org/source/${P}.tar.gz"
LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos"
IUSE="+crypt gmp kernel_linux +mhash pcre static-libs test xml"
RDEPEND=">=media-libs/raptor-2.0.14
kernel_linux? ( >=sys-apps/util-linux-2.19 )
pcre? ( dev-libs/libpcre )
xml? ( dev-libs/libxml2 )
!gmp? ( dev-libs/mpfr )
gmp? ( dev-libs/gmp )
crypt? (
!mhash? ( dev-libs/libgcrypt:0 )
mhash? ( app-crypt/mhash )
)"
DEPEND="${RDEPEND}
>=sys-devel/bison-3
>=sys-devel/flex-2.5.36
virtual/pkgconfig
test? ( dev-perl/XML-DOM )"
DOCS="AUTHORS ChangeLog NEWS README"
src_prepare() {
elibtoolize # g/fbsd .so versioning
}
src_configure() {
# FIXME: From 0.9.27 to .28 --with-random-approach= was introduced, do we
# need a logic for it? Perhaps for dev-libs/gmp?
local regex=posix
local decimal=mpfr
local digest=internal
local uuid=internal
use pcre && regex=pcre
use gmp && decimal=gmp
use kernel_linux && uuid=libuuid
if use crypt; then
digest=gcrypt
use mhash && digest=mhash
fi
econf \
$(use_enable pcre) \
$(use_enable static-libs static) \
$(use_enable xml xml2) \
--with-regex-library=${regex} \
--with-digest-library=${digest} \
--with-uuid-library=${uuid} \
--with-decimal=${decimal} \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}
src_install() {
default
dohtml {NEWS,README,RELEASE}.html
prune_libtool_files --all
# http://bugs.gentoo.org/467768
local _rdocdir=/usr/share/doc/${PF}/html/${PN}
[[ -d ${ED}/${_rdocdir} ]] && dosym ${_rdocdir} /usr/share/gtk-doc/html/${PN}
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-10-21 4:45 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-10-21 4:45 [gentoo-commits] gentoo-x86 commit in dev-libs/rasqal: rasqal-0.9.32.ebuild ChangeLog Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox