* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.1.3-r1.ebuild ChangeLog
@ 2013-10-22 2:00 Doug Goldstein (cardoe)
0 siblings, 0 replies; 3+ messages in thread
From: Doug Goldstein (cardoe) @ 2013-10-22 2:00 UTC (permalink / raw
To: gentoo-commits
cardoe 13/10/22 02:00:33
Modified: ChangeLog
Added: libvirt-1.1.3-r1.ebuild
Log:
Fix for CVE-2013-4400 and CVE-2013-4401.
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key D7DFA8D318FA9AEF!)
Revision Changes Path
1.333 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.333&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.333&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.332&r2=1.333
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.332
retrieving revision 1.333
diff -u -r1.332 -r1.333
--- ChangeLog 13 Oct 2013 10:32:11 -0000 1.332
+++ ChangeLog 22 Oct 2013 02:00:33 -0000 1.333
@@ -1,6 +1,11 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.332 2013/10/13 10:32:11 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.333 2013/10/22 02:00:33 cardoe Exp $
+
+*libvirt-1.1.3-r1 (22 Oct 2013)
+
+ 22 Oct 2013; Doug Goldstein <cardoe@gentoo.org> +libvirt-1.1.3-r1.ebuild:
+ Fix for CVE-2013-4400 and CVE-2013-4401.
13 Oct 2013; Agostino Sarubbo <ago@gentoo.org> libvirt-1.1.3.ebuild:
Stable for x86, wrt bug #487684
1.1 app-emulation/libvirt/libvirt-1.1.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?rev=1.1&content-type=text/plain
Index: libvirt-1.1.3-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild,v 1.1 2013/10/22 02:00:33 cardoe Exp $
EAPI=5
BACKPORTS=062ad8b2
AUTOTOOLIZE=yes
MY_P="${P/_rc/-rc}"
PYTHON_COMPAT=( python{2_6,2_7} )
inherit eutils python-single-r1 user autotools linux-info systemd readme.gentoo
if [[ ${PV} = *9999* ]]; then
inherit git-2
EGIT_REPO_URI="git://libvirt.org/libvirt.git"
AUTOTOOLIZE=yes
SRC_URI=""
KEYWORDS=""
else
SRC_URI="http://libvirt.org/sources/${MY_P}.tar.gz
ftp://libvirt.org/libvirt/${MY_P}.tar.gz
${BACKPORTS:+
http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
KEYWORDS="~amd64 ~x86"
fi
S="${WORKDIR}/${P%_rc*}"
DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
LICENSE="LGPL-2.1"
SLOT="0"
IUSE="audit avahi +caps firewalld fuse iscsi +libvirtd lvm lxc +macvtap nfs \
nls numa openvz parted pcap phyp policykit python +qemu rbd sasl \
selinux +udev uml +vepa virtualbox virt-network xen elibc_glibc \
systemd"
REQUIRED_USE="libvirtd? ( || ( lxc openvz qemu uml virtualbox xen ) )
lxc? ( caps libvirtd )
openvz? ( libvirtd )
qemu? ( libvirtd )
uml? ( libvirtd )
vepa? ( macvtap )
virtualbox? ( libvirtd )
xen? ( libvirtd )
virt-network? ( libvirtd )
firewalld? ( virt-network )
python? ( ${PYTHON_REQUIRED_USE} )"
# gettext.sh command is used by the libvirt command wrappers, and it's
# non-optional, so put it into RDEPEND.
# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
# package will use 3 by default. Since we don't have slot pinning in an API,
# we must go with the most recent
RDEPEND="sys-libs/readline
sys-libs/ncurses
>=net-misc/curl-7.18.0
dev-libs/libgcrypt
>=dev-libs/libxml2-2.7.6
dev-libs/libnl:3
>=net-libs/gnutls-1.0.25
net-libs/libssh2
sys-apps/dmidecode
>=sys-apps/util-linux-2.17
sys-devel/gettext
>=net-analyzer/netcat6-1.0-r2
app-misc/scrub
audit? ( sys-process/audit )
avahi? ( >=net-dns/avahi-0.6[dbus] )
caps? ( sys-libs/libcap-ng )
fuse? ( >=sys-fs/fuse-2.8.6 )
iscsi? ( sys-block/open-iscsi )
lxc? ( sys-power/pm-utils )
lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
nfs? ( net-fs/nfs-utils )
numa? (
>sys-process/numactl-2.0.2
sys-process/numad
)
openvz? ( sys-kernel/openvz-sources )
parted? (
>=sys-block/parted-1.8[device-mapper]
sys-fs/lvm2
)
pcap? ( >=net-libs/libpcap-1.0.0 )
policykit? ( >=sys-auth/polkit-0.9 )
python? ( ${PYTHON_DEPS} )
qemu? (
>=app-emulation/qemu-0.13.0
dev-libs/yajl
sys-power/pm-utils
)
rbd? ( sys-cluster/ceph )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( >=sys-libs/libselinux-2.0.85 )
virtualbox? ( || ( app-emulation/virtualbox >=app-emulation/virtualbox-bin-2.2.0 ) )
xen? ( app-emulation/xen-tools app-emulation/xen )
udev? ( virtual/udev >=x11-libs/libpciaccess-0.10.9 )
virt-network? ( net-dns/dnsmasq
>=net-firewall/iptables-1.4.10
net-misc/radvd
net-firewall/ebtables
sys-apps/iproute2[-minimal]
firewalld? ( net-firewall/firewalld )
)
elibc_glibc? ( || ( >=net-libs/libtirpc-0.2.2-r1 <sys-libs/glibc-2.14 ) )"
# one? ( dev-libs/xmlrpc-c )
DEPEND="${RDEPEND}
virtual/pkgconfig
app-text/xhtml1
dev-lang/perl
dev-libs/libxslt"
DOC_CONTENTS="For the basic networking support (bridged and routed networks)
you don't need any extra software. For more complex network modes
including but not limited to NATed network, you can enable the
'virt-network' USE flag.\n\n
If you are using dnsmasq on your system, you will have
to configure /etc/dnsmasq.conf to enable the following settings:\n\n
bind-interfaces\n
interface or except-interface\n\n
Otherwise you might have issues with your existing DNS server."
LXC_CONFIG_CHECK="
~CGROUPS
~CGROUP_FREEZER
~CGROUP_DEVICE
~CGROUP_CPUACCT
~CGROUP_SCHED
~CGROUP_PERF
~BLK_CGROUP
~NET_CLS_CGROUP
~NETPRIO_CGROUP
~CPUSETS
~RESOURCE_COUNTERS
~NAMESPACES
~UTS_NS
~IPC_NS
~PID_NS
~NET_NS
~USER_NS
~DEVPTS_MULTIPLE_INSTANCES
~VETH
~MACVLAN
~POSIX_MQUEUE
~SECURITYFS
~!GRKERNSEC_CHROOT_MOUNT
~!GRKERNSEC_CHROOT_DOUBLE
~!GRKERNSEC_CHROOT_PIVOT
~!GRKERNSEC_CHROOT_CHMOD
~!GRKERNSEC_CHROOT_CAPS
"
VIRTNET_CONFIG_CHECK="
~BRIDGE_NF_EBTABLES
~BRIDGE_EBT_MARK_T
~NETFILTER_ADVANCED
~NETFILTER_XT_TARGET_CHECKSUM
~NETFILTER_XT_CONNMARK
~NETFILTER_XT_MARK
"
MACVTAP_CONFIG_CHECK=" ~MACVTAP"
LVM_CONFIG_CHECK=" ~BLK_DEV_DM ~DM_SNAPSHOT ~DM_MULTIPATH"
pkg_setup() {
enewgroup qemu 77
enewuser qemu 77 -1 -1 qemu kvm
# Some people used the masked ebuild which was not adding the qemu
# user to the kvm group originally. This results in VMs failing to
# start for some users. bug #430808
egetent group kvm | grep -q qemu
if [[ $? -ne 0 ]]; then
gpasswd -a qemu kvm
fi
python-single-r1_pkg_setup
# Handle specific kernel versions for different features
kernel_is lt 3 6 && LXC_CONFIG_CHECK+=" ~CGROUP_MEM_RES_CTLR"
kernel_is ge 3 6 && LXC_CONFIG_CHECK+=" ~MEMCG ~MEMCG_SWAP ~MEMCG_KMEM"
CONFIG_CHECK=""
use fuse && CONFIG_CHECK+=" ~FUSE_FS"
use lvm && CONFIG_CHECK+="${LVM_CONFIG_CHECK}"
use lxc && CONFIG_CHECK+="${LXC_CONFIG_CHECK}"
use macvtap && CONFIG_CHECK+="${MACVTAP_CONFIG_CHECK}"
use virt-network && CONFIG_CHECK+="${VIRTNET_CONFIG_CHECK}"
if [[ -n ${CONFIG_CHECK} ]]; then
linux-info_pkg_setup
fi
}
src_prepare() {
touch "${S}/.mailmap"
[[ -n ${BACKPORTS} ]] && \
EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
epatch
if [[ ${PV} = *9999* ]]; then
# git checkouts require bootstrapping to create the configure script.
# Additionally the submodules must be cloned to the right locations
# bug #377279
./bootstrap || die "bootstrap failed"
(
git submodule status | sed 's/^[ +-]//;s/ .*//'
git hash-object bootstrap.conf
) >.git-module-status
fi
epatch_user
[[ -n ${AUTOTOOLIZE} ]] && eautoreconf
# Tweak the init script
local avahi_init=
local iscsi_init=
local rbd_init=
local firewalld_init=
cp "${FILESDIR}/libvirtd.init-r12" "${S}/libvirtd.init"
use avahi && avahi_init='avahi-daemon'
use iscsi && iscsi_init='iscsid'
use rbd && rbd_init='ceph'
use firewalld && firewalld_init='need firewalld'
sed -e "s/USE_FLAG_FIREWALLD/${firewalld_init}/" -i "${S}/libvirtd.init"
sed -e "s/USE_FLAG_AVAHI/${avahi_init}/" -i "${S}/libvirtd.init"
sed -e "s/USE_FLAG_ISCSI/${iscsi_init}/" -i "${S}/libvirtd.init"
sed -e "s/USE_FLAG_RBD/${rbd_init}/" -i "${S}/libvirtd.init"
}
src_configure() {
local myconf=""
## enable/disable daemon, otherwise client only utils
myconf="${myconf} $(use_with libvirtd)"
## enable/disable the daemon using avahi to find VMs
myconf="${myconf} $(use_with avahi)"
## hypervisors on the local host
myconf="${myconf} $(use_with xen) $(use_with xen xen-inotify)"
myconf+=" --without-xenapi"
if use xen && has_version ">=app-emulation/xen-tools-4.2.0"; then
myconf+=" --with-libxl"
else
myconf+=" --without-libxl"
fi
myconf="${myconf} $(use_with openvz)"
myconf="${myconf} $(use_with lxc)"
if use virtualbox && has_version app-emulation/virtualbox-ose; then
myconf="${myconf} --with-vbox=/usr/lib/virtualbox-ose/"
else
myconf="${myconf} $(use_with virtualbox vbox)"
fi
myconf="${myconf} $(use_with uml)"
myconf="${myconf} $(use_with qemu)"
myconf="${myconf} $(use_with qemu yajl)" # Use QMP over HMP
myconf="${myconf} $(use_with phyp)"
myconf="${myconf} --with-esx"
myconf="${myconf} --with-vmware"
## additional host drivers
myconf="${myconf} $(use_with virt-network network)"
myconf="${myconf} --with-storage-fs"
myconf="${myconf} $(use_with lvm storage-lvm)"
myconf="${myconf} $(use_with iscsi storage-iscsi)"
myconf="${myconf} $(use_with parted storage-disk)"
myconf="${myconf} $(use_with lvm storage-mpath)"
myconf="${myconf} $(use_with rbd storage-rbd)"
myconf="${myconf} $(use_with numa numactl)"
myconf="${myconf} $(use_with numa numad)"
myconf="${myconf} $(use_with selinux)"
myconf="${myconf} $(use_with fuse)"
# udev for device support details
myconf="${myconf} $(use_with udev)"
# linux capability support so we don't need privileged accounts
myconf="${myconf} $(use_with caps capng)"
## auth stuff
myconf="${myconf} $(use_with policykit polkit)"
myconf="${myconf} $(use_with sasl)"
# network bits
myconf="${myconf} $(use_with macvtap)"
myconf="${myconf} $(use_with pcap libpcap)"
myconf="${myconf} $(use_with vepa virtualport)"
myconf="${myconf} $(use_with firewalld)"
## other
myconf="${myconf} $(use_enable nls)"
myconf="${myconf} $(use_with python)"
# user privilege bits fir qemu/kvm
if use caps; then
myconf="${myconf} --with-qemu-user=qemu"
myconf="${myconf} --with-qemu-group=qemu"
else
myconf="${myconf} --with-qemu-user=root"
myconf="${myconf} --with-qemu-group=root"
fi
# audit support
myconf="${myconf} $(use_with audit)"
## stuff we don't yet support
myconf="${myconf} --without-netcf"
# we use udev over hal
myconf="${myconf} --without-hal"
# locking support
myconf="${myconf} --without-sanlock"
# systemd unit files
use systemd && myconf="${myconf} --with-init-script=systemd"
# this is a nasty trick to work around the problem in bug
# #275073. The reason why we don't solve this properly is that
# it'll require us to rebuild autotools (and we don't really want
# to do that right now). The proper solution has been sent
# upstream and should hopefully land in 0.7.7, in the mean time,
# mime the same functionality with this.
case ${CHOST} in
*cygwin* | *mingw* )
;;
*)
ac_cv_prog_WINDRES=no
;;
esac
econf \
${myconf} \
--disable-static \
--docdir=/usr/share/doc/${PF} \
--with-remote \
--localstatedir=/var
if [[ ${PV} = *9999* ]]; then
# Restore gnulib's config.sub and config.guess
# bug #377279
(cd .gnulib && git reset --hard > /dev/null)
fi
}
src_test() {
# Explicitly allow parallel build of tests
export VIR_TEST_DEBUG=1
HOME="${T}" emake check || die "tests failed"
}
src_install() {
emake install \
DESTDIR="${D}" \
HTML_DIR=/usr/share/doc/${PF}/html \
DOCS_DIR=/usr/share/doc/${PF} \
EXAMPLE_DIR=/usr/share/doc/${PF}/examples \
SYSTEMD_UNIT_DIR="$(systemd_get_unitdir)" \
|| die "emake install failed"
find "${D}" -name '*.la' -delete || die
use libvirtd || return 0
# From here, only libvirtd-related instructions, be warned!
newinitd "${S}/libvirtd.init" libvirtd || die
newconfd "${FILESDIR}/libvirtd.confd-r4" libvirtd || die
keepdir /var/lib/libvirt/images
use python && python_optimize
readme.gentoo_create_doc
}
pkg_preinst() {
# we only ever want to generate this once
if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
fi
# We really don't want to use or support old PolicyKit cause it
# screws with the new polkit integration
if has_version sys-auth/policykit; then
rm -rf "${D}"/usr/share/PolicyKit/policy/org.libvirt.unix.policy
fi
# Only sysctl files ending in .conf work
dodir /etc/sysctl.d
mv "${D}"/usr/lib/sysctl.d/libvirtd.conf "${D}"/etc/sysctl.d/libvirtd.conf
}
pkg_postinst() {
if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml
fi
# support for dropped privileges
if use qemu; then
fperms 0750 "${EROOT}/var/lib/libvirt/qemu"
fperms 0750 "${EROOT}/var/cache/libvirt/qemu"
fi
if use caps && use qemu; then
fowners -R qemu:qemu "${EROOT}/var/lib/libvirt/qemu"
fowners -R qemu:qemu "${EROOT}/var/cache/libvirt/qemu"
elif use qemu; then
fowners -R root:root "${EROOT}/var/lib/libvirt/qemu"
fowners -R root:root "${EROOT}/var/cache/libvirt/qemu"
fi
if ! use policykit; then
elog "To allow normal users to connect to libvirtd you must change the"
elog "unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
fi
use libvirtd || return 0
# From here, only libvirtd-related instructions, be warned!
readme.gentoo_print_elog
if use caps && use qemu; then
elog "libvirt will now start qemu/kvm VMs with non-root privileges."
elog "Ensure any resources your VMs use are accessible by qemu:qemu"
fi
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.1.3-r1.ebuild ChangeLog
@ 2013-10-25 16:24 Agostino Sarubbo (ago)
0 siblings, 0 replies; 3+ messages in thread
From: Agostino Sarubbo (ago) @ 2013-10-25 16:24 UTC (permalink / raw
To: gentoo-commits
ago 13/10/25 16:24:44
Modified: libvirt-1.1.3-r1.ebuild ChangeLog
Log:
Stable for amd64, wrt bug #489374
(Portage version: 2.2.7/cvs/Linux x86_64, RepoMan options: --include-arches="amd64", signed Manifest commit with key 7194459F)
Revision Changes Path
1.2 app-emulation/libvirt/libvirt-1.1.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?r1=1.1&r2=1.2
Index: libvirt-1.1.3-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- libvirt-1.1.3-r1.ebuild 22 Oct 2013 02:00:33 -0000 1.1
+++ libvirt-1.1.3-r1.ebuild 25 Oct 2013 16:24:44 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild,v 1.1 2013/10/22 02:00:33 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild,v 1.2 2013/10/25 16:24:44 ago Exp $
EAPI=5
@@ -24,7 +24,7 @@
ftp://libvirt.org/libvirt/${MY_P}.tar.gz
${BACKPORTS:+
http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
- KEYWORDS="~amd64 ~x86"
+ KEYWORDS="amd64 ~x86"
fi
S="${WORKDIR}/${P%_rc*}"
1.334 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.334&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.334&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.333&r2=1.334
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.333
retrieving revision 1.334
diff -u -r1.333 -r1.334
--- ChangeLog 22 Oct 2013 02:00:33 -0000 1.333
+++ ChangeLog 25 Oct 2013 16:24:44 -0000 1.334
@@ -1,6 +1,9 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.333 2013/10/22 02:00:33 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.334 2013/10/25 16:24:44 ago Exp $
+
+ 25 Oct 2013; Agostino Sarubbo <ago@gentoo.org> libvirt-1.1.3-r1.ebuild:
+ Stable for amd64, wrt bug #489374
*libvirt-1.1.3-r1 (22 Oct 2013)
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.1.3-r1.ebuild ChangeLog
@ 2013-10-25 16:24 Agostino Sarubbo (ago)
0 siblings, 0 replies; 3+ messages in thread
From: Agostino Sarubbo (ago) @ 2013-10-25 16:24 UTC (permalink / raw
To: gentoo-commits
ago 13/10/25 16:24:52
Modified: libvirt-1.1.3-r1.ebuild ChangeLog
Log:
Stable for x86, wrt bug #489374
(Portage version: 2.2.7/cvs/Linux x86_64, RepoMan options: --include-arches="x86", signed Manifest commit with key 7194459F)
Revision Changes Path
1.3 app-emulation/libvirt/libvirt-1.1.3-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild?r1=1.2&r2=1.3
Index: libvirt-1.1.3-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- libvirt-1.1.3-r1.ebuild 25 Oct 2013 16:24:44 -0000 1.2
+++ libvirt-1.1.3-r1.ebuild 25 Oct 2013 16:24:52 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild,v 1.2 2013/10/25 16:24:44 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-1.1.3-r1.ebuild,v 1.3 2013/10/25 16:24:52 ago Exp $
EAPI=5
@@ -24,7 +24,7 @@
ftp://libvirt.org/libvirt/${MY_P}.tar.gz
${BACKPORTS:+
http://dev.gentoo.org/~cardoe/distfiles/${MY_P}-${BACKPORTS}.tar.xz}"
- KEYWORDS="amd64 ~x86"
+ KEYWORDS="amd64 x86"
fi
S="${WORKDIR}/${P%_rc*}"
1.335 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.335&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.335&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.334&r2=1.335
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.334
retrieving revision 1.335
diff -u -r1.334 -r1.335
--- ChangeLog 25 Oct 2013 16:24:44 -0000 1.334
+++ ChangeLog 25 Oct 2013 16:24:52 -0000 1.335
@@ -1,6 +1,9 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.334 2013/10/25 16:24:44 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.335 2013/10/25 16:24:52 ago Exp $
+
+ 25 Oct 2013; Agostino Sarubbo <ago@gentoo.org> libvirt-1.1.3-r1.ebuild:
+ Stable for x86, wrt bug #489374
25 Oct 2013; Agostino Sarubbo <ago@gentoo.org> libvirt-1.1.3-r1.ebuild:
Stable for amd64, wrt bug #489374
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2013-10-25 16:24 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-10-22 2:00 [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-1.1.3-r1.ebuild ChangeLog Doug Goldstein (cardoe)
-- strict thread matches above, loose matches on Subject: below --
2013-10-25 16:24 Agostino Sarubbo (ago)
2013-10-25 16:24 Agostino Sarubbo (ago)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox