[gentoo-commits] gentoo-x86 commit in media-gfx/hugin: hugin-2014.0.0_rc1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-gfx/hugin: hugin-2014.0.0_rc1.ebuild ChangeLog

[Markus Meier (maekke)]

maekke      14/02/20 17:54:04

  Modified:             ChangeLog
  Added:                hugin-2014.0.0_rc1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 072AD062)

Revision  Changes    Path
1.143                media-gfx/hugin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/ChangeLog?rev=1.143&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/ChangeLog?rev=1.143&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/ChangeLog?r1=1.142&r2=1.143

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v
retrieving revision 1.142
retrieving revision 1.143
diff -u -r1.142 -r1.143
--- ChangeLog	5 Feb 2014 11:25:22 -0000	1.142
+++ ChangeLog	20 Feb 2014 17:54:04 -0000	1.143
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/hugin
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v 1.142 2014/02/05 11:25:22 nimiux Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v 1.143 2014/02/20 17:54:04 maekke Exp $
+
+*hugin-2014.0.0_rc1 (20 Feb 2014)
+
+  20 Feb 2014; Markus Meier <maekke@gentoo.org> +hugin-2014.0.0_rc1.ebuild:
+  version bump
 
   05 Feb 2014; Chema Alonso <nimiux@gentoo.org> hugin-2013.0.0-r1.ebuild:
   Stable for amd64 wrt bug #497934



1.1                  media-gfx/hugin/hugin-2014.0.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/hugin-2014.0.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/hugin/hugin-2014.0.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: hugin-2014.0.0_rc1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-2014.0.0_rc1.ebuild,v 1.1 2014/02/20 17:54:04 maekke Exp $

EAPI=5

WX_GTK_VER="2.8"
PYTHON_COMPAT=( python{2_7,3_2,3_3} )

inherit base python-single-r1 wxwidgets versionator cmake-utils

DESCRIPTION="GUI for the creation & processing of panoramic images"
HOMEPAGE="http://hugin.sf.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2 SIFT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"

LANGS=" cs da de en_GB es eu fi fr hu it ja nl pl pt_BR ro ru sk sv zh_CN zh_TW"
IUSE="lapack python sift debug $(echo ${LANGS//\ /\ linguas_})"

CDEPEND="
	!!dev-util/cocom
	app-arch/zip
	dev-cpp/tclap
	>=dev-libs/boost-1.49.0-r1:=
	dev-libs/zthread
	>=media-gfx/enblend-4.0
	media-gfx/exiv2
	media-libs/freeglut
	media-libs/glew:=
	media-libs/lensfun
	>=media-libs/libpano13-2.9.19_beta1:0=
	media-libs/libpng:0=
	media-libs/openexr:=
	media-libs/tiff
	sys-libs/zlib
	virtual/jpeg
	x11-libs/wxGTK:2.8=[X,opengl,-odbc]
	lapack? ( virtual/lapack )
	sift? ( media-gfx/autopano-sift-C )"
RDEPEND="${CDEPEND}
	media-libs/exiftool"
DEPEND="${CDEPEND}
	virtual/pkgconfig
	python? ( ${PYTHON_DEPS} >=dev-lang/swig-2.0.4 )"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

S=${WORKDIR}/${PN}-$(get_version_component_range 1-3)

pkg_setup() {
	DOCS="authors.txt README TODO"
	mycmakeargs=(
		$(cmake-utils_use_enable lapack LAPACK)
		$(cmake-utils_use_build python HSI)
	)
	python-single-r1_pkg_setup
}

src_prepare() {
	sed \
		-e 's:-O3::g' \
		-i src/celeste/CMakeLists.txt || die
	rm CMakeModules/{FindLAPACK,FindPkgConfig}.cmake || die

	cmake-utils_src_prepare
}

src_install() {
	cmake-utils_src_install
	python_optimize

	for lang in ${LANGS} ; do
		case ${lang} in
			ca) dir=ca_ES;;
			cs) dir=cs_CZ;;
			*) dir=${lang};;
		esac
		use linguas_${lang} || rm -r "${D}"/usr/share/locale/${dir}
	done
}