public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in app-backup/backuppc: backuppc-3.3.0.ebuild ChangeLog
@ 2014-07-30  8:26 Patrick Lauer (patrick)
  0 siblings, 0 replies; 4+ messages in thread
From: Patrick Lauer (patrick) @ 2014-07-30  8:26 UTC (permalink / raw
  To: gentoo-commits

patrick     14/07/30 08:26:27

  Modified:             ChangeLog
  Added:                backuppc-3.3.0.ebuild
  Log:
  Bump, ebuild modifications and patches thanks to Lenno Nagel. Fixes #468360
  
  (Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.20                 app-backup/backuppc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	29 Jul 2014 16:29:15 -0000	1.19
+++ ChangeLog	30 Jul 2014 08:26:27 -0000	1.20
@@ -1,6 +1,14 @@
 # ChangeLog for app-backup/backuppc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.19 2014/07/29 16:29:15 zlogene Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.20 2014/07/30 08:26:27 patrick Exp $
+
+*backuppc-3.3.0 (30 Jul 2014)
+
+  30 Jul 2014; Patrick Lauer <patrick@gentoo.org> +backuppc-3.3.0.ebuild,
+  +files/3.3.0/01-fix-configure.pl.patch,
+  +files/3.3.0/02-fix-config.pl-formatting.patch,
+  +files/3.3.0/03-reasonable-config.pl-defaults.patch:
+  Bump, ebuild modifications and patches thanks to Lenno Nagel. Fixes #468360
 
   29 Jul 2014; Mikle Kolyada <zlogene@gentoo.org> backuppc-3.2.1-r2.ebuild,
   backuppc-3.2.1-r3.ebuild:



1.1                  app-backup/backuppc/backuppc-3.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.1&content-type=text/plain

Index: backuppc-3.3.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v 1.1 2014/07/30 08:26:27 patrick Exp $

EAPI="5"

inherit eutils webapp user

MY_P="BackupPC-${PV}"

DESCRIPTION="A high-performance system for backing up computers to a server's disk."
HOMEPAGE="http://backuppc.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"

IUSE="rss samba"

DEPEND="dev-lang/perl
	app-admin/apache-tools
	app-admin/makepasswd"
RDEPEND="${DEPEND}
	perl-core/IO-Compress
	dev-perl/Archive-Zip
	dev-perl/libwww-perl
	>=app-arch/tar-1.13.20
	app-arch/par2cmdline
	app-arch/gzip
	app-arch/bzip2
	virtual/mta
	www-apache/mod_perl
	www-servers/apache
	net-misc/rsync
	>=dev-perl/File-RsyncP-0.68
	rss? ( dev-perl/XML-RSS )
	samba? ( net-fs/samba )"

WEBAPP_MANUAL_SLOT="yes"
SLOT="0"

S=${WORKDIR}/${MY_P}

CONFDIR="/etc/BackupPC"
DATADIR="/var/lib/backuppc"
LOGDIR="/var/log/BackupPC"

pkg_setup() {
	webapp_pkg_setup
	enewgroup backuppc
	enewuser backuppc -1 /bin/bash /var/lib/backuppc backuppc
}

src_prepare() {
	epatch "${FILESDIR}/3.3.0/01-fix-configure.pl.patch"
	epatch "${FILESDIR}/3.3.0/02-fix-config.pl-formatting.patch"
	epatch "${FILESDIR}/3.3.0/03-reasonable-config.pl-defaults.patch"

	# Fix the documentation location in the CGI interface
	epatch "${FILESDIR}/3.2.0/04-add-docdir-marker.patch"
	sed -i "s+__DOCDIR__+/usr/share/doc/${PF}+" "lib/BackupPC/CGI/View.pm"

	epatch "${FILESDIR}/3.2.0/05-nicelevel.patch"
	sed -i -e 's/--chuid ${USER}//' "${S}"/init.d/src/gentoo-backuppc || die "Failed to fix the init script"
}

src_test() {
	true
}

src_install() {
	webapp_src_preinst

	local myconf
	myconf=""
	if use samba ; then
		myconf="--bin-path smbclient=$(type -p smbclient)"
		myconf="${myconf} --bin-path nmblookup=$(type -p nmblookup)"
	fi

	/usr/bin/env perl ./configure.pl \
		--batch \
		--bin-path perl=$(type -p perl) \
		--bin-path tar=$(type -p tar) \
		--bin-path rsync=$(type -p rsync) \
		--bin-path ping=$(type -p ping) \
		--bin-path df=$(type -p df) \
		--bin-path ssh=$(type -p ssh) \
		--bin-path sendmail=$(type -p sendmail) \
		--bin-path hostname=$(type -p hostname) \
		--bin-path gzip=$(type -p gzip) \
		--bin-path bzip2=$(type -p bzip2) \
		--config-dir ${CONFDIR} \
		--install-dir /usr \
		--data-dir ${DATADIR} \
		--hostname $(hostname) \
		--uid-ignore \
		--dest-dir "${D%/}" \
		--html-dir ${MY_HTDOCSDIR}/image \
		--html-dir-url /image \
		--cgi-dir ${MY_HTDOCSDIR} \
		--fhs \
		${myconf} || die "failed the configure.pl script"

	ebegin "Installing documentation"

	pod2man \
		-errors=none \
		--section=8 \
		--center="BackupPC manual" \
		"${S}"/doc/BackupPC.pod backuppc.8 || die "failed to generate man page"

	doman backuppc.8

	# Place the documentation in the correct location
	dodoc "${D}/usr/doc/BackupPC.html"
	dodoc "${D}/usr/doc/BackupPC.pod"
	rm -rf "${D}/usr/doc"

	eend 0

	# Setup directories
	dodir ${CONFDIR}/pc

	keepdir ${CONFDIR}
	keepdir ${CONFDIR}/pc
	keepdir ${DATADIR}/{trash,pool,pc,cpool}
	keepdir ${LOGDIR}

	ebegin "Setting up init.d/conf.d scripts"
	newinitd "${S}"/init.d/gentoo-backuppc backuppc
	newconfd "${S}"/init.d/gentoo-backuppc.conf backuppc
	eend 0

	ebegin "Setting up an apache instance for backuppc"

	cp "${FILESDIR}/apache2-backuppc."{conf,init} "${WORKDIR}/"
	cp "${FILESDIR}/httpd.conf" "${WORKDIR}/httpd.conf"
	sed -i -e "s+HTDOCSDIR+${MY_HTDOCSDIR}+g" "${WORKDIR}/httpd.conf"
	sed -i -e "s+AUTHFILE+${CONFDIR}/users.htpasswd+g" "${WORKDIR}/httpd.conf"

	moduledir="/usr/lib/apache2/modules"

	# Check if the Apache ServerRoot is real.
	# This is sometimes broken on older amd64 systems.
	# In this case we just patch our config file appropriately.
	if [[ ! -d "/usr/lib/apache2" ]]; then
		if [[ -d "/usr/lib64/apache2" ]]; then
			sed -i -e "s+/usr/lib/apache2+/usr/lib64/apache2+g" "${WORKDIR}/httpd.conf"
			sed -i -e "s+/usr/lib/apache2+/usr/lib64/apache2+g" "${WORKDIR}/apache2-backuppc.conf"
			moduledir="/usr/lib64/apache2/modules"
		fi
	fi

	# Check if we're using mod_cgid instead of mod_cgi
	# This happens if you install apache with USE="threads"
	if [[ -f "${moduledir}/mod_cgid.so" ]]; then
		sed -i -e "s+mod_cgi+mod_cgid+g" "${WORKDIR}/httpd.conf"
		sed -i -e "s+cgi_module+cgid_module+g" "${WORKDIR}/httpd.conf"
	fi

	# Install conf.d/init.d files for apache2-backuppc
	if [ -e /etc/init.d/apache2 ]; then
		newconfd "${WORKDIR}/apache2-backuppc.conf" apache2-backuppc
		newinitd /etc/init.d/apache2 apache2-backuppc
	else
		newconfd "${WORKDIR}/apache2-backuppc.conf" apache2-backuppc
		newinitd "${WORKDIR}/apache2-backuppc.init" apache2-backuppc
	fi

	insopts -m 0644
	insinto ${CONFDIR}
	doins "${WORKDIR}/httpd.conf"

	eend $?

	webapp_src_install || die "webapp_src_install"

	# Make sure that the ownership is correct
	chown -R backuppc:backuppc "${D}${CONFDIR}"
	chown -R backuppc:backuppc "${D}${DATADIR}"
	chown -R backuppc:backuppc "${D}${LOGDIR}"
}

pkg_postinst() {
	# This is disabled since BackupPC doesn't need it
	# webapp_pkg_postinst

	elog "Installation finished, now may now start using BackupPC."
	elog ""
	elog "- Read the documentation in /usr/share/doc/${PF}/BackupPC.html"
	elog "  Please pay special attention to the security section."
	elog ""
	elog "- You can launch backuppc and it's apache web interface by running:"
	elog "  # /etc/init.d/backuppc start"
	elog "  # /etc/init.d/apache2-backuppc start"

	if [[ ! -e /etc/runlevels/default/backuppc ]]; then
		elog ""
		elog "- You also might want to add these scripts to your default runlevel:"
		elog "  # rc-update add backuppc default"
		elog "  # rc-update add apache2-backuppc default"
	fi

	# Generate a new password if there's no auth file
	if [[ ! -f "${CONFDIR}/users.htpasswd" ]]; then
		adminuser="backuppc"
		adminpass=$( makepasswd --chars=12 )
		htpasswd -bc "${CONFDIR}/users.htpasswd" $adminuser $adminpass

		elog ""
		elog "- Created admin user $adminuser with password $adminpass"
		elog "  To add new users, run: "
		elog "  # htpasswd ${CONFDIR}/users.htpasswd newUser"
	fi

	if [[ -d "/etc/backuppc" ]]; then
		ewarn ""
		ewarn "Detected old config directory in /etc/backuppc"
		ewarn "Please migrate relevant config files to ${CONFDIR} before starting backuppc"
	fi
}





^ permalink raw reply	[flat|nested] 4+ messages in thread

* [gentoo-commits] gentoo-x86 commit in app-backup/backuppc: backuppc-3.3.0.ebuild ChangeLog
@ 2014-07-30  9:50 Mikle Kolyada (zlogene)
  0 siblings, 0 replies; 4+ messages in thread
From: Mikle Kolyada (zlogene) @ 2014-07-30  9:50 UTC (permalink / raw
  To: gentoo-commits

zlogene     14/07/30 09:50:43

  Modified:             backuppc-3.3.0.ebuild ChangeLog
  Log:
  perl-core/x -> virtual/perl-x
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xC42EB5D6)

Revision  Changes    Path
1.2                  app-backup/backuppc/backuppc-3.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?r1=1.1&r2=1.2

Index: backuppc-3.3.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- backuppc-3.3.0.ebuild	30 Jul 2014 08:26:27 -0000	1.1
+++ backuppc-3.3.0.ebuild	30 Jul 2014 09:50:43 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v 1.1 2014/07/30 08:26:27 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v 1.2 2014/07/30 09:50:43 zlogene Exp $
 
 EAPI="5"
 
@@ -21,7 +21,7 @@
 	app-admin/apache-tools
 	app-admin/makepasswd"
 RDEPEND="${DEPEND}
-	perl-core/IO-Compress
+	virtual/perl-IO-Compress
 	dev-perl/Archive-Zip
 	dev-perl/libwww-perl
 	>=app-arch/tar-1.13.20



1.21                 app-backup/backuppc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	30 Jul 2014 08:26:27 -0000	1.20
+++ ChangeLog	30 Jul 2014 09:50:43 -0000	1.21
@@ -1,6 +1,9 @@
 # ChangeLog for app-backup/backuppc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.20 2014/07/30 08:26:27 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.21 2014/07/30 09:50:43 zlogene Exp $
+
+  30 Jul 2014; Mikle Kolyada <zlogene@gentoo.org> backuppc-3.3.0.ebuild:
+  perl-core/x -> virtual/perl-x
 
 *backuppc-3.3.0 (30 Jul 2014)
 





^ permalink raw reply	[flat|nested] 4+ messages in thread

* [gentoo-commits] gentoo-x86 commit in app-backup/backuppc: backuppc-3.3.0.ebuild ChangeLog
@ 2014-09-16 14:57 Agostino Sarubbo (ago)
  0 siblings, 0 replies; 4+ messages in thread
From: Agostino Sarubbo (ago) @ 2014-09-16 14:57 UTC (permalink / raw
  To: gentoo-commits

ago         14/09/16 14:57:06

  Modified:             backuppc-3.3.0.ebuild ChangeLog
  Log:
  Stable for amd64, wrt bug #519474
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, RepoMan options: --include-arches="amd64", signed Manifest commit with key 7194459F)

Revision  Changes    Path
1.4                  app-backup/backuppc/backuppc-3.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?r1=1.3&r2=1.4

Index: backuppc-3.3.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- backuppc-3.3.0.ebuild	10 Aug 2014 01:54:00 -0000	1.3
+++ backuppc-3.3.0.ebuild	16 Sep 2014 14:57:06 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v 1.3 2014/08/10 01:54:00 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v 1.4 2014/09/16 14:57:06 ago Exp $
 
 EAPI="5"
 
@@ -13,7 +13,7 @@
 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
 
 LICENSE="GPL-2"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
 
 IUSE="rss samba"
 



1.23                 app-backup/backuppc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	10 Aug 2014 01:54:00 -0000	1.22
+++ ChangeLog	16 Sep 2014 14:57:06 -0000	1.23
@@ -1,6 +1,9 @@
 # ChangeLog for app-backup/backuppc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.22 2014/08/10 01:54:00 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.23 2014/09/16 14:57:06 ago Exp $
+
+  16 Sep 2014; Agostino Sarubbo <ago@gentoo.org> backuppc-3.3.0.ebuild:
+  Stable for amd64, wrt bug #519474
 
   10 Aug 2014; Patrick Lauer <patrick@gentoo.org> backuppc-2.1.2-r1.ebuild,
   backuppc-3.2.1-r2.ebuild, backuppc-3.2.1-r3.ebuild, backuppc-3.3.0.ebuild:





^ permalink raw reply	[flat|nested] 4+ messages in thread

* [gentoo-commits] gentoo-x86 commit in app-backup/backuppc: backuppc-3.3.0.ebuild ChangeLog
@ 2014-09-16 14:57 Agostino Sarubbo (ago)
  0 siblings, 0 replies; 4+ messages in thread
From: Agostino Sarubbo (ago) @ 2014-09-16 14:57 UTC (permalink / raw
  To: gentoo-commits

ago         14/09/16 14:57:32

  Modified:             backuppc-3.3.0.ebuild ChangeLog
  Log:
  Stable for x86, wrt bug #519474
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, RepoMan options: --include-arches="x86", signed Manifest commit with key 7194459F)

Revision  Changes    Path
1.5                  app-backup/backuppc/backuppc-3.3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild?r1=1.4&r2=1.5

Index: backuppc-3.3.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- backuppc-3.3.0.ebuild	16 Sep 2014 14:57:06 -0000	1.4
+++ backuppc-3.3.0.ebuild	16 Sep 2014 14:57:32 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v 1.4 2014/09/16 14:57:06 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/backuppc-3.3.0.ebuild,v 1.5 2014/09/16 14:57:32 ago Exp $
 
 EAPI="5"
 
@@ -13,7 +13,7 @@
 SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
 
 LICENSE="GPL-2"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
 
 IUSE="rss samba"
 



1.24                 app-backup/backuppc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backuppc/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	16 Sep 2014 14:57:06 -0000	1.23
+++ ChangeLog	16 Sep 2014 14:57:32 -0000	1.24
@@ -1,6 +1,9 @@
 # ChangeLog for app-backup/backuppc
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.23 2014/09/16 14:57:06 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backuppc/ChangeLog,v 1.24 2014/09/16 14:57:32 ago Exp $
+
+  16 Sep 2014; Agostino Sarubbo <ago@gentoo.org> backuppc-3.3.0.ebuild:
+  Stable for x86, wrt bug #519474
 
   16 Sep 2014; Agostino Sarubbo <ago@gentoo.org> backuppc-3.3.0.ebuild:
   Stable for amd64, wrt bug #519474





^ permalink raw reply	[flat|nested] 4+ messages in thread

end of thread, other threads:[~2014-09-16 14:57 UTC | newest]

Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-09-16 14:57 [gentoo-commits] gentoo-x86 commit in app-backup/backuppc: backuppc-3.3.0.ebuild ChangeLog Agostino Sarubbo (ago)
  -- strict thread matches above, loose matches on Subject: below --
2014-09-16 14:57 Agostino Sarubbo (ago)
2014-07-30  9:50 Mikle Kolyada (zlogene)
2014-07-30  8:26 Patrick Lauer (patrick)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox