[gentoo-commits] gentoo-x86 commit in dev-ruby/locale: locale-2.1.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-ruby/locale: locale-2.1.0.ebuild ChangeLog

[Manuel Rueger (mrueg)]

mrueg       13/12/15 20:52:21

  Modified:             ChangeLog
  Added:                locale-2.1.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.52                 dev-ruby/locale/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/locale/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/locale/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/locale/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/locale/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	26 Oct 2013 06:45:38 -0000	1.51
+++ ChangeLog	15 Dec 2013 20:52:21 -0000	1.52
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/locale
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/locale/ChangeLog,v 1.51 2013/10/26 06:45:38 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/locale/ChangeLog,v 1.52 2013/12/15 20:52:21 mrueg Exp $
+
+*locale-2.1.0 (15 Dec 2013)
+
+  15 Dec 2013; Manuel Rüger <mrueg@gentoo.org> +locale-2.1.0.ebuild:
+  Version bump.
 
   26 Oct 2013; Hans de Graaff <graaff@gentoo.org> locale-2.0.9.ebuild:
   Avoid failing test on jruby.



1.1                  dev-ruby/locale/locale-2.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/locale/locale-2.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/locale/locale-2.1.0.ebuild?rev=1.1&content-type=text/plain

Index: locale-2.1.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/locale/locale-2.1.0.ebuild,v 1.1 2013/12/15 20:52:21 mrueg Exp $

EAPI=5

USE_RUBY="ruby18 ruby19 jruby"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_DOCDIR="doc/reference"
RUBY_FAKEGEM_EXTRADOC="ChangeLog README.rdoc doc/text/news.md"

RUBY_FAKEGEM_TASK_TEST="test"

inherit ruby-fakegem

DESCRIPTION="A pure ruby library which provides basic APIs for localization."
HOMEPAGE="https://github.com/ruby-gettext/locale"
LICENSE="|| ( Ruby GPL-2 )"
SRC_URI="https://github.com/ruby-gettext/locale/archive/${PV}.tar.gz -> ${P}-git.tgz"

KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-macos"
SLOT="0"
IUSE=""

ruby_add_bdepend "doc? ( dev-ruby/yard )"

ruby_add_bdepend "test? ( dev-ruby/test-unit:2 dev-ruby/test-unit-rr )"

all_ruby_prepare() {
	sed -i -e '/notify/ s:^:#:' test/run-test.rb || die
}

each_ruby_prepare() {
	case ${RUBY} in
		*jruby)
			# Avoid failing tests in the partial jruby
			# implementation. This may be dependeny on the specific
			# locales available or it may be an issue with Gentoo still
			# using jruby 1.6.
			sed -i -e '/test_locales/,/end/ s:^:#:' test/test_driver_jruby.rb || die
			;;
	esac
}

all_ruby_compile() {
	all_fakegem_compile

	if use doc ; then
		yard || die
	fi
}

each_ruby_test() {
	${RUBY} test/run-test.rb || die
}

all_ruby_install() {
	all_fakegem_install

	insinto /usr/share/doc/${PF}
	doins -r samples || die
}