[gentoo-commits] gentoo-x86 commit in sys-fs/reiser4progs: reiser4progs-1.0.9.ebuild ChangeLog

["Samuli Suominen (ssuominen)" <ssuominen@gentoo.org>]

ssuominen    14/07/31 05:21:16

  Modified:             ChangeLog
  Added:                reiser4progs-1.0.9.ebuild
  Log:
  Version bump wrt #518594 by Yevgeny Filatov
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.45                 sys-fs/reiser4progs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/reiser4progs/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/reiser4progs/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/reiser4progs/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/reiser4progs/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	13 Mar 2014 22:38:34 -0000	1.44
+++ ChangeLog	31 Jul 2014 05:21:16 -0000	1.45
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/reiser4progs
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/reiser4progs/ChangeLog,v 1.44 2014/03/13 22:38:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/reiser4progs/ChangeLog,v 1.45 2014/07/31 05:21:16 ssuominen Exp $
+
+*reiser4progs-1.0.9 (31 Jul 2014)
+
+  31 Jul 2014; Samuli Suominen <ssuominen@gentoo.org>
+  +reiser4progs-1.0.9.ebuild:
+  Version bump wrt #518594 by Yevgeny Filatov
 
 *reiser4progs-1.0.8 (13 Mar 2014)
 



1.1                  sys-fs/reiser4progs/reiser4progs-1.0.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/reiser4progs/reiser4progs-1.0.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/reiser4progs/reiser4progs-1.0.9.ebuild?rev=1.1&content-type=text/plain

Index: reiser4progs-1.0.9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/reiser4progs/reiser4progs-1.0.9.ebuild,v 1.1 2014/07/31 05:21:16 ssuominen Exp $

EAPI="4"

inherit multilib eutils toolchain-funcs

DESCRIPTION="reiser4progs: mkfs, fsck, etc..."
HOMEPAGE="https://sourceforge.net/projects/reiser4/"
SRC_URI="mirror://sourceforge/reiser4/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 -sparc ~x86"
IUSE="debug readline static static-libs"

LIB_DEPEND="~sys-libs/libaal-1.0.6[static-libs(+)]
	readline? ( sys-libs/readline[static-libs(+)] )"
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
	static-libs? ( ~sys-libs/libaal-1.0.6[static-libs(+)] )"
DEPEND="${RDEPEND}
	static? ( ${LIB_DEPEND} )"

src_prepare() {
	printf '#!/bin/sh\ntrue\n' > run-ldconfig
	# Delete hardcoded link/compile flags.
	sed -i -r \
		-e '/CFLAGS=/s: -static":":' \
		-e '/CFLAGS/s: (-O[123s]|-g)\>::g' \
		configure || die
	epatch "${FILESDIR}"/${PN}-1.0.7-readline-6.3.patch #504472
}

src_configure() {
	econf \
		$(use_enable static full-static) \
		$(use_enable static-libs static) \
		$(use_enable debug) \
		$(use_with readline) \
		--disable-Werror \
		--enable-libminimal \
		--sbindir=/sbin
}

src_install() {
	default
	gen_usr_ldscript -a reiser4{,-minimal} repair
}