* [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: lightdm-1.9.6.ebuild ChangeLog lightdm-1.9.5.ebuild
@ 2014-02-24 8:28 Markos Chandras (hwoarang)
0 siblings, 0 replies; only message in thread
From: Markos Chandras (hwoarang) @ 2014-02-24 8:28 UTC (permalink / raw
To: gentoo-commits
hwoarang 14/02/24 08:28:47
Modified: ChangeLog
Added: lightdm-1.9.6.ebuild
Removed: lightdm-1.9.5.ebuild
Log:
Version bump
(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C)
Revision Changes Path
1.82 x11-misc/lightdm/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?r1=1.81&r2=1.82
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog 23 Dec 2013 22:09:57 -0000 1.81
+++ ChangeLog 24 Feb 2014 08:28:47 -0000 1.82
@@ -1,6 +1,12 @@
# ChangeLog for x11-misc/lightdm
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.81 2013/12/23 22:09:57 maekke Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.82 2014/02/24 08:28:47 hwoarang Exp $
+
+*lightdm-1.9.6 (24 Feb 2014)
+
+ 24 Feb 2014; Markos Chandras <hwoarang@gentoo.org> +lightdm-1.9.6.ebuild,
+ -lightdm-1.9.5.ebuild:
+ Version bump
23 Dec 2013; Markus Meier <maekke@gentoo.org> lightdm-1.8.5.ebuild:
arm stable, bug #492796
1.1 x11-misc/lightdm/lightdm-1.9.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.9.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.9.6.ebuild?rev=1.1&content-type=text/plain
Index: lightdm-1.9.6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.9.6.ebuild,v 1.1 2014/02/24 08:28:47 hwoarang Exp $
EAPI=5
inherit autotools eutils pam readme.gentoo systemd
TRUNK_VERSION="1.9"
DESCRIPTION="A lightweight display manager"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
SRC_URI="http://launchpad.net/${PN}/${TRUNK_VERSION}/${PV}/+download/${P}.tar.xz
mirror://gentoo/introspection-20110205.m4.tar.bz2"
LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="+gtk +introspection kde qt4 razor"
REQUIRED_USE="|| ( gtk kde razor )"
COMMON_DEPEND=">=dev-libs/glib-2.32.3:2
dev-libs/libxml2
sys-apps/accountsservice
virtual/pam
x11-libs/libX11
>=x11-libs/libxklavier-5
introspection? ( >=dev-libs/gobject-introspection-1 )
qt4? (
dev-qt/qtcore:4
dev-qt/qtdbus:4
dev-qt/qtgui:4
)"
RDEPEND="${COMMON_DEPEND}
>=sys-auth/pambase-20101024-r2"
DEPEND="${COMMON_DEPEND}
dev-util/gtk-doc-am
dev-util/intltool
gnome-base/gnome-common
sys-devel/gettext
virtual/pkgconfig"
PDEPEND="gtk? ( x11-misc/lightdm-gtk-greeter )
kde? ( x11-misc/lightdm-kde )
razor? ( razorqt-base/razorqt-lightdm-greeter )"
DOCS=( NEWS )
RESTRICT="test"
src_prepare() {
sed -i -e 's:getgroups:lightdm_&:' tests/src/libsystem.c || die #412369
sed -i -e '/minimum-uid/s:500:1000:' data/users.conf || die
epatch "${FILESDIR}"/${PN}-1.7.7-session-wrapper.patch
epatch_user
# Remove bogus Makefile statement. This needs to go upstream
sed -i /"@YELP_HELP_RULES@"/d help/Makefile.am || die
if has_version dev-libs/gobject-introspection; then
eautoreconf
else
AT_M4DIR=${WORKDIR} eautoreconf
fi
}
src_configure() {
# Set default values if global vars unset
local _greeter _session _user
_greeter=${LIGHTDM_GREETER:=lightdm-gtk-greeter}
_session=${LIGHTDM_SESSION:=gnome}
_user=${LIGHTDM_USER:=root}
# Let user know how lightdm is configured
einfo "Gentoo configuration"
einfo "Default greeter: ${_greeter}"
einfo "Default session: ${_session}"
einfo "Greeter user: ${_user}"
econf \
--localstatedir=/var \
--disable-static \
$(use_enable introspection) \
$(use_enable qt4 liblightdm-qt) \
--with-user-session=${_session} \
--with-greeter-session=${_greeter} \
--with-greeter-user=${_user} \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}
src_install() {
default
# Delete apparmor profiles because they only work with Ubuntu's
# apparmor package. Bug #494426
if [[ -d ${D}/etc/apparmor.d ]]; then
rm -r "${D}/etc/apparmor.d" || die \
"Failed to remove apparmor profiles"
fi
insinto /etc/${PN}
doins data/{${PN},keys}.conf
doins "${FILESDIR}"/Xsession
fperms +x /etc/${PN}/Xsession
prune_libtool_files --all
rm -rf "${ED}"/etc/init
pamd_mimic system-local-login ${PN} auth account session #372229
dopamd "${FILESDIR}"/${PN}-autologin #390863, #423163
readme.gentoo_create_doc
systemd_dounit "${FILESDIR}/${PN}.service"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-02-24 8:28 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-02-24 8:28 [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: lightdm-1.9.6.ebuild ChangeLog lightdm-1.9.5.ebuild Markos Chandras (hwoarang)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox