* [gentoo-commits] gentoo-x86 commit in dev-python/sqlalchemy: sqlalchemy-0.9.7.ebuild ChangeLog sqlalchemy-0.7.8.ebuild sqlalchemy-0.7.4.ebuild sqlalchemy-0.7.6.ebuild sqlalchemy-0.7.7.ebuild sqlalchemy-0.7.5.ebuild
@ 2014-07-29 7:03 Ian Delaney (idella4)
0 siblings, 0 replies; only message in thread
From: Ian Delaney (idella4) @ 2014-07-29 7:03 UTC (permalink / raw
To: gentoo-commits
idella4 14/07/29 07:03:28
Modified: ChangeLog
Added: sqlalchemy-0.9.7.ebuild
Removed: sqlalchemy-0.7.8.ebuild sqlalchemy-0.7.4.ebuild
sqlalchemy-0.7.6.ebuild sqlalchemy-0.7.7.ebuild
sqlalchemy-0.7.5.ebuild
Log:
bump; clean old python impls, rm some old
(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)
Revision Changes Path
1.129 dev-python/sqlalchemy/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/ChangeLog?rev=1.129&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/ChangeLog?rev=1.129&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/ChangeLog?r1=1.128&r2=1.129
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v
retrieving revision 1.128
retrieving revision 1.129
diff -u -r1.128 -r1.129
--- ChangeLog 18 Jul 2014 15:08:41 -0000 1.128
+++ ChangeLog 29 Jul 2014 07:03:28 -0000 1.129
@@ -1,6 +1,13 @@
# ChangeLog for dev-python/sqlalchemy
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.128 2014/07/18 15:08:41 klausman Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/ChangeLog,v 1.129 2014/07/29 07:03:28 idella4 Exp $
+
+*sqlalchemy-0.9.7 (29 Jul 2014)
+
+ 29 Jul 2014; Ian Delaney <idella4@gentoo.org> +sqlalchemy-0.9.7.ebuild,
+ -sqlalchemy-0.7.4.ebuild, -sqlalchemy-0.7.5.ebuild, -sqlalchemy-0.7.6.ebuild,
+ -sqlalchemy-0.7.7.ebuild, -sqlalchemy-0.7.8.ebuild:
+ bump; clean old python impls, rm some old
18 Jul 2014; Tobias Klausmann <klausman@gentoo.org> sqlalchemy-0.9.2.ebuild:
Stable on alpha, bug #505840
1.1 dev-python/sqlalchemy/sqlalchemy-0.9.7.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.9.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.9.7.ebuild?rev=1.1&content-type=text/plain
Index: sqlalchemy-0.9.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlalchemy/sqlalchemy-0.9.7.ebuild,v 1.1 2014/07/29 07:03:28 idella4 Exp $
EAPI=5
PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} pypy )
PYTHON_REQ_USE="sqlite?"
inherit distutils-r1 eutils flag-o-matic
MY_PN="SQLAlchemy"
MY_P="${MY_PN}-${PV/_}"
DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
HOMEPAGE="http://www.sqlalchemy.org/ http://pypi.python.org/pypi/SQLAlchemy"
SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc examples +sqlite test"
REQUIRED_USE="test? ( sqlite )"
RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
sqlite? ( >=dev-db/sqlite-3.3.13 )"
DEPEND="${RDEPEND}
test? (
>=dev-db/sqlite-3.3.13
>=dev-python/nose-0.10.4[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
)"
S="${WORKDIR}/${MY_P}"
python_prepare_all() {
# Disable tests hardcoding function call counts specific to Python versions.
rm -r test/aaa_profiling || die
distutils-r1_python_prepare_all
}
python_compile() {
if ! python_is_python3; then
local CFLAGS=${CFLAGS}
append-cflags -fno-strict-aliasing
fi
distutils-r1_python_compile
}
python_test() {
# Create copies of necessary files in BUILD_DIR.
# https://bitbucket.org/zzzeek/sqlalchemy/issue/3144/
cp -pR examples sqla_nose.py setup.cfg test "${BUILD_DIR}" || die
pushd "${BUILD_DIR}" > /dev/null
if [[ "${EPYTHON}" == "python3.2" ]]; then
2to3 --no-diffs -w test
fi
"${PYTHON}" sqla_nose.py || die "Testsuite failed under ${EPYTHON}"
popd > /dev/null
}
python_install_all() {
use doc && HTML_DOCS=( doc/. )
use examples && local EXAMPLES=( examples/. )
distutils-r1_python_install_all
}
pkg_postinst() {
if [[ -z ${REPLACING_VERSIONS} ]]; then
if ! has_version dev-python/mysql-python; then
elog "For MySQL support, install dev-python/mysql-python"
fi
if ! has_version dev-python/pymssql; then
elog "For mssql support, install dev-python/pymssql"
fi
if ! has_version dev-python/psycopg:2; then
elog "For postgresql support, install dev-python/psycopg:2"
fi
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-07-29 7:03 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-07-29 7:03 [gentoo-commits] gentoo-x86 commit in dev-python/sqlalchemy: sqlalchemy-0.9.7.ebuild ChangeLog sqlalchemy-0.7.8.ebuild sqlalchemy-0.7.4.ebuild sqlalchemy-0.7.6.ebuild sqlalchemy-0.7.7.ebuild sqlalchemy-0.7.5.ebuild Ian Delaney (idella4)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox