* [gentoo-commits] gentoo-x86 commit in dev-qt/qtgui: qtgui-5.3.2.ebuild ChangeLog qtgui-5.3.1-r3.ebuild
@ 2014-09-16 14:45 Davide Pesavento (pesa)
0 siblings, 0 replies; only message in thread
From: Davide Pesavento (pesa) @ 2014-09-16 14:45 UTC (permalink / raw
To: gentoo-commits
pesa 14/09/16 14:45:37
Modified: ChangeLog
Added: qtgui-5.3.2.ebuild
Removed: qtgui-5.3.1-r3.ebuild
Log:
Version bump.
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)
Revision Changes Path
1.45 dev-qt/qtgui/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtgui/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtgui/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtgui/ChangeLog?r1=1.44&r2=1.45
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-qt/qtgui/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog 11 Sep 2014 01:44:59 -0000 1.44
+++ ChangeLog 16 Sep 2014 14:45:37 -0000 1.45
@@ -1,6 +1,12 @@
# ChangeLog for dev-qt/qtgui
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtgui/ChangeLog,v 1.44 2014/09/11 01:44:59 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtgui/ChangeLog,v 1.45 2014/09/16 14:45:37 pesa Exp $
+
+*qtgui-5.3.2 (16 Sep 2014)
+
+ 16 Sep 2014; Davide Pesavento <pesa@gentoo.org> +qtgui-5.3.2.ebuild,
+ -qtgui-5.3.1-r3.ebuild:
+ Version bump.
*qtgui-5.3.1-r3 (11 Sep 2014)
1.1 dev-qt/qtgui/qtgui-5.3.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtgui/qtgui-5.3.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtgui/qtgui-5.3.2.ebuild?rev=1.1&content-type=text/plain
Index: qtgui-5.3.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtgui/qtgui-5.3.2.ebuild,v 1.1 2014/09/16 14:45:37 pesa Exp $
EAPI=5
QT5_MODULE="qtbase"
inherit qt5-build
DESCRIPTION="The GUI module and platform plugins for the Qt5 framework"
if [[ ${QT5_BUILD_TYPE} == live ]]; then
KEYWORDS=""
else
KEYWORDS="~amd64 ~x86"
fi
# TODO: directfb, linuxfb, offscreen (auto-depends on X11)
IUSE="accessibility egl eglfs evdev +gif gles2 harfbuzz ibus jpeg kms +opengl +png udev +xcb"
REQUIRED_USE="
egl? ( evdev opengl )
eglfs? ( egl )
gles2? ( opengl )
kms? ( egl gles2 )
"
RDEPEND="
dev-libs/glib:2
~dev-qt/qtcore-${PV}[debug=]
media-libs/fontconfig
media-libs/freetype:2
sys-libs/zlib
egl? ( media-libs/mesa[egl] )
evdev? ( sys-libs/mtdev )
gles2? ( media-libs/mesa[gles2] )
harfbuzz? ( >=media-libs/harfbuzz-0.9.25:= )
ibus? ( ~dev-qt/qtdbus-${PV}[debug=] )
jpeg? ( virtual/jpeg:0 )
kms? (
media-libs/mesa[gbm]
virtual/libudev:=
x11-libs/libdrm
)
opengl? ( virtual/opengl )
png? ( media-libs/libpng:0= )
udev? ( virtual/libudev:= )
xcb? (
x11-libs/libICE
x11-libs/libSM
>=x11-libs/libX11-1.5
>=x11-libs/libXi-1.6
x11-libs/libXrender
>=x11-libs/libxcb-1.10[xkb]
>=x11-libs/libxkbcommon-0.4.1[X]
x11-libs/xcb-util-image
x11-libs/xcb-util-keysyms
x11-libs/xcb-util-renderutil
x11-libs/xcb-util-wm
accessibility? ( ~dev-qt/qtdbus-${PV}[debug=] )
)
"
DEPEND="${RDEPEND}
evdev? ( sys-kernel/linux-headers )
test? ( ~dev-qt/qtnetwork-${PV}[debug=] )
"
PDEPEND="
ibus? ( app-i18n/ibus )
"
QT5_TARGET_SUBDIRS=(
src/gui
src/platformsupport
src/plugins/generic
src/plugins/imageformats
src/plugins/platforms
)
QT5_GENTOO_CONFIG=(
accessibility:accessibility-atspi-bridge
egl
eglfs
evdev
evdev:mtdev:
:fontconfig
:system-freetype:FREETYPE
!:no-freetype:
!gif:no-gif:
gles2::OPENGL_ES
gles2:opengles2:OPENGL_ES_2
!:no-gui:
harfbuzz:system-harfbuzz:HARFBUZZ
!harfbuzz:no-harfbuzz:
jpeg:system-jpeg:IMAGEFORMAT_JPEG
!jpeg:no-jpeg:
kms:kms:
opengl
png:png:
png:system-png:IMAGEFORMAT_PNG
!png:no-png:
udev:libudev:
xcb:xcb:
xcb:xcb-glx:
xcb:xcb-plugin:
xcb:xcb-render:
xcb:xcb-sm:
xcb:xcb-xlib:
xcb:xinput2:
xcb::XKB
)
pkg_setup() {
use opengl && QT5_TARGET_SUBDIRS+=(src/openglextensions)
use ibus && QT5_TARGET_SUBDIRS+=(src/plugins/platforminputcontexts/ibus)
use xcb && QT5_TARGET_SUBDIRS+=(src/plugins/platforminputcontexts/compose)
# egl_x11 is activated when both egl and xcb are enabled
use egl && QT5_GENTOO_CONFIG+=(xcb:egl_x11) || QT5_GENTOO_CONFIG+=(egl:egl_x11)
}
src_configure() {
local gl="-no-opengl"
if use gles2; then
gl="-opengl es2"
elif use opengl; then
gl="-opengl desktop"
fi
local myconf=(
$(use accessibility && use xcb && echo -dbus-linked)
$(use ibus && echo -dbus-linked)
$(qt_use egl)
$(qt_use eglfs)
$(qt_use evdev)
$(qt_use evdev mtdev)
-fontconfig
-system-freetype
$(use gif || echo -no-gif)
${gl}
$(qt_use harfbuzz harfbuzz system)
$(qt_use jpeg libjpeg system)
$(qt_use kms)
$(qt_use png libpng system)
$(qt_use udev libudev)
$(qt_use xcb xcb system)
$(qt_use xcb xkbcommon system)
$(use xcb && echo -xcb-xlib -xinput2 -xkb -xrender)
)
qt5-build_src_configure
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-09-16 14:45 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-09-16 14:45 [gentoo-commits] gentoo-x86 commit in dev-qt/qtgui: qtgui-5.3.2.ebuild ChangeLog qtgui-5.3.1-r3.ebuild Davide Pesavento (pesa)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox