[gentoo-commits] gentoo-x86 commit in x11-libs/libdrm: libdrm-2.4.54.ebuild ChangeLog libdrm-2.4.51.ebuild libdrm-2.4.45.ebuild libdrm-2.4.50.ebuild libdrm-2.4.49-r1.ebuild libdrm-2.4.42.ebuild libdrm-2.4.46-r1.ebuild libdrm-2.4.44.ebuild libdrm-2.4.49.ebuild libdrm-2.4.40.ebuild libdrm-2.4.47.ebuild libdrm-2.4.43.ebuild libdrm-2.4.48.ebuild

[gentoo-commits] gentoo-x86 commit in x11-libs/libdrm: libdrm-2.4.54.ebuild ChangeLog libdrm-2.4.51.ebuild libdrm-2.4.45.ebuild libdrm-2.4.50.ebuild libdrm-2.4.49-r1.ebuild libdrm-2.4.42.ebuild libdrm-2.4.46-r1.ebuild libdrm-2.4.44.ebuild libdrm-2.4.49.ebuild libdrm-2.4.40.ebuild libdrm-2.4.47.ebuild libdrm-2.4.43.ebuild libdrm-2.4.48.ebuild

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    14/05/14 16:17:13

  Modified:             ChangeLog
  Added:                libdrm-2.4.54.ebuild
  Removed:              libdrm-2.4.51.ebuild libdrm-2.4.45.ebuild
                        libdrm-2.4.50.ebuild libdrm-2.4.49-r1.ebuild
                        libdrm-2.4.42.ebuild libdrm-2.4.46-r1.ebuild
                        libdrm-2.4.44.ebuild libdrm-2.4.49.ebuild
                        libdrm-2.4.40.ebuild libdrm-2.4.47.ebuild
                        libdrm-2.4.43.ebuild libdrm-2.4.48.ebuild
  Log:
  Version bump. Drop some old versions.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.261                x11-libs/libdrm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.261&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.261&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?r1=1.260&r2=1.261

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v
retrieving revision 1.260
retrieving revision 1.261
diff -u -r1.260 -r1.261
--- ChangeLog	19 Apr 2014 17:47:36 -0000	1.260
+++ ChangeLog	14 May 2014 16:17:13 -0000	1.261
@@ -1,6 +1,17 @@
 # ChangeLog for x11-libs/libdrm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.260 2014/04/19 17:47:36 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.261 2014/05/14 16:17:13 chithanh Exp $
+
+*libdrm-2.4.54 (14 May 2014)
+
+  14 May 2014; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +libdrm-2.4.54.ebuild, -files/libdrm-2.4.40-bsd-etime.patch,
+  -files/libdrm-2.4.49-radeonsi-crash.patch, -libdrm-2.4.40.ebuild,
+  -libdrm-2.4.42.ebuild, -libdrm-2.4.43.ebuild, -libdrm-2.4.44.ebuild,
+  -libdrm-2.4.45.ebuild, -libdrm-2.4.46-r1.ebuild, -libdrm-2.4.47.ebuild,
+  -libdrm-2.4.48.ebuild, -libdrm-2.4.49-r1.ebuild, -libdrm-2.4.49.ebuild,
+  -libdrm-2.4.50.ebuild, -libdrm-2.4.51.ebuild:
+  Version bump. Drop some old versions.
 
   19 Apr 2014; Agostino Sarubbo <ago@gentoo.org> libdrm-2.4.52.ebuild:
   Stable for sparc, wrt bug #500368



1.1                  x11-libs/libdrm/libdrm-2.4.54.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.54.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.54.ebuild?rev=1.1&content-type=text/plain

Index: libdrm-2.4.54.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.54.ebuild,v 1.1 2014/05/14 16:17:13 chithanh Exp $

EAPI=5

XORG_MULTILIB=yes
inherit xorg-2

EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"

DESCRIPTION="X.Org libdrm library"
HOMEPAGE="http://dri.freedesktop.org/"
if [[ ${PV} = 9999* ]]; then
	SRC_URI=""
else
	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
fi

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
VIDEO_CARDS="exynos freedreno intel nouveau omap radeon vmware"
for card in ${VIDEO_CARDS}; do
	IUSE_VIDEO_CARDS+=" video_cards_${card}"
done

IUSE="${IUSE_VIDEO_CARDS} libkms"
REQUIRED_USE="video_cards_exynos? ( libkms )"
RESTRICT="test" # see bug #236845

RDEPEND="dev-libs/libpthread-stubs[${MULTILIB_USEDEP}]
	video_cards_intel? ( >=x11-libs/libpciaccess-0.10[${MULTILIB_USEDEP}] )
	abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}"/${PN}-2.4.28-solaris.patch
)

src_prepare() {
	if [[ ${PV} = 9999* ]]; then
		# tests are restricted, no point in building them
		sed -ie 's/tests //' "${S}"/Makefile.am
	fi
	xorg-2_src_prepare
}

src_configure() {
	XORG_CONFIGURE_OPTIONS=(
		--enable-udev
		$(use_enable video_cards_exynos exynos-experimental-api)
		$(use_enable video_cards_freedreno freedreno-experimental-api)
		$(use_enable video_cards_intel intel)
		$(use_enable video_cards_nouveau nouveau)
		$(use_enable video_cards_omap omap-experimental-api)
		$(use_enable video_cards_radeon radeon)
		$(use_enable video_cards_vmware vmwgfx)
		$(use_enable libkms)
	)
	xorg-2_src_configure
}