* [gentoo-commits] gentoo-x86 commit in app-office/scribus: ChangeLog scribus-1.4.4-r1.ebuild scribus-1.4.4.ebuild
@ 2014-08-21 8:02 Justin Lecher (jlec)
0 siblings, 0 replies; only message in thread
From: Justin Lecher (jlec) @ 2014-08-21 8:02 UTC (permalink / raw
To: gentoo-commits
jlec 14/08/21 08:02:11
Modified: ChangeLog
Added: scribus-1.4.4-r1.ebuild
Removed: scribus-1.4.4.ebuild
Log:
app-office/scribus: Fix empty info tabs, #520114
(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)
Revision Changes Path
1.194 app-office/scribus/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/ChangeLog?rev=1.194&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/ChangeLog?rev=1.194&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/ChangeLog?r1=1.193&r2=1.194
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/scribus/ChangeLog,v
retrieving revision 1.193
retrieving revision 1.194
diff -u -r1.193 -r1.194
--- ChangeLog 15 Aug 2014 18:38:05 -0000 1.193
+++ ChangeLog 21 Aug 2014 08:02:11 -0000 1.194
@@ -1,6 +1,12 @@
# ChangeLog for app-office/scribus
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/scribus/ChangeLog,v 1.193 2014/08/15 18:38:05 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/scribus/ChangeLog,v 1.194 2014/08/21 08:02:11 jlec Exp $
+
+*scribus-1.4.4-r1 (21 Aug 2014)
+
+ 21 Aug 2014; Justin Lecher <jlec@gentoo.org> -scribus-1.4.4.ebuild,
+ +scribus-1.4.4-r1.ebuild:
+ Fix empty info tabs, #520114
15 Aug 2014; Jeroen Roovers <jer@gentoo.org> scribus-1.4.4.ebuild:
Stable for HPPA (bug #519890).
1.1 app-office/scribus/scribus-1.4.4-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/scribus-1.4.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/scribus/scribus-1.4.4-r1.ebuild?rev=1.1&content-type=text/plain
Index: scribus-1.4.4-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/scribus/scribus-1.4.4-r1.ebuild,v 1.1 2014/08/21 08:02:11 jlec Exp $
EAPI=5
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="tk?"
inherit cmake-utils fdo-mime python-single-r1
DESCRIPTION="Desktop publishing (DTP) and layout program"
HOMEPAGE="http://www.scribus.net/"
SRC_URI="mirror://sourceforge/${PN}/${PV}/${P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="cairo debug examples hunspell +minimal +pdf scripts templates tk"
# a=$(ls resources/translations/po/scribus.*ts | sed -e 's:\.: :g' | awk '{print $2}'); echo ${a}
IUSE_LINGUAS=" af ar bg br ca cs_CZ cy da_DK de de_1901 de_CH el en_AU en_GB en_US es_ES et eu fi fr gl hu id it ja ko lt_LT nb_NO nl pl_PL pt pt_BR ru sa sk_SK sl sq sr sv th_TH tr uk zh_CN zh_TW"
IUSE+=" ${IUSE_LINGUAS// / linguas_}"
REQUIRED_USE="
${PYTHON_REQUIRED_USE}
tk? ( scripts )"
COMMON_DEPEND="
${PYTHON_DEPS}
dev-libs/boost
dev-libs/hyphen
dev-libs/libxml2
dev-qt/qtcore:4
dev-qt/qtgui:4
media-libs/fontconfig
media-libs/freetype:2
media-libs/lcms:2
media-libs/libpng:0
media-libs/tiff:0
net-print/cups
sys-libs/zlib[minizip]
virtual/jpeg
cairo? ( x11-libs/cairo[X,svg] )
!cairo? ( media-libs/libart_lgpl )
hunspell? ( app-text/hunspell )
pdf? ( app-text/podofo )
scripts? ( virtual/python-imaging[tk?,${PYTHON_USEDEP}] )
tk? ( virtual/python-imaging[tk?,${PYTHON_USEDEP}] )
"
RDEPEND="${COMMON_DEPEND}
app-text/ghostscript-gpl"
DEPEND="${COMMON_DEPEND}
virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-1.4.2-docs.patch
"${FILESDIR}"/${PN}-1.4.0-minizip.patch
)
src_prepare() {
cat > cmake/modules/FindZLIB.cmake <<- EOF
find_package(PkgConfig)
pkg_check_modules(ZLIB minizip zlib)
SET( ZLIB_LIBRARY \${ZLIB_LIBRARIES} )
SET( ZLIB_INCLUDE_DIR \${ZLIB_INCLUDE_DIRS} )
MARK_AS_ADVANCED( ZLIB_LIBRARY ZLIB_INCLUDE_DIR )
EOF
rm scribus/{ioapi,unzip}.[ch] || die
sed \
-e 's:\(${CMAKE_INSTALL_PREFIX}\):./\1:g' \
-i resources/templates/CMakeLists.txt || die
cmake-utils_src_prepare
}
src_configure() {
local lang langs
for lang in ${IUSE_LINGUAS}; do
if use linguas_${lang}; then
langs+=",${lang}"
else
sed -e "/${lang}/d" -i scribus/doc/CMakeLists.txt || die
fi
done
local mycmakeargs=(
-DHAVE_PYTHON=ON
-DPYTHON_INCLUDE_PATH="$(python_get_includedir)"
-DPYTHON_LIBRARY="$(python_get_library_path)"
-DWANT_NORPATH=ON
-DWANT_QT3SUPPORT=OFF
-DGENTOOVERSION=${PVR}
-DWANT_GUI_LANG=${langs#,}
$(cmake-utils_use_with pdf PODOFO)
$(cmake-utils_use_want cairo)
$(cmake-utils_use_want !cairo QTARTHUR)
$(cmake-utils_use_want debug DEBUG)
$(cmake-utils_use_want minimal NOHEADERINSTALL)
$(cmake-utils_use_want hunspell HUNSPELL)
$(cmake-utils_use_want !examples NOEXAMPLES)
$(cmake-utils_use_want !templates NOTEMPLATES)
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
local lang file
for lang in ${IUSE_LINGUAS}; do
file="${ED}"/usr/share/scribus/translations/scribus.${lang}.qm
if ! use linguas_${lang} && [[ -f "${file}" ]]; then
rm "${file}" || die
fi
done
if ! use scripts; then
rm "${ED}"/usr/share/scribus/scripts/*.py || die
elif ! use tk; then
rm "${ED}"/usr/share/scribus/scripts/{FontSample,CalendarWizard}.py || die
fi
python_fix_shebang "${ED}"/usr/share/scribus/scripts
python_optimize "${ED}"/usr/share/scribus/scripts
mv "${ED}"/usr/share/doc/${PF}/{en,html} || die
ln -sf html "${ED}"/usr/share/doc/${PF}/en || die
cat >> "${T}"/COPYING <<- EOF
${PN} is licensed under the "${LICENSE}".
Please visit http://www.gnu.org/licenses/gpl-2.0.html for the complete license text.
EOF
dodoc "${T}"/COPYING
docompress -x /usr/share/doc/${PF}/en /usr/share/doc/${PF}/{AUTHORS,TRANSLATION,LINKS,COPYING}
doicon resources/icons/scribus.png
domenu scribus.desktop
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
}
pkg_postrm() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-08-21 8:02 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-08-21 8:02 [gentoo-commits] gentoo-x86 commit in app-office/scribus: ChangeLog scribus-1.4.4-r1.ebuild scribus-1.4.4.ebuild Justin Lecher (jlec)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox