[gentoo-commits] gentoo-x86 commit in x11-libs/libdrm: libdrm-2.4.47.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-libs/libdrm: libdrm-2.4.47.ebuild ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    13/10/13 23:29:30

  Modified:             ChangeLog
  Added:                libdrm-2.4.47.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.1/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.245                x11-libs/libdrm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.245&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.245&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?r1=1.244&r2=1.245

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v
retrieving revision 1.244
retrieving revision 1.245
diff -u -r1.244 -r1.245
--- ChangeLog	8 Oct 2013 05:07:09 -0000	1.244
+++ ChangeLog	13 Oct 2013 23:29:30 -0000	1.245
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/libdrm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.244 2013/10/08 05:07:09 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.245 2013/10/13 23:29:30 chithanh Exp $
+
+*libdrm-2.4.47 (13 Oct 2013)
+
+  13 Oct 2013; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +libdrm-2.4.47.ebuild:
+  Version bump.
 
   08 Oct 2013; Agostino Sarubbo <ago@gentoo.org> libdrm-2.4.46.ebuild:
   Stable for x86, wrt bug #475480



1.1                  x11-libs/libdrm/libdrm-2.4.47.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.47.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.47.ebuild?rev=1.1&content-type=text/plain

Index: libdrm-2.4.47.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.47.ebuild,v 1.1 2013/10/13 23:29:30 chithanh Exp $

EAPI=5

XORG_MULTILIB=yes
inherit xorg-2

EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"

DESCRIPTION="X.Org libdrm library"
HOMEPAGE="http://dri.freedesktop.org/"
if [[ ${PV} = 9999* ]]; then
	SRC_URI=""
else
	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
fi

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
VIDEO_CARDS="exynos freedreno intel nouveau omap radeon vmware"
for card in ${VIDEO_CARDS}; do
	IUSE_VIDEO_CARDS+=" video_cards_${card}"
done

IUSE="${IUSE_VIDEO_CARDS} libkms"
REQUIRED_USE="video_cards_exynos? ( libkms )"
RESTRICT="test" # see bug #236845

RDEPEND="dev-libs/libpthread-stubs[${MULTILIB_USEDEP}]
	video_cards_intel? ( >=x11-libs/libpciaccess-0.10[${MULTILIB_USEDEP}] )
	abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}"/${PN}-2.4.28-solaris.patch
)

src_prepare() {
	if [[ ${PV} = 9999* ]]; then
		# tests are restricted, no point in building them
		sed -ie 's/tests //' "${S}"/Makefile.am
	fi
	xorg-2_src_prepare
}

src_configure() {
	XORG_CONFIGURE_OPTIONS=(
		--enable-udev
		$(use_enable video_cards_exynos exynos-experimental-api)
		$(use_enable video_cards_freedreno freedreno-experimental-api)
		$(use_enable video_cards_intel intel)
		$(use_enable video_cards_nouveau nouveau)
		$(use_enable video_cards_omap omap-experimental-api)
		$(use_enable video_cards_radeon radeon)
		$(use_enable video_cards_vmware vmwgfx)
		$(use_enable libkms)
	)
	xorg-2_src_configure
}