* [gentoo-commits] gentoo-x86 commit in app-i18n/ibus: ibus-1.5.4-r1.ebuild ChangeLog ibus-1.5.4.ebuild
@ 2013-11-17 6:40 Naohiro Aota (naota)
0 siblings, 0 replies; only message in thread
From: Naohiro Aota (naota) @ 2013-11-17 6:40 UTC (permalink / raw
To: gentoo-commits
naota 13/11/17 06:40:29
Modified: ChangeLog
Added: ibus-1.5.4-r1.ebuild
Removed: ibus-1.5.4.ebuild
Log:
Call gnome2_schemas_{savelist,update} to update schemas properly. #490646
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F8551514)
Revision Changes Path
1.134 app-i18n/ibus/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/ibus/ChangeLog?rev=1.134&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/ibus/ChangeLog?rev=1.134&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/ibus/ChangeLog?r1=1.133&r2=1.134
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v
retrieving revision 1.133
retrieving revision 1.134
diff -u -r1.133 -r1.134
--- ChangeLog 4 Nov 2013 08:55:26 -0000 1.133
+++ ChangeLog 17 Nov 2013 06:40:29 -0000 1.134
@@ -1,6 +1,12 @@
# ChangeLog for app-i18n/ibus
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.133 2013/11/04 08:55:26 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ChangeLog,v 1.134 2013/11/17 06:40:29 naota Exp $
+
+*ibus-1.5.4-r1 (17 Nov 2013)
+
+ 17 Nov 2013; Naohiro Aota <naota@gentoo.org> +ibus-1.5.4-r1.ebuild,
+ -ibus-1.5.4.ebuild:
+ Call gnome2_schemas_{savelist,update} to update schemas properly. #490646
*ibus-1.5.4 (04 Nov 2013)
1.1 app-i18n/ibus/ibus-1.5.4-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/ibus/ibus-1.5.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/ibus/ibus-1.5.4-r1.ebuild?rev=1.1&content-type=text/plain
Index: ibus-1.5.4-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/ibus/ibus-1.5.4-r1.ebuild,v 1.1 2013/11/17 06:40:29 naota Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )
VALA_MIN_API_VERSION="0.18"
VALA_USE_DEPEND="vapigen"
# Vapigen is needed for the vala binding
# Valac is needed when building from git for the engine
inherit bash-completion-r1 eutils gnome2-utils multilib python-single-r1 vala virtualx
DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
HOMEPAGE="http://code.google.com/p/ibus/"
SRC_URI="http://ibus.googlecode.com/files/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="dconf deprecated +gconf gtk +gtk3 +introspection nls +python test vala wayland +X"
REQUIRED_USE="|| ( gtk gtk3 X )
deprecated? ( python )
python? (
${PYTHON_REQUIRED_USE}
|| ( deprecated ( gtk3 introspection ) ) )" #342903
COMMON_DEPEND="
>=dev-libs/glib-2.26:2
gnome-base/librsvg:2
sys-apps/dbus[X?]
app-text/iso-codes
dconf? ( >=gnome-base/dconf-0.13.4 )
gconf? ( >=gnome-base/gconf-2.12:2 )
gtk? ( x11-libs/gtk+:2 )
gtk3? ( x11-libs/gtk+:3 )
python? ( ${PYTHON_DEPS} )
X? (
x11-libs/libX11
x11-libs/gtk+:2 )
introspection? ( >=dev-libs/gobject-introspection-0.6.8 )
nls? ( virtual/libintl )
wayland? ( dev-libs/wayland )"
RDEPEND="${COMMON_DEPEND}
x11-apps/setxkbmap
python? (
dev-python/pyxdg
deprecated? (
>=dev-python/dbus-python-0.83
dev-python/pygobject:2
dev-python/pygtk:2 )
gtk3? (
dev-python/pygobject:3
x11-libs/gdk-pixbuf:2[introspection]
x11-libs/pango[introspection]
x11-libs/gtk+:3[introspection] )
)"
DEPEND="${COMMON_DEPEND}
>=dev-lang/perl-5.8.1
dev-util/gtk-doc-am
dev-util/intltool
virtual/pkgconfig
nls? ( >=sys-devel/gettext-0.16.1 )
vala? ( $(vala_depend) )
gnome-base/gconf"
# stress test in bus/ fails
# IBUS-CRITICAL **: bus_test_client_init: assertion `ibus_bus_is_connected (_bus)' failed
RESTRICT="test"
DOCS="AUTHORS ChangeLog NEWS README"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_prepare() {
# We run "dconf update" in pkg_postinst/postrm to avoid sandbox violations
sed -e 's/dconf update/$(NULL)/' \
-i data/dconf/Makefile.{am,in} || die
use vala && vala_src_prepare
cp "${S}"/client/gtk2/ibusimcontext.c "${S}"/client/gtk3/ibusimcontext.c || die
}
src_configure() {
local python_conf
if use python; then
python_conf="PYTHON=${PYTHON}
$(use_enable deprecated python-library)
$(use_enable gtk3 setup)"
else
python_conf="--disable-python-library --disable-setup"
fi
econf \
$(use_enable dconf) \
$(use_enable introspection) \
$(use_enable gconf) \
$(use_enable gtk gtk2) \
$(use_enable gtk xim) \
$(use_enable gtk3) \
$(use_enable gtk3 ui) \
$(use_enable nls) \
$(use_enable test tests) \
$(use_enable X xim) \
$(use_enable vala) \
$(use_enable wayland) \
${python_conf}
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
Xemake check || die
}
src_install() {
default
prune_libtool_files --all
mv "${ED}"/usr/share/bash-completion/completions/ibus.bash ${T}
rm -rf "${ED}"/usr/share/bash-completion || die
newbashcomp "${T}"/ibus.bash ${PN}
insinto /etc/X11/xinit/xinput.d
newins xinput-ibus ibus.conf
keepdir /usr/share/ibus/{engine,icons} #289547
use deprecated && python_optimize
use python && use gtk3 && python_optimize
}
pkg_preinst() {
use gconf && gnome2_gconf_savelist
use gconf && gnome2_schemas_savelist
gnome2_icon_savelist
}
pkg_postinst() {
if use dconf; then
ebegin "Updating dconf system databases"
dconf update
eend $?
fi
use gconf && gnome2_gconf_install
use gconf && gnome2_schemas_update
use gtk && gnome2_query_immodules_gtk2
use gtk3 && gnome2_query_immodules_gtk3
gnome2_icon_cache_update
elog "To use ibus, you should:"
elog "1. Get input engines from sunrise overlay."
elog " Run \"emerge -s ibus-\" in your favorite terminal"
elog " for a list of packages we already have."
elog
elog "2. Setup ibus:"
elog
elog " $ ibus-setup"
elog
elog "3. Set the following in your user startup scripts"
elog " such as .xinitrc, .xsession or .xprofile:"
elog
elog " export XMODIFIERS=\"@im=ibus\""
elog " export GTK_IM_MODULE=\"ibus\""
elog " export QT_IM_MODULE=\"xim\""
elog " ibus-daemon -d -x"
}
pkg_postrm() {
if use dconf; then
ebegin "Updating dconf system databases"
dconf update
eend $?
fi
use gtk && gnome2_query_immodules_gtk2
use gtk3 && gnome2_query_immodules_gtk3
use gconf && gnome2_schemas_update
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-11-17 6:40 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-11-17 6:40 [gentoo-commits] gentoo-x86 commit in app-i18n/ibus: ibus-1.5.4-r1.ebuild ChangeLog ibus-1.5.4.ebuild Naohiro Aota (naota)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox