* [gentoo-commits] gentoo-x86 commit in net-firewall/ipt_netflow: ChangeLog ipt_netflow-2.0.1.ebuild
@ 2014-09-16 6:06 Jeroen Roovers (jer)
0 siblings, 0 replies; only message in thread
From: Jeroen Roovers (jer) @ 2014-09-16 6:06 UTC (permalink / raw
To: gentoo-commits
jer 14/09/16 06:06:52
Modified: ChangeLog
Added: ipt_netflow-2.0.1.ebuild
Log:
Version bump.
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A792A613)
Revision Changes Path
1.17 net-firewall/ipt_netflow/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ipt_netflow/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ipt_netflow/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ipt_netflow/ChangeLog?r1=1.16&r2=1.17
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/ipt_netflow/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog 19 Aug 2014 07:21:25 -0000 1.16
+++ ChangeLog 16 Sep 2014 06:06:52 -0000 1.17
@@ -1,6 +1,12 @@
# ChangeLog for net-firewall/ipt_netflow
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/ipt_netflow/ChangeLog,v 1.16 2014/08/19 07:21:25 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/ipt_netflow/ChangeLog,v 1.17 2014/09/16 06:06:52 jer Exp $
+
+*ipt_netflow-2.0.1 (16 Sep 2014)
+
+ 16 Sep 2014; Jeroen Roovers <jer@gentoo.org> +ipt_netflow-2.0.1.ebuild,
+ files/ipt_netflow-2.0-pax-const.patch:
+ Version bump.
*ipt_netflow-2.0-r1 (19 Aug 2014)
1.1 net-firewall/ipt_netflow/ipt_netflow-2.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ipt_netflow/ipt_netflow-2.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/ipt_netflow/ipt_netflow-2.0.1.ebuild?rev=1.1&content-type=text/plain
Index: ipt_netflow-2.0.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/ipt_netflow/ipt_netflow-2.0.1.ebuild,v 1.1 2014/09/16 06:06:52 jer Exp $
EAPI=5
inherit eutils linux-info linux-mod multilib toolchain-funcs
DESCRIPTION="Netflow iptables module"
HOMEPAGE="http://sourceforge.net/projects/ipt-netflow"
SRC_URI="mirror://sourceforge/ipt-netflow/${P}.tgz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug pax_kernel"
RDEPEND="net-firewall/iptables"
DEPEND="${RDEPEND}
virtual/linux-sources
virtual/pkgconfig
"
# set S before MODULE_NAMES
S="${WORKDIR}/${PN/_/-}-${PV}"
BUILD_TARGETS="all"
MODULE_NAMES="ipt_NETFLOW(ipt_netflow:${S})"
IPT_LIB="/usr/$(get_libdir)/xtables"
pkg_setup() {
local CONFIG_CHECK="~IP_NF_IPTABLES"
use debug && CONFIG_CHECK+=" ~DEBUG_FS"
linux-mod_pkg_setup
}
src_prepare() {
sed -i \
-e 's:make -C:$(MAKE) -C:g' \
-e 's:gcc -O2:$(CC) $(CFLAGS) $(LDFLAGS):' \
-e 's:gcc:$(CC) $(CFLAGS) $(LDFLAGS):' \
Makefile.in || die
# bug #455984
epatch "${FILESDIR}/${PN}-2.0-configure.patch"
# bugs #466430 and #519480
if use pax_kernel; then
epatch "${FILESDIR}/${PN}-2.0-pax-const.patch"
fi
epatch_user
}
do_conf() {
echo ./configure $*
./configure $* || die 'configure failed'
}
src_configure() {
local IPT_VERSION="$($(tc-getPKG_CONFIG) --modversion xtables)"
# this configure script is not based on autotools
# ipt-src need to be defined, see bug #455984
do_conf \
--ipt-lib="${IPT_LIB}" \
--ipt-src="/usr/" \
--ipt-ver="${IPT_VERSION}" \
--kdir="${KV_DIR}" \
--kver="${KV_FULL}" \
$(use debug && echo '--enable-debugfs')
}
src_compile() {
emake ARCH="$(tc-arch-kernel)" CC="$(tc-getCC)" all
}
src_install() {
linux-mod_src_install
exeinto "${IPT_LIB}"
doexe libipt_NETFLOW.so
doheader ipt_NETFLOW.h
dodoc README*
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-09-16 6:06 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-09-16 6:06 [gentoo-commits] gentoo-x86 commit in net-firewall/ipt_netflow: ChangeLog ipt_netflow-2.0.1.ebuild Jeroen Roovers (jer)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox