* [gentoo-commits] gentoo-x86 commit in sys-boot/plymouth: plymouth-0.8.8-r3.ebuild ChangeLog plymouth-0.8.8.ebuild plymouth-0.8.8-r2.ebuild plymouth-0.8.3-r5.ebuild plymouth-0.8.4.ebuild
@ 2013-10-13 12:27 Pacho Ramos (pacho)
0 siblings, 0 replies; only message in thread
From: Pacho Ramos (pacho) @ 2013-10-13 12:27 UTC (permalink / raw
To: gentoo-commits
pacho 13/10/13 12:27:11
Modified: ChangeLog
Added: plymouth-0.8.8-r3.ebuild
Removed: plymouth-0.8.8.ebuild plymouth-0.8.8-r2.ebuild
plymouth-0.8.3-r5.ebuild plymouth-0.8.4.ebuild
Log:
Install compat symlinks as some rdeps need them, drop old
(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.40 sys-boot/plymouth/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?r1=1.39&r2=1.40
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog 12 Oct 2013 11:21:21 -0000 1.39
+++ ChangeLog 13 Oct 2013 12:27:11 -0000 1.40
@@ -1,6 +1,13 @@
# ChangeLog for sys-boot/plymouth
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v 1.39 2013/10/12 11:21:21 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v 1.40 2013/10/13 12:27:11 pacho Exp $
+
+*plymouth-0.8.8-r3 (13 Oct 2013)
+
+ 13 Oct 2013; Pacho Ramos <pacho@gentoo.org> +plymouth-0.8.8-r3.ebuild,
+ -plymouth-0.8.3-r5.ebuild, -plymouth-0.8.4.ebuild, -plymouth-0.8.8-r2.ebuild,
+ -plymouth-0.8.8.ebuild:
+ Install compat symlinks as some rdeps need them, drop old
12 Oct 2013; Pacho Ramos <pacho@gentoo.org> plymouth-0.8.8-r2.ebuild:
Fix install with static-libs (#487756 by Andrius Štikonas)
1.1 sys-boot/plymouth/plymouth-0.8.8-r3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/plymouth-0.8.8-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/plymouth-0.8.8-r3.ebuild?rev=1.1&content-type=text/plain
Index: plymouth-0.8.8-r3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/plymouth-0.8.8-r3.ebuild,v 1.1 2013/10/13 12:27:11 pacho Exp $
EAPI=5
inherit autotools-utils readme.gentoo systemd toolchain-funcs
DESCRIPTION="Graphical boot animation (splash) and logger"
HOMEPAGE="http://cgit.freedesktop.org/plymouth/"
SRC_URI="
http://www.freedesktop.org/software/plymouth/releases/${P}.tar.bz2
http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE_VIDEO_CARDS="video_cards_intel video_cards_radeon"
IUSE="${IUSE_VIDEO_CARDS} debug gdm +gtk +libkms +pango static-libs systemd"
CDEPEND="
>=media-libs/libpng-1.2.16
gtk? (
dev-libs/glib:2
>=x11-libs/gtk+-2.12:2 )
libkms? ( x11-libs/libdrm[libkms] )
pango? ( >=x11-libs/pango-1.21 )
video_cards_intel? ( x11-libs/libdrm[video_cards_intel] )
video_cards_radeon? ( x11-libs/libdrm[video_cards_radeon] )
"
DEPEND="${CDEPEND}
virtual/pkgconfig
"
# Block due bug #383067
RDEPEND="${CDEPEND}
systemd? ( !sys-boot/plymouth-openrc-plugin sys-apps/systemd )
virtual/udev
"
DOC_CONTENTS="
Follow the following instructions to set up Plymouth:\n
http://dev.gentoo.org/~aidecoe/doc/en/plymouth.xml
"
src_prepare() {
sed -i 's:/bin/systemd-tty-ask-password-agent:/usr/bin/systemd-tty-ask-password-agent:g' \
systemd-units/systemd-ask-password-plymouth.service.in || die \
'ask-password sed failed'
sed -i 's:/bin/udevadm:/usr/bin/udevadm:g' \
systemd-units/plymouth-start.service.in || die 'udevadm sed failed'
autotools-utils_src_prepare
}
src_configure() {
local myeconfargs=(
--with-system-root-install=no
--localstatedir=/var
--without-rhgb-compat-link
$(use_enable debug tracing)
$(use_enable gtk gtk)
$(use_enable libkms)
$(use_enable pango)
$(use_enable gdm gdm-transition)
$(use_enable video_cards_intel libdrm_intel)
$(use_enable video_cards_radeon libdrm_radeon)
$(use_enable systemd systemd-integration)
)
autotools-utils_src_configure
}
src_install() {
autotools-utils_src_install
insinto /usr/share/plymouth
newins "${DISTDIR}"/gentoo-logo.png bizcom.png
# Install compatibility symlinks as some rdeps hardcode the paths
dosym /usr/bin/plymouth /bin/plymouth
dosym /usr/sbin/plymouth-set-default-theme /sbin/plymouth-set-default-theme
dosym /usr/sbin/plymouthd /sbin/plymouthd
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
if ! has_version "sys-kernel/dracut[dracut_modules_plymouth]" && ! has_version "sys-kernel/genkernel-next[plymouth]"; then
ewarn "If you want initramfs builder with plymouth support, please emerge"
ewarn "sys-kernel/dracut[dracut_modules_plymouth] or sys-kernel/genkernel-next[plymouth]."
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-10-13 12:27 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-10-13 12:27 [gentoo-commits] gentoo-x86 commit in sys-boot/plymouth: plymouth-0.8.8-r3.ebuild ChangeLog plymouth-0.8.8.ebuild plymouth-0.8.8-r2.ebuild plymouth-0.8.3-r5.ebuild plymouth-0.8.4.ebuild Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox