[gentoo-commits] gentoo-x86 commit in games-simulation/flightgear: flightgear-2.12.1.ebuild ChangeLog flightgear-2.12.0.ebuild

[gentoo-commits] gentoo-x86 commit in games-simulation/flightgear: flightgear-2.12.1.ebuild ChangeLog flightgear-2.12.0.ebuild

[Maciej Mrozowski (reavertm)]

reavertm    13/12/12 05:15:24

  Modified:             ChangeLog
  Added:                flightgear-2.12.1.ebuild
  Removed:              flightgear-2.12.0.ebuild
  Log:
  Version bump, remove old.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B1E955DB)

Revision  Changes    Path
1.67                 games-simulation/flightgear/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-simulation/flightgear/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-simulation/flightgear/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-simulation/flightgear/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-simulation/flightgear/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	7 Dec 2013 22:27:38 -0000	1.66
+++ ChangeLog	12 Dec 2013 05:15:24 -0000	1.67
@@ -1,6 +1,12 @@
 # ChangeLog for games-simulation/flightgear
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-simulation/flightgear/ChangeLog,v 1.66 2013/12/07 22:27:38 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-simulation/flightgear/ChangeLog,v 1.67 2013/12/12 05:15:24 reavertm Exp $
+
+*flightgear-2.12.1 (12 Dec 2013)
+
+  12 Dec 2013; Maciej Mrozowski <reavertm@gentoo.org> +flightgear-2.12.1.ebuild,
+  -flightgear-2.12.0.ebuild:
+  Version bump, remove old.
 
   07 Dec 2013; Pacho Ramos <pacho@gentoo.org> flightgear-2.10.0.ebuild:
   x86 stable, bug #488552



1.1                  games-simulation/flightgear/flightgear-2.12.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-simulation/flightgear/flightgear-2.12.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-simulation/flightgear/flightgear-2.12.1.ebuild?rev=1.1&content-type=text/plain

Index: flightgear-2.12.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-simulation/flightgear/flightgear-2.12.1.ebuild,v 1.1 2013/12/12 05:15:24 reavertm Exp $

EAPI=5

inherit games cmake-utils

DESCRIPTION="Open Source Flight Simulator"
HOMEPAGE="http://www.flightgear.org/"
SRC_URI="mirror://flightgear/Source/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="debug jpeg +jsbsim oldfdm subversion test +udev +utils +yasim"

COMMON_DEPEND="
	dev-db/sqlite:3
	>=dev-games/openscenegraph-3.0.1[png]
	~dev-games/simgear-${PV}[jpeg?,subversion?]
	sys-libs/zlib
	x11-libs/libX11
	udev? ( virtual/udev )
	utils? (
		media-libs/freeglut
		media-libs/libpng
		virtual/opengl
	)
"
# Most entries below are just buildsystem bugs (deps unconditionally
# inherited from static version of simgear)
DEPEND="${COMMON_DEPEND}
	>=dev-libs/boost-1.44
	media-libs/openal
	>=media-libs/plib-1.8.5
	jpeg? ( virtual/jpeg )
	subversion? (
		dev-libs/apr
		dev-vcs/subversion
	)
"
RDEPEND="${COMMON_DEPEND}
	~games-simulation/${PN}-data-${PV}
"

DOCS=(AUTHORS ChangeLog NEWS README Thanks)

src_configure() {
	local mycmakeargs=(
		-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}
		-DEMBEDDED_SIMGEAR=OFF
		-DENABLE_FGADMIN=OFF
		-DENABLE_PROFILE=OFF
		-DENABLE_RTI=OFF
		-DFG_DATA_DIR="${GAMES_DATADIR}"/${PN}
		-DSIMGEAR_SHARED=ON
		-DSP_FDMS=OFF
		-DSYSTEM_SQLITE=ON
		$(cmake-utils_use jpeg JPEG_FACTORY)
		$(cmake-utils_use_enable jsbsim)
		$(cmake-utils_use_enable oldfdm LARCSIM)
		$(cmake-utils_use_enable oldfdm UIUC_MODEL)
		$(cmake-utils_use_enable subversion LIBSVN)
		$(cmake-utils_use test LOGGING)
		$(cmake-utils_use_enable test TESTS)
		$(cmake-utils_use udev EVENT_INPUT)
		$(cmake-utils_use_enable utils FGELEV)
		$(cmake-utils_use_enable utils FGJS)
		$(cmake-utils_use_with utils FGPANEL)
		$(cmake-utils_use_enable utils FGVIEWER)
		$(cmake-utils_use_enable utils GPSSMOOTH)
		$(cmake-utils_use_enable utils JS_DEMO)
		$(cmake-utils_use_enable utils METAR)
		$(cmake-utils_use_enable utils TERRASYNC)
		$(cmake-utils_use_enable yasim)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newicon -s 48 icons/fg-48.png ${PN}.png
	newmenu package/${PN}.desktop ${PN}.desktop

	prepgamesdirs
}