* [gentoo-commits] gentoo-x86 commit in dev-db/myodbc: myodbc-5.2.6.ebuild ChangeLog
@ 2014-05-04 19:37 Brian Evans (grknight)
0 siblings, 0 replies; only message in thread
From: Brian Evans (grknight) @ 2014-05-04 19:37 UTC (permalink / raw
To: gentoo-commits
grknight 14/05/04 19:37:13
Modified: ChangeLog
Added: myodbc-5.2.6.ebuild
Log:
Version bump to 5.2.6.
Fixes bugs #380141, #442322, #462432, #474088
(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)
Revision Changes Path
1.34 dev-db/myodbc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/myodbc/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/myodbc/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/myodbc/ChangeLog?r1=1.33&r2=1.34
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/myodbc/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog 10 May 2013 08:17:39 -0000 1.33
+++ ChangeLog 4 May 2014 19:37:13 -0000 1.34
@@ -1,6 +1,12 @@
# ChangeLog for dev-db/myodbc
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/myodbc/ChangeLog,v 1.33 2013/05/10 08:17:39 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/myodbc/ChangeLog,v 1.34 2014/05/04 19:37:13 grknight Exp $
+
+*myodbc-5.2.6 (04 May 2014)
+
+ 04 May 2014; <grknight@gentoo.org> +files/cmake-doc-path.patch,
+ +myodbc-5.2.6.ebuild:
+ Version bump to 5.2.6. Fixes bugs #380141, #442322, #462432, #474088
10 May 2013; Patrick Lauer <patrick@gentoo.org> myodbc-5.1.6.ebuild:
Fix src_prepare
1.1 dev-db/myodbc/myodbc-5.2.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/myodbc/myodbc-5.2.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/myodbc/myodbc-5.2.6.ebuild?rev=1.1&content-type=text/plain
Index: myodbc-5.2.6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/myodbc/myodbc-5.2.6.ebuild,v 1.1 2014/05/04 19:37:13 grknight Exp $
EAPI=5
inherit cmake-utils eutils flag-o-matic versionator
MAJOR="$(get_version_component_range 1-2 $PV)"
MY_PN="mysql-connector-odbc"
MY_P="${MY_PN}-${PV/_p/r}-src"
DESCRIPTION="ODBC driver for MySQL"
HOMEPAGE="http://www.mysql.com/products/myodbc/"
SRC_URI="mirror://mysql/Downloads/Connector-ODBC/${MAJOR}/${MY_P}.tar.gz"
RESTRICT="primaryuri"
LICENSE="GPL-2"
SLOT="${MAJOR}"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
RDEPEND="
dev-db/unixODBC
>=virtual/mysql-4.1
"
DEPEND="${DEPEND} ${RDEPEND}"
S=${WORKDIR}/${MY_P}
# Careful!
DRIVER_NAME="${PN}-${SLOT}"
src_prepare() {
# Remove Tests
sed -i -e "s/ADD_SUBDIRECTORY(test)//" \
"${S}/CMakeLists.txt"
# Fix as-needed on the installer binary
echo "TARGET_LINK_LIBRARIES(myodbc-installer odbc)" >> "${S}/installer/CMakeLists.txt"
# Patch document path so it doesn't install files to /usr
epatch "${FILESDIR}/cmake-doc-path.patch"
}
src_configure() {
# The RPM_BUILD flag does nothing except install to /usr/lib64 when "x86_64"
# MYSQL_CXX_LINKAGE expects "mysql_config --cxxflags" which doesn't exist on MariaDB
mycmakeargs+=(
-DMYSQL_CXX_LINKAGE=0
-DWITH_UNIXODBC=1
-DRPM_BUILD=1
-DMYSQL_LIB="$(mysql_config --variable=pkglibdir)/libmysqlclient_r.so"
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
dodir /usr/share/${PN}-${SLOT}
for i in odbc.ini odbcinst.ini; do
einfo "Building $i"
sed \
-e "s,__PN__,${DRIVER_NAME},g" \
-e "s,__PF__,${PF},g" \
-e "s,libmyodbc3.so,libmyodbc${SLOT:0:1}.so,g" \
>"${D}"/usr/share/${PN}-${SLOT}/${i} \
<"${FILESDIR}"/${i}.m4 \
|| die "Failed to build $i"
done;
}
pkg_config() {
[ "${ROOT}" != "/" ] && \
die 'Sorry, non-standard ROOT setting is not supported :-('
local msg='MySQL ODBC driver'
local drivers=$(/usr/bin/odbcinst -q -d)
if echo $drivers | grep -vq "^\[${DRIVER_NAME}\]$" ; then
ebegin "Installing ${msg}"
/usr/bin/odbcinst -i -d -f /usr/share/${PN}-${SLOT}/odbcinst.ini
rc=$?
eend $rc
[ $rc -ne 0 ] && die
else
einfo "Skipping already installed ${msg}"
fi
local sources=$(/usr/bin/odbcinst -q -s)
msg='sample MySQL ODBC DSN'
if echo $sources | grep -vq "^\[${DRIVER_NAME}-test\]$"; then
ebegin "Installing ${msg}"
/usr/bin/odbcinst -i -s -l -f /usr/share/${PN}-${SLOT}/odbc.ini
rc=$?
eend $rc
[ $rc -ne 0 ] && die
else
einfo "Skipping already installed ${msg}"
fi
}
pkg_postinst() {
elog "If this is a new install, please run the following command"
elog "to configure the MySQL ODBC drivers and sources:"
elog "emerge --config =${CATEGORY}/${PF}"
elog "Please note that the driver name used to form the DSN now includes the SLOT."
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-05-04 19:37 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-05-04 19:37 [gentoo-commits] gentoo-x86 commit in dev-db/myodbc: myodbc-5.2.6.ebuild ChangeLog Brian Evans (grknight)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox