* [gentoo-commits] gentoo-x86 commit in media-libs/gstreamer: gstreamer-1.2.3.ebuild ChangeLog gstreamer-1.0.6.ebuild gstreamer-1.0.7.ebuild gstreamer-1.0.8.ebuild
@ 2014-02-11 23:17 Gilles Dartiguelongue (eva)
0 siblings, 0 replies; only message in thread
From: Gilles Dartiguelongue (eva) @ 2014-02-11 23:17 UTC (permalink / raw
To: gentoo-commits
eva 14/02/11 23:17:31
Modified: ChangeLog
Added: gstreamer-1.2.3.ebuild
Removed: gstreamer-1.0.6.ebuild gstreamer-1.0.7.ebuild
gstreamer-1.0.8.ebuild
Log:
Version bump. Clean up old revisions.
(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key C6085806)
Revision Changes Path
1.356 media-libs/gstreamer/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.356&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?rev=1.356&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/ChangeLog?r1=1.355&r2=1.356
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v
retrieving revision 1.355
retrieving revision 1.356
diff -u -r1.355 -r1.356
--- ChangeLog 22 Oct 2013 07:20:26 -0000 1.355
+++ ChangeLog 11 Feb 2014 23:17:31 -0000 1.356
@@ -1,6 +1,12 @@
# ChangeLog for media-libs/gstreamer
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.355 2013/10/22 07:20:26 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/ChangeLog,v 1.356 2014/02/11 23:17:31 eva Exp $
+
+*gstreamer-1.2.3 (11 Feb 2014)
+
+ 11 Feb 2014; Gilles Dartiguelongue <eva@gentoo.org> -gstreamer-1.0.6.ebuild,
+ -gstreamer-1.0.7.ebuild, -gstreamer-1.0.8.ebuild, +gstreamer-1.2.3.ebuild:
+ Version bump. Clean up old revisions.
22 Oct 2013; Agostino Sarubbo <ago@gentoo.org> gstreamer-1.0.10.ebuild:
Stable for sparc, wrt bug #480908
1.1 media-libs/gstreamer/gstreamer-1.2.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/gstreamer-1.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/gstreamer/gstreamer-1.2.3.ebuild?rev=1.1&content-type=text/plain
Index: gstreamer-1.2.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer/gstreamer-1.2.3.ebuild,v 1.1 2014/02/11 23:17:31 eva Exp $
EAPI="5"
inherit eutils multilib pax-utils
DESCRIPTION="Streaming media framework"
HOMEPAGE="http://gstreamer.freedesktop.org/"
SRC_URI="http://${PN}.freedesktop.org/src/${PN}/${P}.tar.xz"
LICENSE="LGPL-2+"
SLOT="1.0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+introspection nls +orc test"
RDEPEND="
>=dev-libs/glib-2.32:2
introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
"
DEPEND="${RDEPEND}
app-arch/xz-utils
>=dev-util/gtk-doc-am-1.12
sys-devel/bison
sys-devel/flex
virtual/pkgconfig
nls? ( sys-devel/gettext )
"
# gtk-doc-am to install API docs
src_configure() {
if [[ ${CHOST} == *-interix* ]] ; then
export ac_cv_lib_dl_dladdr=no
export ac_cv_func_poll=no
fi
if [[ ${CHOST} == powerpc-apple-darwin* ]] ; then
# GCC groks this, but then refers to an implementation (___multi3,
# ___udivti3) that don't exist (at least I can't find it), so force
# this one to be off, such that we use 2x64bit emulation code.
export gst_cv_uint128_t=no
fi
# Disable static archives, dependency tracking and examples
# to speed up build time
# Disable debug, as it only affects -g passing (debugging symbols), this must done through make.conf in gentoo
econf \
--disable-debug \
--disable-examples \
--disable-static \
--disable-valgrind \
--enable-check \
$(use_enable introspection) \
$(use_enable nls) \
$(use_enable test tests) \
--with-package-name="GStreamer ebuild for Gentoo" \
--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer"
}
src_install() {
DOCS="AUTHORS ChangeLog NEWS MAINTAINERS README RELEASE"
default
prune_libtool_files --modules
# Needed for orc-using gst plugins on hardened/PaX systems, bug #421579
use orc && pax-mark -m "${ED}usr/bin/gst-launch-${SLOT}" \
"${ED}usr/libexec/gstreamer-${SLOT}/gst-plugin-scanner"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2014-02-11 23:17 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-02-11 23:17 [gentoo-commits] gentoo-x86 commit in media-libs/gstreamer: gstreamer-1.2.3.ebuild ChangeLog gstreamer-1.0.6.ebuild gstreamer-1.0.7.ebuild gstreamer-1.0.8.ebuild Gilles Dartiguelongue (eva)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox