* [gentoo-commits] gentoo-x86 commit in net-irc/epic5: epic5-1.1.7.ebuild ChangeLog epic5-1.1.2.ebuild
@ 2014-03-25 8:03 Nathan Phillip Brink (binki)
0 siblings, 0 replies; only message in thread
From: Nathan Phillip Brink (binki) @ 2014-03-25 8:03 UTC (permalink / raw
To: gentoo-commits
binki 14/03/25 08:03:27
Modified: ChangeLog
Added: epic5-1.1.7.ebuild
Removed: epic5-1.1.2.ebuild
Log:
Bump to epic5-1.1.7 which has ruby19 support for bug #505232.
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 743A52E86BA81050)
Revision Changes Path
1.21 net-irc/epic5/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/ChangeLog?r1=1.20&r2=1.21
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/epic5/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog 25 Mar 2014 07:05:11 -0000 1.20
+++ ChangeLog 25 Mar 2014 08:03:27 -0000 1.21
@@ -1,6 +1,13 @@
# ChangeLog for net-irc/epic5
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/epic5/ChangeLog,v 1.20 2014/03/25 07:05:11 binki Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/epic5/ChangeLog,v 1.21 2014/03/25 08:03:27 binki Exp $
+
+*epic5-1.1.7 (25 Mar 2014)
+
+ 25 Mar 2014; Nathan Phillip Brink <binki@gentoo.org> +epic5-1.1.7.ebuild,
+ +files/epic5-1.1.7-ruby-automagic-as-needed.patch, -epic5-1.1.2.ebuild,
+ -files/epic5-1.1.2-ruby-automagic-as-needed.patch:
+ Bump to epic5-1.1.7 which has ruby19 support for bug #505232.
25 Mar 2014; Nathan Phillip Brink <binki@gentoo.org> epic5-1.1.2.ebuild:
Fix ability to compile with USE=-ruby for bug #497080.
1.1 net-irc/epic5/epic5-1.1.7.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/epic5-1.1.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/epic5/epic5-1.1.7.ebuild?rev=1.1&content-type=text/plain
Index: epic5-1.1.7.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/epic5/epic5-1.1.7.ebuild,v 1.1 2014/03/25 08:03:27 binki Exp $
EAPI=4
USE_RUBY="ruby19"
RUBY_OPTIONAL=yes
inherit autotools eutils multilib ruby-ng toolchain-funcs
DESCRIPTION="Epic5 IRC Client"
SRC_URI="ftp://ftp.epicsol.org/pub/epic/EPIC5-PRODUCTION/${P}.tar.bz2"
HOMEPAGE="http://epicsol.org/"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="archive ipv6 perl tcl ruby socks5 valgrind"
RDEPEND="virtual/libiconv
>=dev-libs/openssl-0.9.8e-r3
>=sys-libs/ncurses-5.6-r2
archive? ( app-arch/libarchive )
perl? ( >=dev-lang/perl-5.8.8-r2 )
tcl? ( dev-lang/tcl )
socks5? ( net-proxy/dante )
ruby? ( $(ruby_implementations_depend) )"
DEPEND="${RDEPEND}
valgrind? ( dev-util/valgrind )"
REQUIRED_USE="ruby? ( $(ruby_get_use_targets) )"
S=${WORKDIR}/${P}
pkg_setup() {
# bug #489608, bug #497080
use ruby && ruby-ng_pkg_setup
}
# Don't use ruby-ng's separated sources support:
src_unpack() {
default
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-1.1.2-libarchive-automagic.patch \
"${FILESDIR}"/${P}-ruby-automagic-as-needed.patch \
"${FILESDIR}"/${PN}-1.1.2-tcl-automagic-as-needed.patch \
"${FILESDIR}"/${PN}-1.1.2-perl-automagic-as-needed.patch
eautoconf
}
src_configure() {
econf \
--libexecdir="${EPREFIX}"/usr/lib/misc \
$(use_with archive libarchive) \
$(use_with ipv6) \
$(use_with perl) \
$(use_with ruby ruby "$(ruby_implementation_command ${USE_RUBY})") \
$(use_with socks5) \
$(use_with tcl tcl "${EPREFIX}"/usr/$(get_libdir)/tclConfig.sh) \
$(use_with valgrind valgrind)
}
src_compile() {
# parallel build failure
emake -j1
}
src_install () {
einstall \
sharedir="${D}"/usr/share \
libexecdir="${D}"/usr/lib/misc
dodoc BUG_FORM COPYRIGHT EPIC4-USERS-README README KNOWNBUGS VOTES
cd "${S}"/doc || die
docinto doc
dodoc \
*.txt colors EPIC* IRCII_VERSIONS local_vars missing new-load \
nicknames outputhelp README.SSL SILLINESS TS4
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-03-25 8:03 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-03-25 8:03 [gentoo-commits] gentoo-x86 commit in net-irc/epic5: epic5-1.1.7.ebuild ChangeLog epic5-1.1.2.ebuild Nathan Phillip Brink (binki)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox